뛰어나다 CHOOSE 기능

설명:

구문 및 인수

사용법 및 예

• Ex1-기본 사용법 : 사용 CHOOSE 목록 인수에서 값을 선택하는 함수 만
• Ex2 – 여러 조건에 따라 다른 결과 반환
• Ex3 – 조건에 따라 다른 계산 결과 반환
• Ex4 – 목록에서 임의 선택
• Ex5 – 결합 CHOOSE 및 VLOOKUP 왼쪽 열에 값을 반환하는 함수
• Ex6 – 주어진 날짜를 기준으로 평일 또는 월 반환
• Ex7 – 오늘을 기준으로 다음 근무일 / 주말 날짜로 복귀

---

설명:

또한 CHOOSE 함수는 주어진 인덱스 번호를 기반으로 값 인수 목록에서 값을 반환합니다. 예를 들면 CHOOSE(3,”Apple”,”Peach”,”Orange”) Orange를 반환하고 인덱스 번호는 3이며 Orange는 함수의 인덱스 번호 다음 세 번째 값입니다.

구문 및 인수

수식 구문

CHOOSE(index_num, value1, [value2], …)

인수

Index_num: 필수입니다. 선택 될 인수 값을 간접적으로 나타내는 1-254 사이의 숫자 값입니다. index_num이 1-254 사이의 척도를 벗어난 경우 CHOOSE 반환 #VALUE! 오류 값. index_num이 XNUMX 진수 값이면 수식이 사용되기 전에 정수로 내림됩니다. Value1: 필수입니다. 선택할 수있는 공식의 첫 번째 값입니다. Value2: 선택 과목. 선택할 두 번째 및 최대 254 번째 값입니다.

Value1, value2… 숫자, 텍스트, 수식, 셀 참조 또는 정의 된 이름이 될 수 있습니다.

반환 값

또한 CHOOSE 함수는 주어진 위치를 기반으로 목록에서 값을 반환합니다.

사용법 및 예

이 부분에서는 간단하지만 대표적인 예를 나열하여 CHOOSE 기능.

Ex1-기본 사용법 : 사용 CHOOSE 목록 인수에서 값을 선택하는 함수 만

Formula1 :

=CHOOSE(3,"a","b","c","d")

반환 : c, in the index_num of 3 뒤의 세 번째 인수 CHOOSE 기능.

참고 : 텍스트 인 경우 값을 큰 따옴표로 묶습니다.

Formula2 :

=CHOOSE(2,A1,A2,A3,A4)

귀국 : Kate, A2의 가치. index_num은 2이고 A2는 CHOOSE 기능.

Formula3 :

=CHOOSE(4,8,9,7,6)

반환 : 6, 함수의 네 번째 목록 인수.

---

Ex2 – 여러 조건에 따라 다른 결과 반환

아래 스크린 샷과 같이 조건에 따라 라벨을 붙여야하는 각 제품의 편차 목록이 있다고 가정합니다.

일반적으로 IF 함수를 사용하여 처리 할 수 ​​있지만 여기서는 CHOOSE 이 문제를 쉽게 해결하는 기능

수식 :

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

설명:

(B7>0)+(B7>1)+(B7>5): index_num, B7은 2이며 0과 1보다 크지 만 5보다 작으므로 중간 결과를 얻습니다.

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

아시다시피 True = 1, False = 0이므로 공식은 다음과 같이 볼 수 있습니다.

=CHOOSE(1+1+0,"Top","Middle","Bottom")

그때

=CHOOSE(2,"Top","Middle","Bottom")

결과 : 중간

---

Ex3 – 조건에 따라 다른 계산 결과 반환

아래 스크린 샷과 같이 금액과 가격을 기준으로 각 제품에 대한 리베이트를 계산해야한다고 가정합니다.

수식 :

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

설명:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8은 102로 100보다 크지 만 201보다 작으므로이 부분에서는 다음과 같은 결과를 반환합니다.

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

그때

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: 선택할 값, rebate는 price * amount * rebate percent와 같습니다. 여기서 index_num은 2이므로 B8 * C8 * 0.2를 선택합니다.

반환 : 102 * 2 * 0.2 = 40.8

---

Ex4 – 목록에서 임의 선택

Excel에서는 때때로 주어진 목록에서 값을 임의로 선택해야 할 수 있습니다. CHOOSE 기능은이 일을 해결할 수 있습니다.

목록에서 임의로 하나의 값을 선택합니다.

수식 :

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

설명:

RANDBETWEEN(1,5): index_num, 1에서 5 사이의 숫자를 임의로 얻습니다.

$D$2,$D$3,$D$4,$D$5,$D$6: 선택할 값 목록

---

Ex5 – 결합 CHOOSE 및 VLOOKUP 왼쪽 열에 값을 반환하는 함수

일반적으로 우리는 VLOOKUP 함수를 사용합니다. =VLOOKUP (value, table, col_index, [range_lookup]) 테이블 범위에서 주어진 값을 기반으로 값을 반환합니다. 하지만 VLOOKUP 아래 스크린 샷과 같이 반환 열이 조회 열의 왼쪽에있는 동안 오류 값을 반환합니다.

이 경우, 당신은 결합 할 수 있습니다 CHOOSE VLOOKUP 기능으로 문제를 해결합니다.

수식 :

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

설명:

CHOOSE({1,2},B1:B7,A1:A7): VLOOKUP 함수의 table_range 인수로. {1,2}은 VLOOKUP 함수의 col_num 인수를 기반으로 1 또는 2를 index_num 인수로 표시하는 것을 의미합니다. 여기에서 VLOOKUP 함수의 col_num은 2이므로 CHOOSE 기능 표시 CHOOSE(2, B1:B7,A1:A7), A1 : A7에서 값을 선택하는 것을 의미합니다.

---

Ex6 – 주어진 날짜를 기준으로 평일 또는 월 반환

와 더불어 CHOOSE 함수를 사용하면 주어진 날짜를 기준으로 상대적인 요일과 월을 반환 할 수도 있습니다.

수식 1 : 요일을 날짜별로 반환

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

설명:

WEEKDAY(): index_num 인수는 주어진 날짜의 요일 번호를 가져옵니다. 예를 들어 WEEKDAY (A5)는 6을 반환하고 index_num 인수는 6입니다.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": 값 목록 인수는 주중 번호 "1"이 "일요일"을 나타내므로 "일요일"로 시작합니다.

수식 2 : 날짜별로 월을 반환

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

설명:

MONTH(): 지정된 날짜에서 월 번호를 가져 오는 index_num 인수 (예 : MONTH (A5))는 3을 반환합니다.

---

Ex7 – 오늘을 기준으로 다음 근무일 / 주말 날짜로 복귀

일상 업무에서 오늘을 기준으로 다음 근무일 또는 주말을 계산할 수 있습니다. 여기 CHOOSE 기능은 또한 당신에게 호의를 줄 수 있습니다.

예를 들어, 오늘은 12 년 20 월 2018 일 목요일, 이제 다음 근무일과 주말을 받아야합니다.

수식 1 : 오늘 날짜 확인

=TODAY()

결과 : 12 년 20 월 2018 일

수식 2 : 오늘의 요일 번호를 얻다

=WEEKDAY(TODAY())

결과 : 5 (오늘은 12 년 20 월 2018 일)

아래 스크린 샷에 표시된 평일 번호 목록 :

수식 3 : 다음 근무일 확보

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

설명:

Today(): 현재 날짜를 반환

WEEKDAY(TODAY()): index_num 인수 CHOOSE 예를 들어, 일요일은 1, 월요일은 2…

1,1,1,1,1,3,2: 값 목록 인수 CHOOSE 함수. 예를 들어 weekday (today ())가 1 (일요일)을 반환하는 경우 값 목록에서 1을 선택하면 전체 수식이 = Today () + 1로 변경됩니다. 즉, 다음 월요일을 반환하기 위해 1 일을 추가합니다. weekday (today ())가 6 (Friday)을 반환하면 금요일이 다음 월요일에서 3 일 멀기 때문에 값 목록에서 3을 선택합니다.

결과 (오늘은 12 년 20 월 2018 일) :

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12 년 20 월 2018 일 +1

= 12 / 21 / 2018

수식 4 : 다음 주말에 도착

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

설명:

6,5,4,3,2,1,1: 값 목록 인수 CHOOSE 함수. 예를 들어 weekday (today ())가 1 (일요일)을 반환하는 경우 값 목록에서 6을 선택하면 전체 수식이 = Today () + 6으로 변경되어 6 일을 더하고 다음 토요일을 반환합니다.

결과 :

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12 년 20 월 2018 일 +2

= 12 / 22 / 2018

---

샘플 파일