Excel 에서 셀 내 특정 문자 기준으로 텍스트 문자열 분할하기

이 자습서에서는 Excel 에서 특정 문자를 기준으로 텍스트 문자열을 별도의 열 수식로 분할하는 방법을 설명합니다。

Excel 에서 셀 내 특정 문자 기준으로 텍스트 문자열을 분할하려면 어떻게 해야 하나요？

아래 스크린샷과 같이 B 열에 텍스트 문자열 목록이 있고， 문자 “-”를 기준으로 텍스트를 분할하여 세 개의 별도 열에 출력하려는 경우， 아래 수식이 도움이 될 수 있습니다。

일반 수식

왼쪽 텍스트를 분할하기 위한 일반 수식

=LEFT(text_string,FIND(「Char」, text_string)-1)

중간 텍스트를 분할하기 위한 일반 수식

=MID(text_string, FIND(「Char」, text_string) + 1, FIND(「Char」, text_string,FIND(「Char」, text_string)+1) - FIND(「Char」, text_string) - 1)

오른쪽 텍스트를 분할하기 위한 일반 수식

=RIGHT(text_string,LEN(text_string) - FIND(「Char」, text_string, FIND(「Char」, text_string) + 1))

위 수식의 인수

이 수식을 어떻게 사용하나요？

첫째， 특정 문자를 기준으로 첫 번째 텍스트 문자열 분할하기

1. 결과를 출력할 빈 셀을 선택합니다. 여기서는 C3 를 선택했습니다。

2. 아래 수식을 입력하고Enter키를 누릅니다。 그런 다음 LEFT 수식이 포함된 셀을 끝까지 아래로 드래그하여 다른 셀에도 적용합니다。

=LEFT(B3,FIND("-",B3)-1)

둘째， 특정 문자를 기준으로 중간 텍스트 문자열 분할하기

1. 결과를 출력할 빈 셀(예： D3)을 선택합니다。

2. 아래 수식을 입력하고Enter키를 누릅니다。 결과 셀을 선택한 후 채우기 핸들을 아래로 드래그하여 다른 셀에도 수식을 적용합니다。

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

마지막으로， 특정 문자를 기준으로 마지막 텍스트 문자열 분할하기

1. 결과를 출력할 빈 셀(예： E3)을 선택합니다。

2. 아래 수식을 입력하고Enter키를 누릅니다。 결과 셀을 선택한 후 채우기 핸들을 아래로 드래그하여 다른 셀에도 수식을 적용합니다。

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

이제 B 열 각 셀의 텍스트 문자열이 세 부분으로 분할되었습니다。

팁： 텍스트 문자열을 특정 문자를 기준으로 두 부분만 분할하려는 경우， 위의 LEFT 수식으로 첫 번째 부분을 분할한 후 아래의 RIGHT 수식을 적용하여 아래 스크린샷과 같이 두 번째 부분을 추출할 수 있습니다。

=RIGHT(B3,LEN(B3)-FIND("-",B3))

이 수식들은 어떻게 작동하나요？

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3): FIND 함수는 텍스트 문자열 KTE-Jan-359 에서 문자 “-”의 시작 위치를 반환합니다. 결과는 4 입니다。
• LEFT(B3,4-1): LEFT 함수는 텍스트 문자열 KTE-Jan-359 의 왼쪽에서 3 자(4-1=3)를 추출합니다. 여기서 결과는 KTE 입니다。
  참고: 첫 번째 문자 “-”가 텍스트 문자열의 4 번째 위치에 있으므로, 이를 추출 대상에서 제외하려면 1 을 빼야 합니다。

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1: FIND 함수는 텍스트 문자열 KTE-Jan-359 에서 문자 “-”의 시작 위치를 반환합니다. 여기서 결과는 4 입니다。
  참고: 첫 번째 문자 "-"가 텍스트 문자열의 4 번째 위치에 있으므로, 그 이후를 텍스트 추출하기 위해 4 에 1 를 더해야 하며, 최종적으로 4+1=5 이 됩니다。
• FIND("-",B3,FIND("-",B3)+1)여기서는 FIND("-",KTE-Jan-359,4+1)로 표시됩니다. FIND 함수는 KTE-Jan-359 에서 5 번째 문자부터 시작하여 문자 "-"의 위치를 찾고, 결과로 8 을 반환합니다。
• MID(B3, 5, 8 - 4 - 1): MID(KTE-Jan-359,5,3)은 MID 함수가 텍스트 문자열 KTE-Jan-359 에서 5 번째 문자부터 3 자를 추출함을 의미합니다. 결과는 Jan 입니다。

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3): LEN 함수는 텍스트 문자열 KTE-Jan-359 의 전체 길이를 계산하고, 결과로 11 를 반환합니다。
• FIND("-",B3,FIND("-",B3)+1): FIND 함수는 KTE-Jan-359 에서 5 번째 문자부터 시작하여 문자 "-"의 위치를 찾고, 결과로 8 를 반환합니다。
• RIGHT(B3,11 - 8)): RIGHT 함수는 KTE-Jan-359 의 오른쪽에서 3 자(11-8)를 추출합니다. 여기서 결과는 359 입니다。

관련 함수

관련 수식