Skip to main content

특정 문자의 마지막 인스턴스 이후 텍스트 추출

Author: Xiaoyang Last Modified: 2025-08-06

복잡한 텍스트 문자열 목록이 있고 여러 구분 기호를 포함하고 있다면 (아래 스크린샷 예시 참조, 셀 데이터 내 하이픈, 쉼표, 공백 포함), 마지막 하이픈의 위치를 찾고 그 뒤에 있는 부분 문자열을 추출하려고 한다면 이 문서에서는 해당 작업을 처리하기 위한 몇 가지 수식을 소개하겠습니다.

doc-extract-text-after-last-character-1

수식 1: 특정 구분 기호의 마지막 인스턴스 이후 부분 문자열 추출

Excel에서 RIGHT 함수는 LEN, SEARCH, SUBSTITUTE 함수와 결합하여 이 작업을 해결하는 수식을 생성하는 데 도움이 될 수 있습니다.

1. 마지막 하이픈 문자 이후 부분 문자열을 추출하려면 다음 수식을 빈 셀에 입력하거나 복사하세요:

=RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2,"-","#",LEN(A2)-LEN(SUBSTITUTE(A2,"-","")))))

2. 그런 다음, 이 수식을 적용하려는 셀까지 채우기 핸들을 아래로 드래그하면 아래 스크린샷과 같은 결과를 얻을 수 있습니다:

doc-extract-text-after-last-character-2

수식 설명:

1. LEN(A2)-LEN(SUBSTITUTE(A2,"-","")): 이 부분은 A2 셀에서 하이픈 문자의 개수를 가져오는 데 사용됩니다.

  • LEN(A2): 이 LEN 함수는 A2 셀의 전체 문자 수를 반환합니다. 결과는 44입니다.
  • SUBSTITUTE(A2,"-",""): 이 SUBSTITUTE 함수는 모든 하이픈을 제거하는 데 사용됩니다. 결과는 다음과 같습니다: “InsertDeleterows, sheets, images, formulas”입니다.
  • LEN(SUBSTITUTE(A2,"-",""): 하이픈을 제외한 A2 셀의 텍스트 문자열의 총 길이를 가져옵니다.
  • LEN(A2)-LEN(SUBSTITUTE(A2,"-","")): 하이픈을 제외한 텍스트 문자열의 길이를 전체 문자열 길이에서 뺀 값으로 하이픈의 개수를 얻습니다. 결과는 2입니다.

2. SUBSTITUTE(A2,"-","#",LEN(A2)-LEN(SUBSTITUTE(A2,"-",""))): 이 SUBSTITUTE 함수는 첫 번째 수식에서 반환된 마지막 하이픈을 # 문자로 대체하는 데 사용됩니다. 결과는 다음과 같습니다: “Insert-Delete#rows, sheets, images, formulas”입니다.

doc-extract-text-after-last-character-3

3. SEARCH("#",SUBSTITUTE(A2,"-","#",LEN(A2)-LEN(SUBSTITUTE(A2,"-",""))))= SEARCH("#", "Insert-Delete#rows, sheets, images, formulas"): 이 SEARCH 함수는 SUBSTUTTE 함수에서 반환된 텍스트 문자열에서 # 문자의 위치를 반환합니다. 결과는 숫자 14입니다.

4. LEN(A2)-SEARCH("#",SUBSTITUTE(A2,"-","#",LEN(A2)-LEN(SUBSTITUTE(A2,"-","")))): 이 수식의 일부는 마지막 하이픈 이후에 있는 문자 수를 계산합니다. 결과는 30입니다.

5. RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2,"-","#",LEN(A2)-LEN(SUBSTITUTE(A2,"-","")))))= RIGHT(A2, 30): 마지막으로 RIGHT 함수는 A2 셀의 텍스트 문자열 오른쪽에서 4단계 수식에서 반환된 30개의 문자를 추출합니다.

참고:

1. 다른 구분 기호의 마지막 인스턴스 이후 텍스트를 추출해야 하는 경우 하이픈 문자를 필요한 다른 구분 기호로 변경하기만 하면 됩니다.

2. 텍스트 문자열에 특정 구분 기호가 없는 경우 위의 수식은 오류 값을 반환합니다. 아래 스크린샷 참조:

doc-extract-text-after-last-character-4

이 오류를 수정하려면 위의 수식을 IFERROR 함수로 감싸주시면 됩니다. 다음 수식을 적용하세요:

=IFERROR(RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2,"-","#",LEN(A2)-LEN(SUBSTITUTE(A2,"-",""))))), A2)

doc-extract-text-after-last-character-5

수식 2: 특정 구분 기호의 마지막 인스턴스 이후 부분 문자열 추출

다음은 TRIM, RIGHT, SUBSTITUTE, REPT 및 LEN 함수로 생성된 또 다른 간단한 수식으로 Excel에서 이 작업을 해결하는 데 도움이 될 수 있습니다.

1. 결과를 얻으려는 빈 셀에 아래 수식을 복사하거나 입력하세요:

=TRIM(RIGHT(SUBSTITUTE(A2,"-",REPT(" ",LEN(A2))),LEN(A2)))

2. 그런 다음, 이 수식을 적용하려는 셀까지 채우기 핸들을 아래로 드래그하면 마지막 하이픈 이후의 모든 부분 문자열이 아래 스크린샷과 같이 추출됩니다:

doc-extract-text-after-last-character-6

수식 설명:

1. LEN(A2): 이 LEN 함수는 A2 셀의 전체 문자 수를 반환합니다. 이 값은 RIGHT 함수의 num_chars 인수로 인식됩니다. 결과는 44입니다.

2. SUBSTITUTE(A2,"-",REPT(" ",LEN(A2))):

  • REPT(" ",LEN(A2): 이 REPT 함수는 A2 셀의 길이에 따라 일정한 수의 공백 문자열을 가져오는 데 사용됩니다.
  • SUBSTITUTE(A2,"-",REPT(" ",LEN(A2))): 이 SUBSTITUTE 함수는 A2 셀의 하이픈 문자를 REPT 함수에서 반환된 공백 문자열로 대체합니다.

이 부분 수식은 RIGHT 함수의 text 인수로 인식됩니다.

3. RIGHT(SUBSTITUTE(A2,"-",REPT(" ",LEN(A2))),LEN(A2)): 이 RIGHT 함수는 SUBSTITUTE 함수에서 반환된 텍스트 문자열의 오른쪽에서부터 텍스트를 가져옵니다.

4. TRIM(): 이 TRIM 함수는 모든 추가 공백을 제거하고 단어 사이에 하나의 공백만 남깁니다.

관련 함수:

  • RIGHT:
  • RIGHT 함수는 텍스트 문자열의 오른쪽에서 특정 수의 문자를 추출합니다.
  • SEARCH:
  • SEARCH 함수는 주어진 텍스트에서 특정 문자 또는 부분 문자열의 위치를 찾는 데 도움이 됩니다.
  • LEN:
  • LEN 함수는 텍스트 문자열의 문자 수를 반환합니다.
  • SUBSTITUTE:
  • Microsoft Excel의 SUBSTITUTE 함수는 텍스트 문자열 내의 텍스트 또는 문자를 다른 텍스트 또는 문자로 대체합니다.
  • TRIM:
  • TRIM 함수는 텍스트 문자열에서 모든 추가 공백을 제거하고 단어 사이에 하나의 공백만 유지합니다.
  • REPT:
  • REPT 함수는 지정된 횟수만큼 문자를 반복하는 데 사용됩니다.

추가 자료:

  • 셀에서 여러 줄 추출
  • 줄 바꿈(Alt + Enter 키를 눌러 텍스트를 입력할 때 발생)으로 구분된 텍스트 문자열 목록이 있고, 이를 여러 셀로 추출하려는 경우 아래 스크린샷과 같이 해결하려면 Excel에서 어떤 수식을 사용해야 할까요?
  • 괄호 안의 텍스트 추출
  • 텍스트 문자열 내 괄호로 둘러싸인 텍스트가 있을 경우, 아래 스크린샷과 같이 괄호 사이의 모든 텍스트를 추출하려면 Excel에서 어떻게 해결할 수 있을까요?
  • Excel에서 텍스트 문자열에서 부분 문자열 추출
  • 텍스트 문자열에서 부분 문자열을 추출하는 것은 일반적인 작업일 수 있습니다. Excel에는 이를 직접적으로 수행하는 함수가 없지만 LEFT, RIGHT, MID 및 SEARCH 함수의 도움으로 다양한 부분 문자열을 추출할 수 있습니다.

최고의 오피스 생산성 도구

Kutools for Excel - 당신을 돋보이게 하는 도구

🤖 Kutools AI Aide: 지능형 실행, 코드 생성, 사용자 정의 수식 작성, 데이터 분석 및 차트 생성, Kutools 기능 호출을 통해 데이터 분석 혁신
인기 있는 기능: 중복 찾기, 강조 또는 식별 | 빈 행 삭제 | 데이터 손실 없이 열 또는 셀 결합 | 수식 없이 반올림 ...
슈퍼 VLookup: 다중 조건 | 다중 값 | 여러 시트 간 | 퍼지 매치...
고급 드롭다운 목록: 쉬운 드롭다운 목록 | 종속 드롭다운 목록 | 다중 선택 드롭다운 목록...
열 관리자: 특정 개수의 열 추가 | 열 이동 | 숨겨진 열 표시 상태 전환 | 열 비교하여 동일한 셀 & 다른 셀 선택...
주요 기능: 그리드 포커스 | 디자인 보기 | 큰 수식 표시줄 | 통합 문서 & 시트 관리자 | 자동 텍스트 라이브러리(자동 텍스트) | 날짜 선택기 | 데이터 병합 | 셀 암호화/해독 | 목록으로 이메일 보내기 | 슈퍼 필터 | 특수 필터 (굵게/이탤릭체/취소선 필터링...) ...
상위 15가지 도구 세트: 12개의 텍스트 도구(텍스트 추가, 특정 문자 삭제...) | 50+ 차트 유형(간트 차트...) | 40+ 실용적인 수식(생일을 기반으로 나이 계산...) | 19개 삽입 도구(QR 코드 삽입, 경로에서 그림 삽입...) | 12개 변환 도구(숫자를 단어로, 통화 변환...) | 7개 병합 및 분할 도구(고급 행 병합, 엑셀 셀 분할...) | ... 그리고 더 많은 기능
영어, 스페인어, 독일어, 프랑스어, 중국어 등 40개 이상의 언어로 Kutools를 사용하세요!

Kutools for Excel은 300개 이상의 기능을 제공하며, 원하는 모든 것이 단 한 번의 클릭만으로 가능합니다...

Office Tab - Microsoft Office(Excel 포함)에서 탭 방식의 읽기 및 편집 활성화

  • 수십 개의 열린 문서 간에 1초 만에 전환 가능!
  • 매일 수백 번의 마우스 클릭을 줄이고, 마우스 손과 작별 인사하세요.
  • 여러 문서를 보고 편집할 때 생산성을 50% 향상시킵니다.
  • Office(Excel 포함)에 효율적인 탭을 제공합니다. Chrome, Edge 및 Firefox와 비슷합니다.