Outlook 에서 다양한 유형의 삭제된 항목을(를) 자동으로 서로 다른 폴더로 이동하려면 어떻게 해야 하나요？

Outlook 에서는 모든 종류의 삭제된 항목(메일, 작업, 연락처 등)이 삭제된 항목 폴더로 이동됩니다. 아래 스크린샷과 같이 삭제된 항목 폴더 아래에 항목 유형별로 서로 다른 폴더로 이동하려면 Outlook 에서 어떻게 설정해야 할까요？

---

VBA 코드를 사용하여 다양한 유형의 삭제된 항목을(를) 자동으로 서로 다른 폴더로 이동하기

다음의 VBA 코드를 사용하면 삭제된 항목을(를) 자동으로 서로 다른 폴더로 이동할 수 있습니다。 다음 단계를 따르세요：

1. Outlook 을 실행한 후ALT + F11키를 누른 채로Microsoft Visual Basic for Applications창을 엽니다。

2。 그런 다음ThisOutlookSession을(를)Project-Project1패널에서 두 번 클릭하고， 아래 코드를 빈 코드 창에 복사하여 붙여넣습니다：

VBA 코드： 다양한 유형의 삭제된 항목을(를) 자동으로 서로 다른 폴더로 이동하기

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. 그런 다음 이 코드를 저장하고 Outlook 을 다시 시작하여 코드를 활성화합니다。

4。 이제부터 항목을 삭제할 때마다 해당 항목은 자동으로삭제된 항목폴더 아래의 해당 유형의 폴더로 이동됩니다。

5。 결과를 확인하려면 폴더 패널 하단의아이콘을 클릭한 후 패널에서Folders을(를) 클릭하여 모든 폴더 확장을(를) 확인하세요。 스크린샷 참조：