Excel에서 수식으로부터 셀 참조를 추출하는 방법은 무엇입니까?

긴 수식들이 있다고 가정하고, 이제 아래 스크린샷에 표시된 대로 수식에서 모든 셀 참조를 추출하려고 합니다. 어떻게 하면 가능한 한 빨리 수식에서 셀 참조를 추출할 수 있을까요?

사용자 정의 함수를 사용하여 수식에서 셀 참조 추출하기

사용자 정의 함수를 사용하여 수식에서 셀 참조 추출하기

수식에서 셀 참조를 추출하기 위해 아래 VBA 코드가 도움이 될 수 있습니다. 다음 단계를 따르세요:

1. ALT + F11 키를 눌러 Microsoft Visual Basic for Applications 창을 엽니다.

2. 삽입 > 모듈을 클릭하고, 모듈 창에 다음 코드를 붙여넣습니다.

VBA 코드: 수식에서 셀 참조 추출하기:

Function ExtractCellRefs(Rg As Range) As String
'Updateby Extendoffice
    Dim xRetList As Object
    Dim xRegEx As Object
    Dim I As Long
    Dim xRet As String
    Application.Volatile
    Set xRegEx = CreateObject("VBSCRIPT.REGEXP")
    With xRegEx
        .Pattern = "('?[a-zA-Z0-9\s\[\]\.]{1,99})?'?!?\$?[A-Z]{1,3}\$?[0-9]{1,7}(:\$?[A-Z]{1,3}\$?[0-9]{1,7})?"
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
    End With
    Set xRetList = xRegEx.Execute(Rg.Formula)
    If xRetList.Count > 0 Then
        For I = 0 To xRetList.Count - 1
            xRet = xRet & xRetList.Item(I) & ", "
        Next
        ExtractCellRefs = Left(xRet, Len(xRet) - 2)
    Else
        ExtractCellRefs = "No Matches"
    End If
End Function

3. 코드를 붙여넣은 후, 코드를 저장하고 워크시트로 돌아가서, 결과를 얻고자 하는 셀에 이 수식을 입력합니다: =extractcellrefs(G2) (G2는 셀 참조를 추출하려는 수식이 포함된 셀입니다). 그런 다음 Enter 키를 누르면, 수식에서 모든 셀 참조가 추출됩니다. 스크린샷을 참조하세요: