Word 문서에서 표 캡션을 위에서 아래로 또는 그 반대로 이동하려면 어떻게 해야 하나요?

Author: Xiaoyang Last Modified: 2025-05-21

Word 문서에서 각 표 아래에 삽입된 여러 표가 있는 경우, 때때로 이러한 캡션을 표 아래에서 위로 이동하고 싶을 수 있습니다. 이 작업을 가능한 한 빨리 일괄 처리하려면 어떻게 해야 할까요?

VBA 코드를 사용하여 Word에서 표 캡션을 아래에서 위로 또는 그 반대로 이동하기

VBA 코드를 사용하여 Word에서 표 캡션을 아래에서 위로 또는 그 반대로 이동하기

표 아래의 모든 캡션을 표 위로 이동하려면 다음 VBA 코드가 도움이 될 것입니다. 아래 단계를 따라주세요:

1. ALT + F11 키를 눌러 Microsoft Visual Basic for Applications 창을 엽니다.

2. 삽입 > 모듈을 클릭하고, 모듈 창에 다음 매크로를 붙여넣습니다.

Word 문서에서 표 캡션을 아래에서 위로 이동하기

Sub ReLabelDownToUpTables()
    Dim I As Long
    Dim xRngPre As Range
    Dim xRngNext As Range
    Application.ScreenUpdating = False
    With ActiveDocument
        For I = .Tables.Count To 1 Step -1
            With .Tables(I).Range
                Set xRngPre = .Characters.First.Previous.Characters.Last
                xRngPre.Select
                Set xRngNext = .Characters.Last.Next.Paragraphs.First.Range
                xRngNext.Select
                With xRngPre
                    .InsertBefore vbCr
                    .Style = xRngNext.Style
                    .Start = .End - 1
                    .End = .Start
                End With
                If Len(xRngNext.Text) > 1 Then
                    xRngNext.End = xRngNext.End - 1
                    xRngNext.Cut
                    xRngNext.Delete
                    xRngPre.Paste
                Else
                    xRngNext.Delete
                End If
            End With
        Next
    End With
    Application.ScreenUpdating = True
End Sub

3. 그런 다음, F5 키를 눌러 이 코드를 실행하면 모든 표 캡션이 표 아래에서 위로 이동됩니다. 스크린샷을 참조하세요:

All table captions are moved from below to above

참고: 표 캡션을 표 위에서 아래로 이동하려면 다음 VBA 코드를 적용하세요:

Word 문서에서 표 캡션을 위에서 아래로 이동하기

Sub ReLabelUpToDownTables()
    Dim I As Long
    Dim xRngPre As Range
    Dim xRngNext As Range
    Application.ScreenUpdating = False
    With ActiveDocument
        For I = .Tables.Count To 1 Step -1
            With .Tables(I).Range
                Set xRngNext = .Characters.First.Previous.Paragraphs.First.Range
                xRngNext.Select
                Set xRngPre = .Characters.Last.Next
                xRngPre.End = xRngPre.End - 1
                xRngPre.Select
                With xRngPre
                    .InsertBefore vbCr
                    .Style = xRngNext.Style
                    .Start = .End - 1
                    .End = .Start
                End With
                If Len(xRngNext.Text) > 1 Then
                    xRngNext.End = xRngNext.End - 1
                    xRngNext.Cut
                    xRngNext.Delete
                    xRngPre.Paste
                Else
                    xRngNext.Delete
                End If
            End With
        Next
    End With
    Application.ScreenUpdating = True
End Sub

여러 표, 그림 또는 수식 캡션을 한 번에 Word 문서에 삽입하기

일반적으로 Word 파일에서 표, 이미지 또는 수식에 대해 하나씩 표, 그림 또는 수식 캡션을 삽입해야 합니다. 하지만 Kutools for Word의 다중 캡션 기능이 있다면, 모든 표, 이미지 또는 수식에 대해 가능한 한 빠르게 캡션을 삽입할 수 있습니다.

Batch Insert Captions