Excel에서 텍스트 문자열에서 마지막 숫자를 추출하는 방법은 무엇입니까?

텍스트와 숫자가 혼합된 텍스트 문자열 목록이 있다고 가정해 봅시다. 이제 다음과 같은 스크린샷에 표시된 대로 마지막 숫자 세트를 추출해야 합니다. Excel에서 이 작업을 어떻게 처리할 수 있을까요?

VBA 코드를 사용하여 텍스트 문자열에서 마지막 숫자 추출하기

VBA 코드를 사용하여 텍스트 문자열에서 마지막 숫자 추출하기

텍스트 문자열에서 마지막 숫자 세트를 신속히 추출하려면 다음 VBA 코드를 적용할 수 있습니다. 아래 단계를 따르세요:

1. ALT + F11 키를 눌러 Microsoft Visual Basic for Applications 창을 엽니다.

2. 삽입 > 모듈을 클릭한 다음, 모듈 창에 다음 코드를 복사하여 붙여넣습니다.

VBA 코드: 텍스트 문자열에서 마지막 숫자 추출하기:

Sub GetLastDigits()
'Updateby Extendoffice
    Dim xRg As Range
    Dim xCell As Range
    Dim xRegEx As Object
    Dim xRetList As Object
    Dim xAddress As String
    On Error Resume Next
    xAddress = ActiveWindow.RangeSelection.Address
    Set xRg = Application.InputBox("Please select the range:", "Kutools for Excel", xAddress, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    If xRg.Columns.Count > 1 Then
       MsgBox "Only one column can be available", vbInformation, "Kutools for Excel"
       Exit Sub
    End If
    Set xRegEx = CreateObject("VBSCRIPT.REGEXP")
    With xRegEx
        .MultiLine = False
        .Global = True
        .IgnoreCase = True
        .Pattern = "(\d+)"
    End With
    For Each xCell In xRg
        Set xRetList = xRegEx.Execute(xCell.Value)
        If xRetList.Count > 0 Then
            If Left(xRetList(xRetList.Count - 1), 1) = 0 Then
                xCell.Offset(0, 1) = Right(xRetList(xRetList.Count - 1), Len(xRetList(xRetList.Count - 1)) - 1)
            Else
                xCell.Offset(0, 1) = xRetList(xRetList.Count - 1)
            End If
        End If
    Next
End Sub

3. 그런 다음 F5 키를 눌러 이 코드를 실행하면 데이터 범위를 선택하라는 메시지 상자가 나타납니다. 스크린샷을 참조하세요:

4. 확인 버튼을 클릭하면 각 텍스트 문자열에서 마지막 숫자 세트가 인접한 열의 셀로 추출됩니다. 스크린샷을 참조하세요: