길이, 높이 및 너비로 차원을 분할하기

이 문서에서는 셀 내의 차원을 세 부분(길이, 높이 및 너비를 포함한 개별 차원)으로 나누는 방법을 설명합니다.

차원을 세 부분으로 나누는 방법은 무엇입니까?

차원을 개별 길이, 높이 및 너비로 분할하려면 세 가지 다른 수식을 별도로 적용해야 합니다.

첫 번째 차원 추출에 대한 일반적인 수식

=LEFT(text,FIND("char",text)-1)

두 번째 차원 추출에 대한 일반적인 수식

=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))

세 번째 차원 추출에 대한 일반적인 수식

=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))

위 수식들의 인수

이러한 수식을 사용하는 방법은 무엇입니까?

먼저 첫 번째 차원을 얻어야 합니다.

1. 첫 번째 차원을 출력할 빈 셀을 선택합니다.

2. 아래 수식을 입력하고 Enter 키를 누릅니다. 결과 셀을 선택하고 필요에 따라 수식을 다른 셀에 적용하도록 채우기 핸들을 드래그합니다.

=LEFT(B5,FIND("x",B5)-1)

다음으로 두 번째 차원을 다음과 같이 분할합니다.

1. 두 번째 차원을 출력할 빈 셀을 선택합니다.

2. 아래 수식을 입력하고 Enter 키를 누릅니다. 결과 셀을 선택하고 필요에 따라 수식을 다른 셀에 적용하도록 채우기 핸들을 드래그합니다.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

마지막으로 마지막 차원을 얻습니다.

1. 마지막 차원을 출력할 빈 셀을 선택합니다.

2. 아래 수식을 입력하고 Enter 키를 누릅니다. 결과 셀을 선택하고 필요에 따라 수식을 다른 셀에 적용하도록 채우기 핸들을 드래그합니다.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

이 수식들은 어떻게 작동합니까?

=LEFT(B5,FIND("x",B5)-1)

1. FIND("x",B5)-1: FIND 함수는 B5에서 첫 번째 "x"의 위치를 가져옵니다. 첫 번째 "x" 없이 첫 번째 차원을 얻으려면 1을 빼야 합니다. 그러면 결과는 4-1=3이 됩니다.
2. LEFT(B5,3): LEFT 함수는 B5의 왼쪽에서 시작하여 3개의 문자를 추출하고 결과를 100으로 반환합니다.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

1. FIND("x",B5)+1: FIND 함수는 B5의 첫 번째 "x"를 찾습니다. 첫 번째 "x" 이후의 두 번째 차원을 얻으려면 여기서 1을 더해야 합니다. 그러면 결과는 4+1=5가 됩니다.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2): SUBSTITUTE 함수는 B5의 두 번째 "x"를 "@"로 바꾸고 결과를 100x50@300으로 반환합니다;
• FIND("@",100x50@300): FIND 함수는 여기서 텍스트 100x50@300에서 "@" 문자의 위치를 가져오고 결과를 7로 반환합니다.

3. (FIND("x",B5)+1): 위 단계 1에서 언급했듯이 여기서 FIND 함수는 B5의 첫 번째 "x"를 찾고 1을 더해 결과를 5로 반환합니다.
4. MID(B5,5,7-(5)): MID 함수는 B5의 텍스트에서 다섯 번째 문자부터 시작하여 (7-5=2)개의 문자를 추출합니다. 그리고 최종 결과를 50으로 반환합니다.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

1. LEN(B5): LEN 함수는 B5의 전체 문자열 길이를 계산하고 결과를 10으로 반환합니다;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2): SUBSTITUTE 함수는 B5의 두 번째 "x"를 "@"로 바꾸고 결과를 100x50@300으로 반환합니다;
• FIND("@",100x50@300): FIND 함수는 여기서 텍스트 100x50@300에서 "@"의 위치를 찾고 결과를 7로 반환합니다.

3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): (10-7) 셀 B5의 텍스트 문자열의 전체 길이에서 처음 7개의 문자를 뺀 결과를 반환하며 결과는 3입니다.
4. RIGHT(B5,3): 그런 다음 RIGHT 함수는 B5의 오른쪽에서부터 3개의 문자를 추출하고 세 번째 차원을 300으로 반환합니다.

관련 함수들

관련 수식들