누락된 값 찾기

두 개의 목록을 비교하여 목록 A의 값이 목록 B에 있는지 확인해야 하는 경우가 있습니다. 예를 들어, 제품 목록이 있고 해당 목록의 제품이 공급업체에서 제공한 제품 목록에 있는지 확인하고 싶다고 가정해 보겠습니다. 이 작업을 수행하기 위해 아래에 세 가지 방법을 나열했으니 원하는 방법을 선택하십시오.

MATCH, ISNA 및 IF로 누락된 값 찾기
VLOOKUP, ISNA 및 IF로 누락된 값 찾기
COUNTIF 및 IF로 누락된 값 찾기

MATCH, ISNA 및 IF로 누락된 값 찾기

위 스크린샷에 표시된 대로 귀하의 목록에 있는 모든 제품이 공급업체의 목록에 있는지 확인하려면 먼저 MATCH 함수를 사용하여 귀하의 목록(목록 A)에 있는 제품의 위치를 공급업체의 목록(목록 B)에서 검색할 수 있습니다. 제품이 발견되지 않으면 MATCH는 #N/A 오류를 반환합니다. 그런 다음 결과를 ISNA에 전달하여 #N/A 오류를 TRUE로 변환할 수 있으며, 이는 해당 제품이 누락되었음을 의미합니다. 그런 다음 IF 함수는 기대하는 결과를 반환합니다.

일반적인 구문

=IF(ISNA(MATCH("검색값",검색범위,0)),"누락","발견")

√ 참고: 필요에 따라 "누락", "발견"을 다른 값으로 변경할 수 있습니다.

귀하의 목록에 있는 모든 제품이 공급업체의 목록에 있는지 확인하려면 아래 수식을 H6 셀에 복사하거나 입력하고 Enter 키를 눌러 결과를 얻으십시오.

=IF(ISNA(MATCH(30002,$B$6:$B$10,0)),"누락","발견")

또는 셀 참조를 사용하여 수식을 동적으로 만들 수 있습니다.

=IF(ISNA(MATCH(G6,$B$6:$B$10,0)),"누락","발견")

√ 참고: 위의 달러 기호($)는 절대 참조를 나타내며, 이는 수식을 다른 셀로 이동하거나 복사해도 수식의 검색범위가 변경되지 않음을 의미합니다. 그러나 검색값은 동적 상태로 유지하기 위해 달러 기호가 추가되지 않았습니다. 수식을 입력한 후에는 채우기 핸들을 아래로 드래그하여 수식을 아래 셀에 적용하십시오.

수식 설명

다음은 아래 수식을 예로 들어 설명합니다.

=IF(ISNA(MATCH(G8,$B$6:$B$10,0)),"누락","발견")

• MATCH(G8,$B$6:$B$10,0): match_type 0은 MATCH 함수가 G8 셀의 값인 3004의 첫 번째 일치 항목의 위치를 배열 $B$6:$B$10에서 반환하도록 합니다. 그러나 이 경우 MATCH는 조회 배열에서 값을 찾을 수 없으므로 #N/A 오류를 반환합니다.
• ISNA(ISNA(MATCH(G8,$B$6:$B$10,0))) = ISNA(ISNA(#N/A)): ISNA는 값이 “#N/A” 오류인지 아닌지를 확인합니다. 그렇다면 함수는 TURE를 반환하고, 값이 “#N/A” 오류가 아니라면 FALSE를 반환합니다. 따라서 이 ISNA 수식은 TURE를 반환합니다.
• IF(ISNA(MATCH(G8,$B$6:$B$10,0)),"누락","발견") = IF(TRUE,"누락","발견"): ISNA와 MATCH에 의해 수행된 비교가 TRUE라면 IF 함수는 누락을 반환하고, 그렇지 않으면 발견을 반환합니다. 따라서 수식은 누락을 반환합니다.

VLOOKUP, ISNA 및 IF로 누락된 값 찾기

귀하의 목록에 있는 모든 제품이 공급업체의 목록에 있는지 확인하려면, 값이 다른 목록에 존재하지 않을 때 #N/A 오류를 반환한다는 점에서 MATCH 함수와 동일하게 작동하는 VLOOKUP으로 이를 대체할 수 있습니다.

일반적인 구문

=IF(ISNA(VLOOKUP("검색값",검색범위,1,FALSE)),"누락","발견")

√ 참고: 필요에 따라 "누락", "발견"을 다른 값으로 변경할 수 있습니다.

귀하의 목록에 있는 모든 제품이 공급업체의 목록에 있는지 확인하려면 아래 수식을 H6 셀에 복사하거나 입력하고 Enter 키를 눌러 결과를 얻으십시오.

=IF(ISNA(VLOOKUP(30002,$B$6:$B$10,1,FALSE)),"누락","발견")

또는 셀 참조를 사용하여 수식을 동적으로 만들 수 있습니다.

=IF(ISNA(VLOOKUP(G6,$B$6:$B$10,1,FALSE)),"누락","발견")

√ 참고: 위의 달러 기호($)는 절대 참조를 나타내며, 이는 수식을 다른 셀로 이동하거나 복사해도 수식의 검색범위가 변경되지 않음을 의미합니다. 그러나 검색값은 동적 상태로 유지하기 위해 달러 기호가 추가되지 않았습니다. 수식을 입력한 후에는 채우기 핸들을 아래로 드래그하여 수식을 아래 셀에 적용하십시오.

수식 설명

다음은 아래 수식을 예로 들어 설명합니다.

=IF(ISNA(VLOOKUP(G8,$B$6:$B$10,1,FALSE)),"누락","발견")

• VLOOKUP(G8,$B$6:$B$10,1,FALSE): range_lookup FALSE는 VLOOKUP 함수가 G8 셀의 값인 3004과 정확히 일치하는 값을 검색하고 반환하도록 합니다. 만약 lookup_value 3004이 배열 $B$6:$B$10의 첫 번째 열에 존재한다면 VLOOKUP은 그 값을 반환하고, 그렇지 않으면 #N/A 오류 값을 반환합니다. 여기서 3004은 배열에 존재하지 않으므로 결과는 #N/A입니다.
• ISNA(ISNA(VLOOKUP(G8,$B$6:$B$10,1,FALSE))) = ISNA(ISNA(#N/A)): ISNA는 값이 “#N/A” 오류인지 아닌지를 확인합니다. 그렇다면 함수는 TURE를 반환하고, 값이 “#N/A” 오류가 아니라면 FALSE를 반환합니다. 따라서 이 ISNA 수식은 TURE를 반환합니다.
• IF(ISNA(VLOOKUP(G8,$B$6:$B$10,1,FALSE)),"누락","발견") = IF(TRUE,"누락","발견"): ISNA와 VLOOKUP에 의해 수행된 비교가 TRUE라면 IF 함수는 누락을 반환하고, 그렇지 않으면 발견을 반환합니다. 따라서 수식은 누락을 반환합니다.

COUNTIF 및 IF로 누락된 값 찾기

귀하의 목록에 있는 모든 제품이 공급업체의 목록에 있는지 확인하려면 COUNTIF 및 IF 함수를 사용한 더 간단한 수식을 사용할 수 있습니다. 이 수식은 Excel이 0을 제외한 모든 숫자를 TRUE로 평가한다는 사실을 활용합니다. 따라서 값이 다른 목록에 존재하면 COUNTIF 함수는 해당 목록에서 발생 횟수를 반환하고 IF는 이를 TRUE로 취급합니다. 값이 목록에 존재하지 않으면 COUNTIF 함수는 0을 반환하고 IF는 이를 FALSE로 취급합니다.

일반적인 구문

=IF(COUNTIF("검색범위",검색값),"발견","누락")

√ 참고: 필요에 따라 "발견", "누락"을 다른 값으로 변경할 수 있습니다.

귀하의 목록에 있는 모든 제품이 공급업체의 목록에 있는지 확인하려면 아래 수식을 H6 셀에 복사하거나 입력하고 Enter 키를 눌러 결과를 얻으십시오.

=IF(COUNTIF($B$6:$B$10,30002),"발견","누락")

또는 셀 참조를 사용하여 수식을 동적으로 만들 수 있습니다.

=IF(COUNTIF($B$6:$B$10,G6),"발견","누락")

√ 참고: 위의 달러 기호($)는 절대 참조를 나타내며, 이는 수식을 다른 셀로 이동하거나 복사해도 수식의 검색범위가 변경되지 않음을 의미합니다. 그러나 검색값은 동적 상태로 유지하기 위해 달러 기호가 추가되지 않았습니다. 수식을 입력한 후에는 채우기 핸들을 아래로 드래그하여 수식을 아래 셀에 적용하십시오.

수식 설명

다음은 아래 수식을 예로 들어 설명합니다.

=IF(COUNTIF($B$6:$B$10,G8),"발견","누락")

• COUNTIF($B$6:$B$10,G8): COUNTIF 함수는 G8 셀의 값인 3004이 배열 $B$6:$B$10에 몇 번 나타나는지 계산합니다. 분명히 3004은 배열에 존재하지 않으므로 결과는 0입니다.
• IF(COUNTIF($B$6:$B$10,G8),"발견","누락") = IF(0,"발견","누락"): IF 함수는 0을 FALSE로 평가합니다. 따라서 수식은 첫 번째 인수가 FALSE로 평가될 때 반환되는 값인 누락을 반환합니다.

관련 함수

관련 수식