Outlook 에서 특정 사용자로부터 온 회의 요청을 자동으로 수락하려면 어떻게 하나요？

Outlook 에서 회의 초대를 받을 때 직접 회의 요청을 수락하고 발신자에게 응답을 보내야 합니다。 특정 사용자로부터 오는 요청을 자동으로 수락할 수 있는 쉬운 방법이 있을까요？ 이 문서에서 소개하는 방법이 도움이 될 것입니다。

VBA 코드로 특정 사용자로부터 온 회의 요청 자동 수락하기

---

VBA 코드로 특정 사용자로부터 온 회의 요청 자동 수락하기

다음 VBA 코드를 사용하면 Outlook 에서 특정 사용자가 보낸 회의 요청을 자동으로 수락할 수 있습니다。 아래 단계를 따라 주세요。

1. Alt+F11키를 눌러Microsoft Visual Basic for Applications창을 엽니다。

2. Microsoft Visual Basic for Applications창에서 왼쪽 패인의ThisOutlookSession을 두 번 클릭하여 코드 창을 연 후， 아래의 VBA 코드를 복사하여 붙여넣습니다。 스크린샷 참조：

VBA 코드: Outlook 에서 특정 사용자로부터 온 회의 요청 자동 수락하기

Public WithEvents GItems As Outlook.Items
'Updated by ExtendOffice 20180814
Private Sub Application_Startup()
    Set GItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub GItems_ItemAdd(ByVal Item As Object)
Dim xMtRequest As MeetingItem
Dim xAppointmentItem As AppointmentItem
Dim xMtResponse As MeetingItem
If Item.Class = olMeetingRequest Then
    Set xMtRequest = Item
    Set xAppointmentItem = xMtRequest.GetAssociatedAppointment(True)
    If xAppointmentItem.GetOrganizer.Name = "Sender Name" Then
        With xAppointmentItem
            .ReminderMinutesBeforeStart = 45
            .Categories = "Orange Category"
            .Save
        End With
        Set xMtResponse = xAppointmentItem.Respond(olMeetingAccepted)
        xMtResponse.Send
        xMtRequest.Delete
    End If
End If
End Sub

참고： 코드에서 “보낸 사람 이름” 부분을 발신자의 표시 이름으로 바꾸세요。

3. 코드를 저장한 후Alt+Q키를 눌러Microsoft Visual Basic for Applications창을 닫습니다。

4. 이 코드가 적용되도록 Outlook 을 다시 시작하세요。

이제 코드에 지정한 사용자로부터 회의 요청을 받으면 해당 회의가 자동으로 수락되고 발신자에게 응답 이메일도 전송됩니다。

참고: 회의 요청을 수신하는 이메일 계정은 Outlook 에서 기본 계정이어야 합니다。

；

---

관련 문서：

• Outlook 에서 회의 초대를 거절하되 캘린더에는 계속 표시하려면 어떻게 하나요？
• Outlook 에서 향후 모든 반복 회의를 거절하려면 어떻게 하나요？