Skip to main content

Kutools for Office — 하나의 패키지. 다섯 가지 도구. 더 많은 일을 처리하세요.

첫 번째와 두 번째 쉼표 사이의 텍스트 추출하기

Author Xiaoyang Last modified

텍스트 문자열에서 첫 번째와 두 번째 쉼표 또는 두 번째와 세 번째 쉼표 사이의 텍스트를 추출하려면, 이 튜토리얼에서는 Excel에서 이 작업을 해결하기 위한 몇 가지 수식을 소개합니다.

doc-extract-text-between-two-commas-1

텍스트 문자열에서 첫 번째와 두 번째 쉼표 또는 기타 구분 기호 사이의 텍스트 추출하기

첫 번째와 두 번째 쉼표 또는 다른 구분 기호 사이의 텍스트를 추출하려면 MID 및 SEARCH 함수가 이를 수행하는 데 도움이 될 수 있으며 일반적인 구문은 다음과 같습니다:

=MID(cell, SEARCH("char",cell) + 1, SEARCH("char",cell, SEARCH("char",cell)+1) - SEARCH("char",cell) - 1)
  • cell: 텍스트를 추출하려는 셀 참조 또는 텍스트 문자열입니다.
  • char: 텍스트를 추출할 기준이 되는 특정 구분 기호입니다.

결과를 얻고자 하는 빈 셀에 다음 수식을 복사하거나 입력하십시오:

=MID(A2, SEARCH(",",A2) + 1, SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) - 1)

그런 다음, 이 수식을 적용하고자 하는 셀까지 채우기 핸들을 드래그하면, 첫 번째와 두 번째 쉼표 사이의 모든 텍스트가 추출됩니다. 아래 스크린샷을 참조하세요:

doc-extract-text-between-two-commas-2

수식 설명:

1. SEARCH(",",A2) + 1: 이 SEARCH 함수는 A2 셀에서 첫 번째 쉼표의 위치를 찾으며, 1을 더하는 것은 그 다음 문자부터 추출을 시작한다는 의미입니다. 결과로 숫자 14를 반환합니다. 이 부분은 MID 함수 내에서 start_num 인수로 인식됩니다.

2. SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) – 1: 이 부분은 MID 함수 내에서 num_chars 인수로 인식됩니다.

  • SEARCH(",",A2,SEARCH(",",A2)+1): 이 공식은 두 번째 쉼표의 위치를 가져오며, 결과로 숫자 21을 반환합니다.
  • SEARCH(",", A2): 이 SEARCH 함수는 A2 셀에서 첫 번째 쉼표의 위치를 가져옵니다. 결과로 숫자 13을 반환합니다.
  • SEARCH(",", A2, SEARCH(",", A2)+1) - SEARCH(",", A2)-1=21-13-1: 두 번째 쉼표의 위치에서 첫 번째 쉼표의 위치를 뺀 후, 결과에서 1을 빼서 쉼표 문자를 제외합니다. 결과는 7입니다.

3. MID(A2, SEARCH(",",A2) + 1, SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) - 1)=MID(A2, 14, 7): 마지막으로, MID 함수는 A2 셀의 중간에서 7개의 문자를 추출하며, 14번째 문자에서 시작합니다.

참고:

1. 텍스트 문자열이 다른 구분 기호로 분리된 경우, 필요에 따라 쉼표를 다른 구분 기호로 변경하기만 하면 됩니다.

2. 여기에는 또 다른 간단한 수식도 도움이 될 수 있습니다:

=TRIM(MID(SUBSTITUTE(A2,",",REPT(" ",100)),100,100))

doc-extract-text-between-two-commas-3

텍스트 문자열에서 두 번째와 세 번째 쉼표 또는 기타 구분 기호 사이의 텍스트 추출하기

때때로 두 번째와 세 번째 쉼표 사이의 텍스트를 추출해야 할 수 있으며, 이 경우 MID, FIND 및 SUBSTITUTE 함수의 조합이 도움이 될 수 있습니다. 일반적인 구문은 다음과 같습니다:

=MID(cell, FIND("#",SUBSTITUTE(cell,"char","#",2))+1, FIND("#",SUBSTITUTE(cell,"char","#",3)) - FIND("#",SUBSTITUTE(cell,"char","#",2))-1)
  • cell: 텍스트를 추출하려는 셀 참조 또는 텍스트 문자열입니다.
  • char: 텍스트를 추출할 기준이 되는 특정 구분 기호입니다.

아래 수식을 빈 셀에 복사하거나 입력하십시오:

=MID(A2, FIND("#",SUBSTITUTE(A2,",","#",2))+1, FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1)

수식을 붙여넣은 후, 채우기 핸들을 드래그하여 해당 수식을 적용할 셀까지 확장하면, 두 번째와 세 번째 쉼표 사이의 모든 텍스트가 아래 스크린샷과 같이 추출됩니다:

doc-extract-text-between-two-commas-4

수식 설명:

1. FIND("#",SUBSTITUTE(A2,",","#",2))+1: 이 부분은 MID 함수 내에서 start_num 인수로 인식됩니다.

  • SUBSTITUTE(A2,",","#",2): 이 SUBSTITUTE 함수는 A2 셀에서 두 번째 쉼표를 # 문자로 대체하며, 결과로 "Apple-3000KG,Houston#Texas,US"를 얻습니다.
  • FIND("#",SUBSTITUTE(A2,",","#",2))+1: FIND 함수를 사용하여 SUBSTITUE 함수에서 반환된 텍스트 문자열 내에서 # 문자의 위치를 가져옵니다. 1을 더하는 것은 그 다음 문자부터 추출을 시작한다는 의미입니다. 결과로 숫자 22를 반환합니다.

2. FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1: 이 부분은 MID 함수 내에서 num_chars 인수로 인식됩니다.

  • FIND("#",SUBSTITUTE(A2,",","#",3)): 이 수식은 세 번째 쉼표의 위치를 반환하며, 결과로 숫자 27을 반환합니다.
  • FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1= 27-21-1: 세 번째 쉼표의 위치에서 두 번째 쉼표의 위치를 뺀 후, 결과에서 1을 빼서 쉼표 문자를 제외합니다. 결과는 5입니다.

3. MID(A2, FIND("#",SUBSTITUTE(A2,",","#",2))+1, FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1) = MID(A2, 22, 5): 마지막으로, MID 함수는 A2 셀의 중간에서 5개의 문자를 추출하며, 22번째 문자에서 시작합니다.

참고:

1. 텍스트 문자열이 다른 구분 기호로 분리된 경우, 필요에 따라 쉼표를 다른 구분 기호로 변경하기만 하면 됩니다.

2. 또 다른 간단한 수식도 두 번째와 세 번째 쉼표 사이의 텍스트를 추출하는 데 도움이 될 수 있습니다:

=TRIM(MID(SUBSTITUTE(A2,",",REPT(" ",100)),200,100))

doc-extract-text-between-two-commas-5

관련 기능:

  • MID:
  • MID 함수는 주어진 텍스트 문자열의 중간에서 특정 개수의 문자를 찾아 반환하는 데 사용됩니다.
  • FIND:
  • FIND 함수는 하나의 문자열을 다른 문자열 내에서 찾고, 해당 문자열의 시작 위치를 반환합니다.
  • SEARCH:
  • SEARCH 함수는 주어진 텍스트 문자열에서 특정 문자나 부분 문자열의 위치를 찾는 데 도움이 됩니다.
  • SUBSTITUTE:
  • Excel의 SUBSTITUTE 함수는 텍스트 문자열 내의 텍스트나 문자를 다른 텍스트나 문자로 대체합니다.

추가 관련 문서:

  • 셀에서 여러 줄 추출하기
  • 줄 바꿈(Alt + Enter 키를 눌러 입력된 경우)으로 구분된 텍스트 문자열 목록이 있고, 이제 아래 스크린샷과 같이 이러한 줄을 여러 셀로 추출하려고 합니다. Excel에서 수식을 사용해 어떻게 해결할 수 있을까요?
  • 괄호 안의 텍스트 추출하기
  • 괄호로 묶인 텍스트가 텍스트 문자열 내에 있는 경우, 아래 스크린샷과 같이 괄호 사이의 모든 텍스트를 추출하려고 합니다. Excel에서 이 작업을 신속하고 쉽게 해결하려면 어떻게 해야 할까요?
  • 특정 문자의 마지막 인스턴스 이후의 텍스트 추출하기
  • 하이픈, 쉼표, 공백 등 여러 구분 기호가 포함된 복잡한 텍스트 문자열 목록이 있는 경우(아래 스크린샷 예시 참조), 마지막 하이픈의 위치를 찾고 그 이후의 하위 문자열을 추출하려고 합니다. 이 문서에서는 이 작업을 처리하기 위한 몇 가지 수식을 소개합니다.

최고의 오피스 생산성 도구

Kutools for Excel - 대중 속에서 돋보이게 도와드립니다

🤖 Kutools AI Aide: 지능형 실행, 코드 생성, 사용자 정의 수식 작성, 데이터 분석 및 차트 생성, Kutools 기능 호출을 통한 데이터 분석 혁신…
인기 기능: 중복 찾기, 강조 또는 식별  |  빈 행 삭제  |  데이터 손실 없이 열 또는 셀 병합  |  수식 없이 반올림 ...
슈퍼 VLookup: 다중 조건  |  다중 값  |  다중 시트 간  |  퍼지 매치...
고급 드롭다운 목록: 쉬운 드롭다운 목록  |  종속 드롭다운 목록  |  다중 선택 드롭다운 목록...
열 관리자: 특정 수의 열 추가  |  열 이동  |  숨겨진 열의 가시성 상태 전환  |  열 비교하여 동일하고 다른 셀 선택 ...
주요 기능: 그리드 포커스  |  디자인 보기  |  향상된 수식 표시줄  |  통합 문서 및 시트 관리자 | 자동 텍스트 라이브러리 (Auto Text)  |  날짜 선택기  |  워크시트 병합  |  셀 암호화/해독  |  목록으로 이메일 보내기  |  슈퍼 필터  |  특별 필터 (filter bold/italic/strikethrough...) ...
상위 15개 도구 모음:  12개 텍스트 도구 (텍스트 추가, 특정 문자 삭제 ...)  |  50개 이상의 차트 유형 (간트 차트 ...)  |  40개 이상의 실용적인 수식 (생일을 기반으로 나이 계산 ...)  |  19개 삽입 도구 (QR 코드 삽입, 경로에서 그림 삽입 ...)  |  12개 변환 도구 (숫자를 단어로, 통화 변환 ...)  |  7개 병합 및 분할 도구 (고급 행 병합, 엑셀 셀 분할 ...)  |  ... 그리고 더 많은 기능들
영어, 스페인어, 독일어, 프랑스어, 중국어 등 40개 이상의 언어로 Kutools를 사용해 보세요!

Kutools for Excel은 300가지 이상의 기능을 자랑하며, 원하는 기능이 단 한 번의 클릭만으로 가능합니다...

Office Tab - 마이크로소프트 오피스(엑셀 포함)에서 탭 방식의 읽기 및 편집 활성화

  • 수십 개의 열린 문서 간에 1초 만에 전환하세요!
  • 매일 수백 번의 마우스 클릭을 줄이고, '마우스 손'과 작별하세요.
  • 여러 문서를 보고 편집할 때 생산성을 50% 향상시킵니다.
  • 크롬, 엣지 및 파이어폭스처럼 오피스(엑셀 포함)에 효율적인 탭을 제공합니다.