Skip to main content

Kutools for Office — 하나의 패키지. 다섯 가지 도구. 더 많은 일을 처리하세요.

Excel SUMIF 함수

Author Xiaoyang Last modified

Excel에서 SUMIF 함수는 특정 조건에 따라 셀의 합계를 구하는 데 도움이 될 수 있습니다. 이 문서에서는 이 함수의 구문을 설명하고 SUMIF 함수 사용 예제를 소개합니다.

show the usage of SUMIF function

 구문:

Excel에서 SUMIF 함수의 구문은 다음과 같습니다:

=SUMIF (범위, 조건, [합계_범위])

 인수:

  • 범위: 필수. 조건을 적용하려는 셀 범위입니다.
  • 조건: 필수. 어떤 셀을 더할지 결정하는 데 사용되는 조건입니다. 조건은 텍스트, 숫자, 날짜, 논리 표현식, 셀 참조 또는 다른 함수가 될 수 있습니다.
  • 참고: 모든 텍스트 조건 또는 수학 기호를 포함하는 조건은 반드시 큰따옴표로 묶어야 합니다. 조건이 숫자인 경우 큰따옴표가 필요하지 않습니다.
  • 합계_범위: 선택 사항. 함께 합산할 셀 범위입니다. 이 매개변수가 생략되면 범위를 합계_범위로 사용합니다.

 반환 값:

특정 조건에 따라 숫자 목록에 대한 합계를 반환합니다.


 예제:

예제 1: 값이 크거나 작거나 같거나 다른 비교 연산자인 경우 합계

Excel에서 SUMIF 함수를 사용하여 주어진 조건보다 크거나 작거나 같은 값을 더할 수 있습니다.

아래 스크린샷과 같이 이름, 수량 및 가격 열이 포함된 표가 있다고 가정해 보겠습니다. 수량이 250보다 큰 총 가격을 어떻게 얻을 수 있을까요?

show the usage of SUMIF function

다음 공식을 빈 셀에 입력하십시오:

=SUMIF(B2:B8,">250",C2:C8)
  • 팁: 위의 공식에서:
  • B2:B8: 조건을 찾을 셀 범위입니다.
  • ">250": 셀 값을 합산할 조건입니다.
  • C2:C8: 합산할 범위를 나타냅니다.

그런 다음 Enter 키를 눌러 아래 스크린샷과 같이 수량이 250보다 큰 총 가격을 얻습니다:

show the usage of SUMIF function

참고: 필요에 따라 크거나 같음(>=), 작음(<), 작거나 같음(<=), 같음(=), 같지 않음(<>) 등의 다른 비교 연산자를 사용할 수 있습니다.


예제 2: 텍스트 조건을 포함한 SUMIF 수식

특정 텍스트 값이 다른 열에 있는지 여부에 따라 셀 값을 합산하려면 SUMIF 함수도 도움이 될 수 있습니다.


사례 1: 다른 열에 특정 텍스트가 포함된 경우 셀 값 합산

아래 데이터를 예로 들어보겠습니다. A열에 David라는 이름이 있는 모든 총 수량을 얻으려고 합니다.

show the usage of SUMIF function

다음 공식을 빈 셀에 입력하거나 복사하십시오:

=SUMIF(A2:A8, "David", B2:B8)
  • 팁: 위의 공식에서:
  • A2:A8: 조건을 찾을 셀 범위입니다.
  • "David": 셀 값을 합산할 조건입니다.
  • B2:B8: 합산할 셀 범위입니다.
show the usage of SUMIF function

참고: 위의 공식에서 조건을 셀 참조로 대체할 수도 있습니다: =SUMIF(A2:A8, D2, B2:B8).


사례 2: 특정 값과 같지 않은 경우 셀 값 합산

셀이 특정 값과 같지 않을 때 셀을 합산하려면, 예를 들어 David를 제외한 모든 사람들의 수량을 합산하려면 어떻게 해야 할까요?

show the usage of SUMIF function

다음 공식을 빈 셀에 적용하십시오:

=SUMIF(A2:A8, "<>David", B2:B8)
  • 팁: 위의 공식에서:
  • A2:A8: 조건을 찾을 셀 범위입니다.
  • "<>David": 셀 값을 합산할 조건입니다.
  • B2:B8: 합산할 셀 범위입니다.
show the usage of SUMIF function

참고: 위의 공식에서 조건을 셀 참조로 대체할 수도 있습니다: =SUMIF(A2:A8,"<>"&D2, B2:B8). 비교 연산자는 반드시 큰따옴표("")로 묶고, 셀 참조는 앰퍼샌드(&)로 연결해야 합니다. 스크린샷 보기:

show the usage of SUMIF function

예제 3: 와일드카드 문자를 포함한 SUMIF 수식

때로는 정확한 일치 대신 부분 일치를 기준으로 셀 값을 합산해야 할 수 있습니다. 이 경우 와일드카드 문자인 별표(*) 또는 물음표(?)를 SUMIF 함수와 결합할 수 있습니다.

별표(*): 임의 개수의 문자를 나타냅니다.

물음표(?): 특정 위치의 단일 문자를 나타냅니다.


사례 1: 별표(*) 문자를 사용한 부분 일치 기반 값 합산

예를 들어, 아래 스크린샷과 같은 표가 있다고 가정해 보겠습니다. 이제 Kutools라는 텍스트가 포함된 제품의 총 주문량을 합산하려고 합니다.

show the usage of SUMIF function

여기에서 다음 공식을 빈 셀에 적용하십시오:

=SUMIF(A2:A8, "*Kutools*", B2:B8)

그런 다음 Enter 키를 눌러 아래 결과를 얻습니다:

show the usage of SUMIF function

참고:

1. Kutools로 시작하는 셀 값을 합산하려면 다음 공식을 사용하십시오: =SUMIF(A2:A8, "Kutools*", B2:B8).

2. A열의 해당 셀이 Kutools라는 텍스트로 끝나는 경우 셀 값을 합산하려면 다음 공식을 사용하십시오: =SUMIF(A2:A8, "*Kutools", B2:B8).

3. 위의 공식에서 조건을 셀 참조로 대체할 수도 있습니다: =SUMIF(A2:A8, "*"&D2&"*", B2:B8). 별표는 반드시 큰따옴표("")로 묶고, 셀 참조는 앰퍼샌드(&)로 연결해야 합니다. 스크린샷 보기:

show the usage of SUMIF function

사례 2: 물음표(?)를 사용한 특정 길이의 문자 값 합산

아래 스크린샷과 같이 해당 셀이 정확히 5글자 길이인 리스트의 셀 값을 합산하려면 Excel에서 이 작업을 어떻게 해결할 수 있을까요?

show the usage of SUMIF function

이 작업을 처리하려면 아래 공식을 적용하십시오:

=SUMIF(A2:A8, "?????", B2:B8)

팁: 이 공식에서 물음표 하나는 한 글자를 나타내며, 다섯 개의 물음표는 5글자 길이를 나타냅니다.

그런 다음 Enter 키를 누르면 필요한 결과를 얻을 수 있습니다:

show the usage of SUMIF function

예제 4: 빈 셀 또는 비어 있지 않은 셀에 해당하는 셀 값 합산

Excel에서 SUMIF 함수는 인접한 셀이 빈 셀 또는 비어 있지 않은 셀인 경우에도 리스트의 값을 합산하는 데 도움이 될 수 있습니다.


사례 1: 인접한 셀이 빈 경우 셀 값 합산

결과를 얻고자 하는 셀에 아래 공식 중 하나를 입력하거나 복사하십시오:

=SUMIF(A2:A8,"=",B2:B8)
=SUMIF(A2:A8,"",B2:B8)

그런 다음 Enter 키를 눌러 A열에 빈 셀이 있는 경우 총 가격 결과를 얻습니다. 스크린샷 보기:

show the usage of SUMIF function

사례 2: 인접한 셀이 비어 있지 않은 경우 셀 값 합산

인접한 셀에 텍스트가 포함되어 있고 빈 셀을 제외한 값을 합산해야 하는 경우 아래 공식을 적용하십시오:

=SUMIF(A2:A8,"<>",B2:B8)

그런 다음 Enter 키를 누르면 인접한 셀에 값이 포함된 모든 값이 합산됩니다. 스크린샷 보기:

show the usage of SUMIF function

예제 5: Excel에서 날짜와 함께 SUMIF 사용

일반적으로 Excel에서 특정 날짜를 기준으로 값을 합산하는 데 SUMIF 함수를 사용할 수도 있습니다.


사례 1: 날짜가 현재 날짜이거나 오늘보다 작거나 큰 경우 값 합산

날짜가 현재 날짜인 셀 값을 합산하려면 아래 공식을 사용하십시오:

=SUMIF(B2:B8, TODAY(), C2:C8)

그런 다음 Enter 키를 누르면 해당 날짜가 오늘인 모든 셀이 합산됩니다. 스크린샷 보기:

show the usage of SUMIF function

참고:

1. 해당 날짜가 오늘보다 작거나 이전인 경우 값을 합산하려면 다음 공식을 사용하십시오: =SUMIF(B2:B8, "<"&TODAY(), C2:C8).

2. 해당 날짜가 오늘보다 크거나 이후인 경우 값을 합산하려면 다음 공식을 사용하십시오: =SUMIF(B2:B8, ">"&TODAY(), C2:C8).


사례 2: 두 지정된 날짜 사이의 값 합산

두 지정된 날짜 사이의 날짜에 대해 값을 합산하려면 두 개의 SUMIF 함수를 결합하여 이 작업을 해결할 수 있습니다.

다음 공식을 적용하십시오:

=SUMIF(B2:B8, ">=6/15/2019", C2:C8) - SUMIF(B2:B8, ">=7/31/2019", C2:C8)

그런 다음 Enter 키를 누르면 두 지정된 날짜 사이의 총 값이 계산됩니다. 스크린샷 보기:

show the usage of SUMIF function

참고: 위의 공식에서 조건을 셀 참조로 대체할 수도 있습니다: =SUMIF(B2:B8, ">="&E2, C2:C8) - SUMIF(B2:B8, ">="&F2, C2:C8). 스크린샷 보기:

show the usage of SUMIF function

예제 6: Excel에서 여러 열의 값 합산

이 SUMIF 함수는 하나의 조건에 따라 여러 열의 값을 합산하는 데에도 도움이 될 수 있습니다. 예를 들어, 아래 스크린샷과 같은 데이터 범위가 있다고 가정해 보겠습니다. 이제 Jan, Feb, Mar 및 Apr 네 달 동안 제품 KTE의 총 값을 구하려고 합니다. 어떻게 해야 할까요?

show the usage of SUMIF function

일반적으로 SUMIF 함수는 하나의 기준에 따라 열의 값을 합산하는 데 사용됩니다. 여러 열의 값을 합산하려면 여러 개의 SUMIF 함수를 결합하여 이 작업을 해결할 수 있습니다.

다음 공식을 빈 셀에 적용하십시오:

=SUM(SUMIF(A2:A8,G2,B2:B8), SUMIF(A2:A8,G2,C2:C8), SUMIF(A2:A8,G2,D2:D8),SUMIF(A2:A8,G2,E2:E8))

그런 다음 Enter 키를 눌러 필요한 정확한 결과를 얻습니다. 스크린샷 보기:

show the usage of SUMIF function

참고: 열이 많아서 합산해야 하는 경우 위의 SUMIF 함수는 사용하기 어려울 수 있으므로 여기에서는 간단한 SUMPRODUCT 함수를 사용하여 이 작업을 처리할 수 있습니다. 다음 공식을 사용하십시오: =SUMPRODUCT((A2:A8=G2)*(B2:E8)), 그리고 Enter 키를 눌러 결과를 얻습니다:

  • 팁: 위의 공식에서:
  • A2:A8: 조건을 찾을 셀 범위입니다.
  • G2: 셀 값을 합산할 조건입니다.
  • B2:E8: 합산할 셀 범위입니다.
show the usage of SUMIF function

 SUMIF 함수 관련 추가 기사:

  • Excel에서 동일한 날짜에 해당하는 값 합산하기
  • Excel에서 다른 열의 동일한 날짜를 기준으로 해당 값을 합산해 본 적이 있습니까? 예를 들어, 아래 데이터 범위(A1:B13)가 있다고 가정해 보겠습니다. A열은 일부 중복 날짜를 포함하는 날짜 범위이고, B열에는 주문 수량이 있습니다. 이제 A열의 동일한 날짜를 기준으로 숫자를 더하려고 합니다. Excel에서 이를 빠르고 쉽게 해결하려면 어떻게 해야 할까요?
  • Excel에서 오늘보다 작거나 큰 날짜로 합산하기
  • 매출량 계획과 실제 매출량이 포함된 매출량 테이블이 있다고 가정해 보겠습니다. 이제 우리는 오늘 이전의 발생한 날짜를 세고, 오늘 이전의 계획된 매출량을 계산하여 계획된 매출량과 실제 매출량을 동적으로 비교해야 합니다. 여기에서는 SUMIF 함수를 사용하여 Excel에서 이를 빠르게 해결하는 방법을 설명하겠습니다.
  • Excel에서 하나 이상의 조건으로 합산하기
  • Excel에서 하나 이상의 조건에 따라 값을 합산하는 것은 우리 대부분에게 일반적인 작업입니다. SUMIF 함수는 하나의 조건에 따라 값을 빠르게 합산하는 데 도움이 되며, SUMIFS 함수는 여러 조건에 따라 값을 합산하는 데 도움이 됩니다. 이 문서에서는 Excel에서 하나 이상의 조건으로 합산하는 방법을 설명하겠습니다.
  • Excel에서 부분 일치를 기준으로 합산하기
  • 아래 데이터를 예로 들어보겠습니다. A열에 'KTE' 텍스트가 부분적으로 포함된 경우 B열의 셀 값을 합산하려고 합니다. 이를 어떻게 달성할 수 있을까요? 이 문서에서는 Excel 워크시트에서 부분 일치를 기준으로 셀 값을 합산하는 방법에 대해 설명하겠습니다.

최고의 오피스 생산성 도구

Kutools for Excel - 대중 속에서 돋보이게 도와드립니다

🤖 Kutools AI Aide: 지능형 실행, 코드 생성, 사용자 정의 수식 작성, 데이터 분석 및 차트 생성, Kutools 기능 호출을 통한 데이터 분석 혁신…
인기 기능: 중복 찾기, 강조 또는 식별  |  빈 행 삭제  |  데이터 손실 없이 열 또는 셀 병합  |  수식 없이 반올림 ...
슈퍼 VLookup: 다중 조건  |  다중 값  |  다중 시트 간  |  퍼지 매치...
고급 드롭다운 목록: 쉬운 드롭다운 목록  |  종속 드롭다운 목록  |  다중 선택 드롭다운 목록...
열 관리자: 특정 수의 열 추가  |  열 이동  |  숨겨진 열의 가시성 상태 전환  열 비교하여 동일하고 다른 셀 선택 ...
주요 기능: 그리드 포커스  |  디자인 보기  |  향상된 수식 표시줄  |  통합 문서 및 시트 관리자 | 자동 텍스트 라이브러리 (Auto Text)  |  날짜 선택기  |  워크시트 병합  |  셀 암호화/해독  |  목록으로 이메일 보내기  |  슈퍼 필터  |  특별 필터 (filter bold/italic/strikethrough...) ...
상위 15개 도구 모음12개 텍스트 도구 (텍스트 추가, 특정 문자 삭제 ...)  |  50개 이상의 차트 유형 (간트 차트 ...)  |  40개 이상의 실용적인 수식 (생일을 기반으로 나이 계산 ...)  |  19개 삽입 도구 (QR 코드 삽입, 경로에서 그림 삽입 ...)  |  12개 변환 도구 (숫자를 단어로, 통화 변환 ...)  |  7개 병합 및 분할 도구 (고급 행 병합, 엑셀 셀 분할 ...)  |  ... 그리고 더 많은 기능들
영어, 스페인어, 독일어, 프랑스어, 중국어 등 40개 이상의 언어로 Kutools를 사용해 보세요!

Kutools for Excel은 300가지 이상의 기능을 자랑하며, 원하는 기능이 단 한 번의 클릭만으로 가능합니다...


Office Tab - 마이크로소프트 오피스(엑셀 포함)에서 탭 방식의 읽기 및 편집 활성화

  • 수십 개의 열린 문서 간에 1초 만에 전환하세요!
  • 매일 수백 번의 마우스 클릭을 줄이고, '마우스 손'과 작별하세요.
  • 여러 문서를 보고 편집할 때 생산성을 50% 향상시킵니다.
  • 크롬, 엣지 및 파이어폭스처럼 오피스(엑셀 포함)에 효율적인 탭을 제공합니다.