특정 셀 범위에서 모든 특정 단어를 굵게 표시하려면 어떻게 해야 하나요?

Excel에서 찾기 및 바꾸기 기능은 특정 텍스트를 찾아 전체 셀에 굵게 또는 다른 서식을 적용하는 데 도움이 될 수 있습니다. 하지만 아래 스크린샷과 같이 셀의 특정 텍스트만 굵게 표시하고 전체 셀은 굵게 표시하지 않는 방법을 시도해 본 적이 있나요:

VBA 코드를 사용하여 셀 범위 내의 모든 특정 단어를 굵게 표시하기

VBA 코드를 사용하여 셀 범위 내의 모든 특정 단어를 굵게 표시하기

다음 VBA 코드는 셀 내용에서 특정 텍스트만 굵게 표시하는 데 도움이 될 수 있습니다. 아래 단계를 따라 주세요:

1. ALT + F11 키를 눌러 Microsoft Visual Basic for Applications 창을 엽니다.

2. 삽입 > 모듈을 클릭하고, 모듈 창에 다음 코드를 붙여넣습니다.

VBA 코드: 셀 범위 내 특정 텍스트 굵게 표시하기

Sub FindAndBold()
'Updateby Extendoffice 20160711
    Dim xFind As String
    Dim xCell As Range
    Dim xTxtRg As Range
    Dim xCount As Long
    Dim xLen As Integer
    Dim xStart As Integer
    Dim xRg As Range
    Dim xTxt As String
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Please select data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    On Error Resume Next
    Set xTxtRg = Application.Intersect(xRg.SpecialCells(xlCellTypeConstants, xlTextValues), xRg)
    If xTxtRg Is Nothing Then
        MsgBox "There are no cells with text"
        Exit Sub
    End If
    xFind = Trim(Application.InputBox("What do you want to BOLD?", "Kutools for Excel", , , , , , 2))
    If xFind = "" Then
        MsgBox "No text was listed", vbInformation, "Kutools for Excel"
        Exit Sub
    End If
    xLen = Len(xFind)
    For Each xCell In xTxtRg
        xStart = InStr(xCell.Value, xFind)
        Do While xStart > 0
            xCell.Characters(xStart, xLen).Font.Bold = True
            xCount = xCount + 1
            xStart = InStr(xStart + xLen, xCell.Value, xFind)
        Loop
    Next
    If xCount > 0 Then
        MsgBox "number of " & CStr(xCount) & " text be bolded!", vbInformation, "Kutools for Excel"
    Else
        MsgBox "Not find the specific text!", vbInformation, "Kutools for Excel"
    End If
End Sub

3. 그런 다음 F5 키를 눌러 이 코드를 실행하면 데이터 범위를 선택하라는 메시지 상자가 나타납니다. 스크린샷을 참조하세요:

4. 확인을 클릭하면, 셀 내에서 굵게 표시할 특정 텍스트를 입력하라는 또 다른 상자가 나타납니다. 스크린샷을 참조하세요:

5. 텍스트를 입력한 후 확인 버튼을 클릭하면, 선택한 범위 내에서 지정한 모든 텍스트가 굵게 표시됩니다. 스크린샷을 참조하세요: