특정 열 전체를 조회하고 검색하기

특정 값을 매칭하여 전체 열을 조회하고 검색하려면, INDEX 및 MATCH 수식이 도움이 될 것입니다.

특정 값에 기반한 전체 열 조회 및 검색
특정 값에 기반한 전체 열 합계 계산
특정 값에 기반한 전체 열 추가 분석

특정 값에 기반한 전체 열 조회 및 검색

위 표에 따른 Q2 판매 목록을 얻으려면 먼저 MATCH 함수를 사용하여 Q2 판매의 위치를 반환한 다음, 이를 INDEX에 전달하여 해당 위치의 값을 검색할 수 있습니다.

일반적인 구문

=INDEX(반환_범위,0,MATCH(조회_값,조회_배열,0))

√ 참고: 이는 배열 수식으로 Ctrl + Shift + Enter로 입력해야 합니다.

Q2 판매 목록을 얻으려면 아래 수식을 I6 셀에 복사하거나 입력하고, Ctrl + Shift + Enter를 누른 다음, 셀을 두 번 클릭하고 F9를 눌러 결과를 얻으세요.

=INDEX(C5:F11,0,MATCH("Q2",C4:F4,0))

또는 셀 참조를 사용하여 수식을 동적으로 만들 수 있습니다:

=INDEX(C5:F11,0,MATCH(I5,C4:F4,0))

수식 설명

=INDEX(C5:F11,0,MATCH(I5,C4:F4,0))

• MATCH(I5,C4:F4,0): 매치_타입 0은 MATCH 함수가 C4:F4 범위 내 I5의 값인 Q2의 위치를 반환하도록 강제하며, 그 값은 2입니다.
• INDEX(C5:F11C5:F11,0,MATCH(I5,C4:F4,0)) = INDEX(C5:F11C5:F11,0,2): INDEX 함수는 C5:F11 범위의 2번째 열에 있는 모든 값을 {7865;4322;8534;5463;3252;7683;3654}와 같은 배열로 반환합니다. 배열을 Excel에서 보이게 하려면 수식을 입력한 셀을 두 번 클릭한 후 F9를 누르세요.

특정 값에 기반한 전체 열 합계 계산

이제 우리는 판매 목록을 가지고 있으므로, Q2 총 판매량을 얻는 것은 쉬운 작업입니다. 필요한 것은 수식에 SUM 함수를 추가하여 목록에서 모든 판매 값을 더하는 것뿐입니다.

일반적인 구문

=SUM(INDEX(반환_범위,0,MATCH(조회_값,조회_배열,0)))

이 예시에서 Q2 총 판매량을 얻으려면 아래 수식을 I8 셀에 복사하거나 입력하고, Enter를 눌러 결과를 얻으세요.

=SUM(INDEX(C5:F11,0,MATCH(I5,C4:F4,0)))

수식 설명

=SUM(INDEX(C5:F11,0,MATCH(I5,C4:F4,0)))

• MATCH(I5,C4:F4,0): 매치_타입 0은 MATCH 함수가 C4:F4 범위 내 I5의 값인 Q2의 위치를 반환하도록 강제하며, 그 값은 2입니다.
• INDEX(INDEX(C5:F11C5:F11,0,,0,MATCH(I5,C4:F4,0))) = INDEX(INDEX(C5:F11C5:F11,0,,0,2)): INDEX 함수는 C5:F11 범위의 2번째 열에 있는 모든 값을 {7865;4322;8534;5463;3252;7683;3654}와 같은 배열로 반환합니다.
• SUM(INDEX(C5:F11,0,MATCH(I5,C4:F4,0))) = SUM({7865;4322;8534;5463;3252;7683;3654}): SUM 함수는 배열의 모든 값을 더하고, Q2 총 판매량 $40,773을 얻습니다.

특정 값에 기반한 전체 열 추가 분석

Q2 판매 목록에 대한 추가 처리를 위해서는 단순히 SUM, AVERAGE, MAX, MIN, LARGE 등의 다른 함수들을 수식에 추가하면 됩니다.

예를 들어, Q2 동안의 평균 판매량을 얻으려면 다음 수식을 사용할 수 있습니다:

=AVERAGE(INDEX(C5:F11,0,MATCH(I5,C4:F4,0)))

Q2 동안의 최고 판매량을 알아보려면 아래 수식 중 하나를 사용하세요:

=MAX(INDEX(C5:F11,0,MATCH(I5,C4:F4,0)))
OR
=LARGE(INDEX(C5:F11,0,MATCH(I5,C4:F4,0)),1)

관련 함수

관련 수식