Skip to main content

Kutools for Office — 하나의 패키지. 다섯 가지 도구. 더 많은 일을 처리하세요.

특정 문자(첫 번째 또는 마지막) 앞이나 뒤의 텍스트 제거하기

Author Xiaoyang Last modified

이 튜토리얼에서는 Excel에서 텍스트 문자열 목록에서 첫 번째 또는 마지막 특정 문자(예: 공백, 쉼표) 앞이나 뒤의 텍스트를 제거하는 방법에 대해 설명합니다.

doc-remove-after-first-space-01


텍스트 문자열에서 첫 번째 특정 문자 앞이나 뒤의 텍스트 제거하기

첫 번째 특정 문자(예: 공백, 쉼표) 앞의 텍스트 제거하기

텍스트 문자열에서 첫 번째 특정 문자 앞의 텍스트를 제거하려면 RIGHT, LEN 및 FIND 함수를 사용할 수 있으며 일반적인 구문은 다음과 같습니다:

=RIGHT(, LEN()-FIND("문자", ))
  • : 텍스트를 제거하려는 셀 참조 또는 텍스트 문자열입니다.
  • 문자: 텍스트를 제거할 기준이 되는 특정 구분자입니다.

결과를 출력하려는 빈 셀에 아래 수식을 입력하거나 복사하세요:

=RIGHT(A2,LEN(A2)-FIND(" ",A2))

그런 다음, 이 수식을 적용하려는 셀까지 채우기 핸들을 드래그하면, 텍스트 문자열에서 첫 번째 공백 앞의 모든 텍스트가 제거됩니다. 스크린샷 참고:

doc-remove-after-first-space-02

수식 설명:

1.LEN(A2)-FIND(" ",A2): 이 부분은 RIGHT 함수 내에서 num_chars로 인식됩니다.

  • FIND(" ",A2): FIND 함수는 첫 번째 공백의 위치를 가져오며, 숫자 11을 반환합니다.
  • LEN(A2): 이 LEN 함수는 A2 셀의 전체 문자 수를 반환하며, 숫자 27을 얻습니다.
  • LEN(A2)-FIND(" ",A2)=27-11: 첫 번째 공백의 위치를 A2 셀의 전체 길이에서 빼면 첫 번째 공백 이후의 문자 수를 얻게 됩니다.

2. RIGHT(A2,LEN(A2)-FIND(" ",A2))=RIGHT(A2, 16): 마지막으로, 이 RIGHT 함수는 A2 셀의 텍스트 문자열 오른쪽에서 16개의 문자를 추출합니다.


첫 번째 특정 문자(예: 공백, 쉼표) 뒤의 텍스트 제거하기

Excel에서는 LEFT와 FIND 함수를 조합하여 첫 번째 특정 문자 뒤의 텍스트를 빠르게 제거할 수 있습니다. 일반적인 구문은 다음과 같습니다:

=LEFT(,FIND("문자",)-1)
  • : 텍스트를 제거하려는 셀 참조 또는 텍스트 문자열입니다.
  • 문자: 텍스트를 제거할 기준이 되는 특정 구분자입니다.

다음 수식을 빈 셀에 적용하세요:

=LEFT(A2,FIND(" ",A2)-1)

그런 다음, 이 수식을 적용하려는 셀까지 채우기 핸들을 드래그하면, 첫 번째 공백 뒤의 모든 텍스트가 한 번에 제거됩니다. 스크린샷 참고:

doc-remove-after-first-space-03

수식 설명:

1.FIND(" ",A2)-1: 이 FIND 함수는 A2 셀에서 첫 번째 공백의 위치를 가져오며, 1을 빼는 것은 공백 문자를 제외하기 위함입니다. 결과는 10이며, 이는 LEFT 함수 내에서 num_chars로 인식됩니다.

2. LEFT(A2,FIND(" ",A2)-1)=LEFT(A2, 10): 이 LEFT 함수는 A2 셀의 텍스트 문자열 왼쪽에서 10개의 문자를 추출합니다.


텍스트 문자열에서 마지막 특정 문자 앞이나 뒤의 텍스트 제거하기

마지막 특정 문자(예: 공백, 쉼표) 앞의 텍스트 제거하기

마지막 특정 문자 앞의 모든 텍스트를 제거하고 마지막 특정 문자 뒤의 하위 문자열만 남겨야 하는 경우, RIGHT, LEN, SEARCH 및 SUBSTITUTE 함수가 도움이 될 수 있습니다. 일반적인 구문은 다음과 같습니다:

=RIGHT(,LEN()-SEARCH("#",SUBSTITUTE(,"문자","#",LEN()-LEN(SUBSTITUTE(,"문자","")))))
  • : 텍스트를 제거하려는 셀 참조 또는 텍스트 문자열입니다.
  • 문자: 텍스트를 제거할 기준이 되는 특정 구분자입니다.

이 작업을 해결하려면 다음 수식을 빈 셀에 복사하거나 입력하세요:

=RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))))

그런 다음, 채우기 핸들을 드래그하여 이 수식을 다른 필요한 셀에 적용하면, 마지막 공백 앞의 모든 텍스트가 삭제되고 마지막 공백 뒤의 텍스트만 남게 됩니다. 스크린샷 참고:

doc-remove-after-first-space-04

수식 설명:

1. LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))):

  • SUBSTITUTE(A2," ",""): 이 SUBSTITUTE 함수는 A2 셀에서 모든 공백 문자를 없애며, 결과는 “Tom-Grade1HoustonTexasUS”와 같이 나옵니다.
  • LEN(SUBSTITUTE(A2," ",""): 이 LEN 함수는 SUBSTITUTE 함수가 반환한 공백 없는 텍스트 문자열의 문자 수를 반환합니다. 결과는 24입니다.
  • LEN(A2)-LEN(SUBSTITUTE(A2," ","")=27-24: 공백 없는 문자 수를 A2 셀의 전체 길이에서 빼면 텍스트 문자열 사이의 공백 수를 얻을 수 있습니다. 결과는 3입니다.
  • SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))= SUBSTITUTE(A2," ","#", 3): 이 SUBSTITUTE 함수는 마지막 공백 문자를 특정 # 문자로 대체하며, 결과는 “Tom-Grade1 Houston Texas#US”입니다.
  • SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))= SEARCH("#", "Tom-Grade1 Houston Texas#US") : 이 SEARCH 함수는 SUBSTITUTE 함수가 반환한 텍스트 문자열에서 특정 # 문자의 위치를 찾습니다. 결과는 25입니다.
  • LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))=27-25: A2 셀의 텍스트 전체 길이에서 마지막 공백의 위치를 빼면 마지막 공백 이후의 문자 수를 얻을 수 있습니다. 결과는 2입니다.

2. RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))))=RIGHT(A2, 2): 마지막으로, 이 RIGHT 함수는 A2 셀의 텍스트 문자열 오른쪽에서 2개의 문자를 추출합니다.


마지막 특정 문자(예: 공백, 쉼표) 뒤의 텍스트 제거하기

마지막 특정 문자 뒤의 텍스트를 제거하려면 LEFT, FIND, SUBSTITUTE 및 LEN 함수가 도움이 될 수 있습니다. 일반적인 구문은 다음과 같습니다:

=LEFT(,FIND("#",SUBSTITUTE(,"문자","#",LEN()-LEN(SUBSTITUTE(,"문자",""))))-1)
  • : 텍스트를 제거하려는 셀 참조 또는 텍스트 문자열입니다.
  • 문자: 텍스트를 제거할 기준이 되는 특정 구분자입니다.

다음 수식을 빈 셀에 입력하거나 복사하세요:

=LEFT(A2,FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1)

그런 다음, 이 수식을 적용하려는 셀까지 채우기 핸들을 드래그하면 아래 스크린샷과 같은 결과를 얻을 수 있습니다:

doc-remove-after-first-space-05

수식 설명:

1. FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1:

  • SUBSTITUTE(A2," ",""): 이 SUBSTITUTE 함수는 A2 셀에서 모든 공백 문자를 없애며, 결과는 “Tom-Grade1HoustonTexasUS”와 같이 나옵니다.
  • LEN(SUBSTITUTE(A2," ",""): 이 LEN 함수는 SUBSTITUTE 함수가 반환한 공백 없는 텍스트 문자열의 문자 수를 반환합니다. 결과는 24입니다.
  • LEN(A2)-LEN(SUBSTITUTE(A2," ",""))=27-24: 공백 없는 문자 수를 A2 셀의 전체 길이에서 빼면 텍스트 문자열 사이의 공백 수를 얻을 수 있습니다. 결과는 3입니다.
  • SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))= SUBSTITUTE(A2," ","#", 3): 이 SUBSTITUTE 함수는 마지막 공백 문자를 특정 # 문자로 대체하며, 결과는 “Tom-Grade1 Houston Texas#US”입니다.
  • FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1=FIND("#", "Tom-Grade1 Houston Texas#US ")-1=25-1: 이 FIND 함수는 SUBSTITUTE 함수가 반환한 텍스트 문자열에서 특정 # 문자의 위치를 반환하며, 1을 빼는 것은 공백 문자를 제외하기 위함입니다. 결과는 24입니다.

2. LEFT(A2,FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1)=LEFT(A2, 24): 마지막으로, 이 LEFT 함수는 A2 셀의 텍스트 문자열 왼쪽에서 24개의 문자를 추출합니다.


관련 함수:

  • LEFT:
  • LEFT 함수는 제공된 문자열의 왼쪽에서 지정된 수의 문자를 추출합니다.
  • RIGHT:
  • RIGHT 함수는 텍스트 문자열의 오른쪽에서 특정 수의 문자를 추출하는 데 사용됩니다.
  • FIND:
  • FIND 함수는 하나의 문자열 안에서 다른 문자열을 찾아 해당 문자열의 시작 위치를 반환합니다.
  • SEARCH:
  • SEARCH 함수는 주어진 텍스트 문자열에서 특정 문자 또는 하위 문자열의 위치를 찾는 데 도움이 됩니다.
  • SUBSTITUTE:
  • Excel의 SUBSTITUTE 함수는 텍스트 문자열 내의 텍스트나 문자를 다른 텍스트나 문자로 대체합니다.
  • LEN:
  • LEN 함수는 텍스트 문자열의 문자 수를 반환합니다.

추가 문서:

  • 텍스트 문자열에서 비숫자 문자 제거하기
  • 때때로 텍스트 문자열에서 모든 비숫자 문자를 제거하고 숫자만 남겨야 할 수도 있습니다. 이 문서에서는 Excel에서 이 작업을 해결하기 위한 몇 가지 수식을 소개합니다.

최고의 오피스 생산성 도구

Kutools for Excel - 대중 속에서 돋보이게 도와드립니다

🤖 Kutools AI Aide: 지능형 실행, 코드 생성, 사용자 정의 수식 작성, 데이터 분석 및 차트 생성, Kutools 기능 호출을 통한 데이터 분석 혁신…
인기 기능: 중복 찾기, 강조 또는 식별  |  빈 행 삭제  |  데이터 손실 없이 열 또는 셀 병합  |  수식 없이 반올림 ...
슈퍼 VLookup: 다중 조건  |  다중 값  |  다중 시트 간  |  퍼지 매치...
고급 드롭다운 목록: 쉬운 드롭다운 목록  |  종속 드롭다운 목록  |  다중 선택 드롭다운 목록...
열 관리자: 특정 수의 열 추가  |  열 이동  |  숨겨진 열의 가시성 상태 전환  열 비교하여 동일하고 다른 셀 선택 ...
주요 기능: 그리드 포커스  |  디자인 보기  |  향상된 수식 표시줄  |  통합 문서 및 시트 관리자 | 자동 텍스트 라이브러리 (Auto Text)  |  날짜 선택기  |  워크시트 병합  |  셀 암호화/해독  |  목록으로 이메일 보내기  |  슈퍼 필터  |  특별 필터 (filter bold/italic/strikethrough...) ...
상위 15개 도구 모음12개 텍스트 도구 (텍스트 추가, 특정 문자 삭제 ...)  |  50개 이상의 차트 유형 (간트 차트 ...)  |  40개 이상의 실용적인 수식 (생일을 기반으로 나이 계산 ...)  |  19개 삽입 도구 (QR 코드 삽입, 경로에서 그림 삽입 ...)  |  12개 변환 도구 (숫자를 단어로, 통화 변환 ...)  |  7개 병합 및 분할 도구 (고급 행 병합, 엑셀 셀 분할 ...)  |  ... 그리고 더 많은 기능들
영어, 스페인어, 독일어, 프랑스어, 중국어 등 40개 이상의 언어로 Kutools를 사용해 보세요!

Kutools for Excel은 300가지 이상의 기능을 자랑하며, 원하는 기능이 단 한 번의 클릭만으로 가능합니다...


Office Tab - 마이크로소프트 오피스(엑셀 포함)에서 탭 방식의 읽기 및 편집 활성화

  • 수십 개의 열린 문서 간에 1초 만에 전환하세요!
  • 매일 수백 번의 마우스 클릭을 줄이고, '마우스 손'과 작별하세요.
  • 여러 문서를 보고 편집할 때 생산성을 50% 향상시킵니다.
  • 크롬, 엣지 및 파이어폭스처럼 오피스(엑셀 포함)에 효율적인 탭을 제공합니다.