아웃룩에서 모든 카테고리를 지우는 방법은 무엇입니까?

Author: Xiaoyang Last Modified: 2025-08-06

당신의 아웃룩에서 많은 항목들이 색상 카테고리에 적용되어 있다고 가정해 봅시다. 만약 이 모든 카테고리를 항목들로부터 지워야 한다면, 어떻게 하면 이를 아웃룩에서 빠르고 쉽게 처리할 수 있을까요?

모든 카테고리를 특정 폴더에서 '모두 지우기' 기능을 사용하여 제거하기

VBA 코드를 사용하여 특정 계정에서 모든 카테고리 지우기

모든 카테고리를 특정 폴더에서 '모두 지우기' 기능을 사용하여 제거하기

특정 폴더에서만 카테고리를 지우려면, 다음 단계를 따르세요:

1. 색상 카테고리를 제거하려는 폴더를 클릭한 다음 Ctrl + A를 눌러 모든 항목을 선택합니다.

2. 그런 다음 마우스 오른쪽 버튼을 클릭하고, 컨텍스트 메뉴에서 카테고리 추가하기 > 모두 지우기를 선택하세요. 스크린샷을 참조하세요:

3. 그리고 나서, 이 특정 폴더의 모든 색상 카테고리가 한 번에 지워집니다.

VBA 코드를 사용하여 특정 계정에서 모든 카테고리 지우기

이메일, 작업, 연락처, 메모 등과 같은 모든 항목에서 모든 카테고리를 지우려면 아래 VBA 코드를 사용할 수 있습니다:

1. 모든 카테고리를 정리하고자 하는 계정의 이메일을 클릭한 다음 ALT + F11 키를 눌러 Microsoft Visual Basic for Applications 창을 엽니다.

2. 삽입 > 모듈을 클릭하고, 모듈 창에 다음 매크로를 붙여넣습니다.

VBA 코드: 특정 계정에서 모든 카테고리 지우기:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. 그런 다음 F5 키를 눌러 실행하면, 선택된 계정의 모든 카테고리가 지워졌다는 알림 상자가 나타납니다. 스크린샷을 참조하세요: