Outlook 에서 연락처 정보와 사진을 함께 내보내는 방법은 무엇입니까？

Outlook 에서 연락처를 파일로 내보낼 때는 연락처의 텍스트 정보만 내보낼 수 있습니다. 하지만 때로는 연락처의 텍스트 정보뿐 아니라 사진도 함께 내보내야 할 경우가 있습니다. Outlook 에서 이 작업을 어떻게 처리할 수 있을까요？

VBA 코드를 사용하여 관련 사진과 함께 연락처 정보 내보내기

---

VBA 코드를 사용하여 관련 사진과 함께 연락처 정보 내보내기

아래의 VBA 코드를 사용하면 특정 연락처 폴더에 있는 모든 연락처를 사진과 함께 별도의 텍스트 파일로 내보낼 수 있습니다。 다음 단계를 따르세요：

1. 사진과 함께 내보낼 연락처 폴더를 선택합니다。

2. 그런 다음 「ALT」 + “F11" 키를 누른 상태로 「Microsoft Visual Basic for Applications」 창을 엽니다。

3. 그런 다음 「삽입(Insert)」 > 「모듈(Module)」을 클릭하고， 아래 코드를 열린 빈 모듈에 복사하여 붙여넣습니다。 스크린샷 참조：

VBA 코드： 사진과 함께 연락처 정보 내보내기

Sub BatchExportContactPhotosandInformation()
Dim xContactItems As Outlook.Items
Dim xItem As Object
Dim xContactItem As ContactItem
Dim xContactInfo As String
Dim xShell As Object
Dim xFSO As Scripting.FileSystemObject
Dim xTextFile As Scripting.TextStream
Dim xAttachments As Attachments
Dim xAttachment As Attachment
Dim xSavePath, xEmailAddress As String
Dim xFolder As Outlook.Folder
On Error Resume Next
Set xFSO = CreateObject("Scripting.FileSystemObject")
Set xShell = CreateObject("Shell.application").BrowseforFolder(0, "Select a Folder", 0, 16)
If xShell Is Nothing Then Exit Sub
xSavePath = xShell.Items.Item.Path & "\"
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    Set xFolder = Outlook.Application.Session.GetDefaultFolder(olFolderContacts)
Else
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
End If
Set xContactItems = xFolder.Items
For i = xContactItems.Count To 1 Step -1
    Set xItem = xContactItems.Item(i)
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        With xContactItem
            xEmailAddress = .Email1Address
            If Len(Trim(.Email2Address)) <> 0 Then
                xEmailAddress = xEmailAddress & ";" & .Email2Address
            End If
            If Len(Trim(.Email3Address)) <> 0 Then
                xEmailAddress = xEmailAddress & ";" & .Email3Address
            End If
            xContactInfo = "Name: " & .FullName & vbCrLf & "Email: " & _
                           xEmailAddress & vbCrLf & "Company: " & .CompanyName & _
                           vbCrLf & "Department: " & .Department & _
                           vbCrLf & "Job Title: " & .JobTitle & _
                           vbCrLf & "IM: " & .IMAddress & _
                           vbCrLf & "Business Phone: " & .BusinessTelephoneNumber & _
                           vbCrLf & "Home Phone: " & .HomeTelephoneNumber & _
                           vbCrLf & "BusinessFax Phone: " & .BusinessFaxNumber & _
                           vbCrLf & "Mobile Phone: " & .MobileTelephoneNumber & _
                           vbCrLf & "Business Address: " & .BusinessAddress
            Set xTextFile = xFSO.CreateTextFile(xSavePath & .FullName & ".txt", True)
            xTextFile.WriteLine xContactInfo
            If .Attachments.Count > 0 Then
                Set xAttachments = .Attachments
                For Each xAttachment In xAttachments
                    If InStr(LCase(xAttachment.FileName), "contactpicture.jpg") > 0 Then
                        xAttachment.SaveAsFile (xSavePath & .FullName & ".jpg")
                    End If
                Next
            End If
        End With
    End If
Next i
End Sub

4. 모듈에 코드를 붙여넣은 후， 「Microsoft Visual Basic for Applications」 창에서 「도구(Tools)」 > 「참조(References)」를 클릭합니다。 나타나는 “References-Project1" 대화상자에서 「Available References」 목록 상자에서 「Microsoft Scripting Runtime」 옵션을 선택합니다。 스크린샷 참조：

5. 「확인(OK)」을 클릭하여 대화상자를 닫은 다음 “F5" 키를 눌러 이 코드를 실행합니다。 나타나는 「폴더 찾아보기(Browse For Folder)」 대화상자에서 내보낸 연락처를 저장할 폴더를 지정합니다。 스크린샷 참조：

6. 그런 다음 「확인(OK)」을 클릭하면 모든 연락처 정보와 사진이 지정한 폴더에 각각 별도로 내보내집니다。 스크린샷 참조：