Outlook 에서 모든 폴더 및 하위 폴더 목록을 내보내고 인쇄하는 방법은 무엇입니까？

일반적으로 Outlook 의 탐색에서 「Ctrl」 + "6" 키를 눌러 모든 폴더 목록을 확인할 수 있습니다. 그러나 폴더 목록을 직접 인쇄할 수는 없습니다. 이 문서에서는 Outlook 의 모든 폴더 및 하위 폴더 목록을 내보내고 인쇄할 수 있는 두 가지 VBA 스크립트를 소개합니다。

• Outlook 의 모든 폴더 및 하위 폴더 목록을 새 이메일으로 내보내고 인쇄합니다
• Outlook 의 모든 폴더 및 하위 폴더 목록을 메모장(Notepad)으로 내보내고 인쇄합니다

---

Outlook 의 모든 폴더 및 하위 폴더 목록을 새 이메일으로 내보내고 인쇄합니다

이 방법은 지정된 전자메일 계정의 모든 폴더 및 하위 폴더 목록을 Outlook 의 새 이메일으로 내보내는 VBA 스크립트를 소개합니다。 이후 폴더 목록을 쉽게 인쇄할 수 있습니다。

1. 「Alt」 + “F11"을 눌러 Microsoft Visual Basic for Applications 창을 엽니다。

2. 「삽입(Insert)」 > 「모듈(Module)」을 클릭한 후 다음 VBA 코드를 새 모듈 창에 붙여넣습니다。

VBA: Outlook 의 새 이메일에서 폴더 및 하위 폴더 목록 내보내기

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. "F5"를 눌러 VBA 를 실행합니다。

4. 표시되는 폴더 선택(Select Folder) 대화 상자에서 인쇄하려는 폴더 목록이 포함된 전자메일 계정을 선택하고 「확인(OK)」을 클릭합니다。

5. 선택한 계정의 폴더 목록이 아래와 같이 새 이메일에 복사됩니다。 「파일(File)」 > 「인쇄(Print)」를 클릭하여 폴더 목록을 인쇄합니다。

6. 인쇄 후 저장하지 않고 새 이메일을 닫습니다。

---

Outlook 의 모든 폴더 및 하위 폴더 목록을 메모장(Notepad)으로 내보내고 인쇄합니다

이 방법은 지정된 전자메일 계정의 모든 폴더 및 하위 폴더 목록을 Outlook 에서 메모장(Notepad)으로 내보내는 VBA 스크립트를 소개합니다。 이후 폴더 목록을 쉽게 인쇄할 수 있습니다。

1. 「Alt」 + “F11"을 눌러 Microsoft Visual Basic for Applications 창을 엽니다。

2. 「삽입(Insert)」 > 「모듈(Module)」을 클릭한 후 다음 VBA 코드를 새 모듈 창에 붙여넣습니다。

VBA: Outlook 의 모든 폴더 및 하위 폴더 목록을 Outlook 에서 메모장(Notepad)으로 내보내기

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. "F5"를 눌러 VBA 를 실행합니다。 열리는 폴더 선택(Select Folder) 대화 상자에서 내보내고 인쇄하려는 폴더 목록이 포함된 전자메일 계정을 선택한 후 「확인(OK)」을 클릭합니다。

4. 출력 폴더 트리(Output Folder Tree) 대화 상자가 나타납니다。 트리 들여쓰기를 포함할지 여부에 따라 「예(Yes)」 또는 「아니요(No)」를 클릭합니다。

이제 아래와 같이 데스크톱에 「Outlook-Folders」라는 이름의 텍스트 파일이 생성되어 저장됩니다：

5. 새로 생성된 텍스트 파일을 두 번 클릭하여 열고， 「파일(File)」 > 「인쇄(Print)」를 클릭하여 내보낸 Outlook 폴더 목록을 인쇄합니다。

관련 문서

Outlook 에서 폴더 목록 보기 표시 또는 숨기기