대소문자 구분 조회

INDEX 및 MATCH 함수를 결합하거나 VLOOKUP 함수를 사용하여 Excel에서 값을 조회할 수 있다는 것을 알고 있을 것입니다. 그러나 이러한 조회는 대소문자를 구분하지 않습니다. 따라서 대소문자를 구분하는 일치를 수행하려면 EXACT 및 CHOOSE 함수를 활용해야 합니다.

INDEX 및 MATCH로 대소문자 구분 조회 수행하기
VLOOKUP으로 대소문자 구분 조회 수행하기

INDEX 및 MATCH로 대소문자 구분 조회 수행하기

위 스크린샷에 표시된 YUKI의 성적을 INDEX와 MATCH를 사용하여 알아보기 위해, EXACT 함수를 사용하여 학생 이름 범위의 텍스트 문자열을 G5 셀의 값인 YUKI와 비교할 수 있습니다. 이때 각 문자의 대소문자도 포함됩니다. 그런 다음 INDEX와 MATCH 함수를 함께 사용하여 원하는 값을 찾을 수 있습니다.

일반적인 문법

=INDEX(반환_범위,MATCH(TRUE,EXACT(조회_값,조회_범위),0))

√ 참고: 이것은 배열 수식으로 Ctrl + Shift + Enter로 입력해야 합니다.

YUKI의 성적을 확인하려면 아래 수식을 G6 셀에 복사하거나 입력하고, 결과를 얻으려면 Ctrl + Shift + Enter를 누르세요:

=INDEX(D5:D14,MATCH(TRUE,EXACT("YUKI",B5:B14),0))

또는 셀 참조를 사용하여 수식을 동적으로 만들 수 있습니다:

=INDEX(D5:D14,MATCH(TRUE,EXACT(G5,B5:B14),0))

수식 설명

=INDEX(D5:D14,MATCH(TRUE,EXACT("YUKI",B5:B14),0))

• EXACT(G5,B5:B14): EXACT 함수는 학생 이름 범위의 텍스트 문자열을 비교합니다. B5:B14 대상 "YUKI", 셀의 값인 G5와 비교하며, B5부터 B14까지의 셀 중 하나의 값이 YUKI와 정확히 같으면 TRUE를 반환하고 그렇지 않으면 FALSE를 반환합니다. 따라서 다음과 같은 TRUE와 FALSE의 배열을 얻게 됩니다:
  {FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE}
• MATCH(TRUE,MATCH(TRUE,EXACT(G5,B5:B14),0),0) = MATCH(TRUE,MATCH(TRUE,{FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE},0),0): 매치_타입 0은 MATCH 함수가 정확히 일치하는 값을 찾도록 요청합니다. 함수는 배열에서 정확한 조회_값 “TRUE”의 위치를 반환하며, 유일한 TRUE가 배열의 10번째 위치에 있으므로 결과는 10입니다.
• INDEX(D5:D14D5:D14,MATCH(TRUE,EXACT(G5,B5:B14),0)) = INDEX(D5:D14D5:D14,10): INDEX 함수는 성적 범위 D5:D14에서 10번째 값을 반환하며, 그 값은 A입니다.

VLOOKUP으로 대소문자 구분 조회 수행하기

나라에서 JIMMY가 왔는지 VLOOKUP 함수를 사용하여 알아보려면, 대소문자 구분 조회를 수행하기 위해 CHOOSE 및 EXACT 함수를 활용해야 합니다. EXACT 함수는 JIMMY와 학생 이름 범위의 각 텍스트 문자열 간에 대소문자 구분 비교를 수행합니다. 그런 다음 CHOOSE를 사용하여 EXACT의 결과와 국가 범위의 값을 결합할 수 있습니다. 이제 VLOOKUP이 그 능력을 발휘할 차례입니다.

일반적인 문법

=VLOOKUP(TRUE,CHOOSE({1,2},EXACT(조회_값,조회_범위),반환_범위),2,FALSE)

√ 참고: 이것은 배열 수식으로 Ctrl + Shift + Enter로 입력해야 합니다.

JIMMY가 어떤 나라에서 왔는지 확인하려면 아래 수식을 G9 셀에 복사하거나 입력하고, 결과를 얻으려면 Ctrl + Shift + Enter를 누르세요:

=VLOOKUP(TRUE,CHOOSE({1,2},EXACT("JIMMY",B5:B14),C5:C14),2,FALSE)

또는 셀 참조를 사용하여 수식을 동적으로 만들 수 있습니다:

=VLOOKUP(TRUE,CHOOSE({1,2},EXACT(G8,B5:B14),C5:C14),2,FALSE)

수식 설명

=VLOOKUP(TRUE,CHOOSE({1,2},EXACT(G8,B5:B14),C5:C14),2,FALSE)

• EXACT(G8,B5:B14): EXACT 함수는 학생 이름 범위의 텍스트 문자열을 비교합니다. B5:B14 셀의 값인 G8, JIMMY와 비교하며, 학생 이름 범위의 값이 JIMMY와 정확히 같으면 TRUE를 반환하고 그렇지 않으면 FALSE를 반환합니다. 따라서 다음과 같은 TRUE와 FALSE의 배열을 얻게 됩니다:
  {FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE}
• CHOOSE({1,2},EXACT(G8,B5:B14),C5:C14) = CHOOSE({1,2},{FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE},C5:C14): CHOOSE의 인덱스_번호 인수 {1,2} EXACT 배열과 C5:C14 에서 가져온 값을 결합하여 다음과 같은 2차원 배열을 만듭니다:
  {FALSE,"China";FALSE,"England";FALSE,"America";FALSE,"India";TRUE,"America";FALSE,"India";FALSE,"America";FALSE,"China";FALSE,"England";FALSE,"China"}
• VLOOKUP(VLOOKUP(TRUETRUE,,CHOOSE({1,2},EXACT(G8,B5:B14),C5:C14),2,FALSE) = VLOOKUP(VLOOKUP(TRUETRUE,,{FALSE,"China";FALSE,"England";FALSE,"America";FALSE,"India";TRUE,"America";FALSE,"India";FALSE,"America";FALSE,"China";FALSE,"England";FALSE,"China"},2,FALSE): range_lookup FALSE는 VLOOKUP 함수가 2차원 배열의 첫 번째 열에서 정확한 값 “TRUE”를 검색하고 두 번째 열에서 정확히 일치하는 값을 반환하도록 요청합니다. 결과는 America입니다.

관련 기능

관련 수식