열에서 고유한 숫자 값 또는 날짜 개수 세기

중복된 숫자 목록이 있고, 아래 스크린샷과 같이 목록에서 고유한 값 또는 한 번만 나타나는 값의 개수를 세고자 할 때, 이 문서에서는 Excel 에서 이 작업을 빠르고 쉽게 해결할 수 있는 유용한 수식들을 소개합니다。

• Excel 2019, 2016 및 이전 버전에서 열의 고유한 숫자 값 또는 날짜 개수 세기
  • 열에서 고유한 숫자 값 또는 날짜 개수 세기
  • 열에서 한 번만 나타나는 고유한 숫자 값 또는 날짜 개수 세기
• Excel 365 에서 열의 고유한 숫자 값 또는 날짜 개수 세기
  • 열에서 고유한 숫자 값 또는 날짜 개수 세기
  • 열에서 한 번만 나타나는 고유한 숫자 값 또는 날짜 개수 세기

Excel 2019, 2016 및 이전 버전에서 열의 고유한 숫자 값 또는 날짜 개수 세기

Excel 2019, 2016 및 이전 버전을 사용하는 경우 일반적인 SUM， FREQUENCY， IF， COUNTIF， ISNUMBER 함수를 적용해 고유한 값 또는 한 번만 나타나는 값의 개수를 얻을 수 있습니다。

열에서 고유한 숫자 값 또는 날짜 개수 세기

목록에서 고유한 숫자를 세려면 SUM 과 FREQUENCY 함수를 사용할 수 있습니다。 일반적인 구문은 다음과 같습니다：

• range： 범위 내 고유 값 수 세기하려는 데이터 열입니다。

결과를 출력할 빈 셀에 다음 수식을 입력하거나 복사한 후Enter키를 눌러 결과를 얻으세요：

수식 설명：

=SUM(--(FREQUENCY(A2:A12,A2:A12)>0))

• FREQUENCY(A2:A12,A2:A12): FREQUENCY 함수는 A2:A12 목록에서 각 숫자 값이 나타나는 횟수를 계산하여 다음과 같은 배열을 반환합니다: {1;2;0;2;0;1;1;3;0;0;1;0}. 배열의 숫자는 해당 값이 열에서 몇 번 나타나는지를 나타냅니다. 배열의 0 은 해당 숫자가 이미 데이터 범위에 나타났음을 의미합니다。
• --(FREQUENCY(A2:A12,A2:A12)>0=--({1;2;0;2;0;1;1;3;0;0;1;0})>0): 배열의 각 값이 0 과 비교됩니다. 0 보다 크면 TRUE, 그렇지 않으면 FALSE 가 표시됩니다. 그런 다음 이중 부호(-- )를 사용해 TRUE 와 FALSE 를 각각 1 과 0 으로 변환하므로 결과는 다음과 같습니다： {1;1;0;1;0;1;1;1;0;0;1;0}。
• SUM(--(FREQUENCY(A2:A12,A2:A12)>0))=SUM({1;1;0;1;0;1;1;1;0;0;1;0}): 마지막으로 SUM 함수가 배열의 모든 값을 더해 결과 7 을 반환합니다。

열에서 한 번만 나타나는 고유한 숫자 값 또는 날짜 개수 세기

목록에서 한 번만 나타나는 고유한 숫자 값을 세려면 SUM， IF， ISNUMBER 및 COUNTIF 함수를 조합해 수식을 만들어야 합니다。 일반적인 구문은 다음과 같습니다：

• range： 범위 내 고유 값 수 세기하려는 데이터 열입니다。

빈 셀에 아래 수식을 입력하거나 복사한 후Ctrl + Shift + Enter키를 동시에 눌러 올바른 결과를 얻으세요：

수식 설명：

=SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

• ISNUMBER(A2:A12): ISNUMBER 함수는 A2:A12 목록의 값이 숫자인지 확인합니다. 셀에 숫자 값이 있으면 TRUE, 그렇지 않으면 FALSE 를 반환하므로 다음과 같은 배열을 얻게 됩니다： {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}。
• COUNTIF(A2:A12,A2:A12)： COUNTIF 함수는 지정된 범위에서 각 값이 몇 번 나타나는지 계산하여 다음과 같은 결과를 반환합니다： {1;2;2;2;2;1;1;3;3;3;1}。
• ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)= {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}* {1;2;2;2;2;1;1;3;3;3;1}： 두 표현식을 곱해서 다음과 같은 결과를 얻습니다： {1;2;2;2;2;1;1;3;3;3;1}。
• IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0)=IF({1;2;2;2;2;1;1;3;3;3;1}=1,1,0): 여기서 IF 함수는 배열의 각 값이 1 과 같은지 확인합니다. 같으면 숫자 1 을 반환하고, 다르면 숫자 0 을 표시합니다。 결과는 다음과 같습니다： {1;0;0;0;0;1;1;0;0;0;1}。
• SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))=SUM({1;0;0;0;0;1;1;0;0;0;1}): 마지막으로 SUM 함수가 배열의 값을 모두 더해 고유한 값의 총 개수 4 를 반환합니다。

Excel 365 에서 열의 고유한 숫자 값 또는 날짜 개수 세기

Excel 365 에서는 UNIQUE 라는 새롭고 간편한 함수가 도입되었습니다。 이 함수를 COUNT 함수로 감싸면 필요한 작업을 빠르게 처리할 수 있습니다。

열에서 고유한 숫자 값 또는 날짜 개수 세기

Excel 365 에서 고유한 숫자 값 또는 날짜 개수를 세는 일반적인 구문은 다음과 같습니다：

• range： 범위 내 고유 값 수 세기하려는 데이터 열입니다。

빈 셀에 아래 수식을 입력하거나 복사한 후Enter키를 눌러 결과를 얻으세요(스크린샷 참조)：

수식 설명：

=COUNT(UNIQUE(A2:A12))

• UNIQUE(A2:A12)： UNIQUE 함수는 목록에서 모든 고유한 값을 추출하여 다음과 같은 배열 목록을 반환합니다： {258;560;774;801;985;990;1569}。
• COUNT(UNIQUE(A2:A12))=COUNT({258;560;774;801;985;990;1569}): COUNT 함수는 숫자 값의 개수를 세어 결과 7 를 반환합니다。

열에서 한 번만 나타나는 고유한 숫자 값 또는 날짜 개수 세기

이 UNIQUE 함수는 목록에서 정확히 한 번만 나타나는 고유 값을 추출할 수도 있습니다。 일반적인 구문은 다음과 같습니다：

• range： 범위 내 고유 값 수 세기하려는 데이터 열입니다。

결과를 반환할 셀에 다음 수식을 입력하거나 복사한 후Enter키를 누르세요。 스크린샷 참조：

수식 설명：

=COUNT(UNIQUE(A2:A12,0,1))

• UNIQUE(A2:A12,0,1)： UNIQUE 함수는 목록에서 한 번만 나타나는 고유한 값을 추출하여 다음과 같은 배열 목록을 반환합니다： {258;801;985;1569}。
• COUNT(UNIQUE(A2:A12,0,1))=COUNT({258;801;985;1569}): COUNT 함수는 숫자 값의 개수를 세어 결과 4 을 반환합니다。

팁： 위의 모든 수식은 열에서 고유 날짜를 세는 데 사용할 수 있습니다。

사용된 관련 함수：

추가 기사：