특정 도메인에 따라 Outlook에서 이메일 주소를 내보내는 방법은 무엇입니까?

Author: Xiaoyang Last Modified: 2025-08-06

Outlook의 모든 연락처에서 특정 도메인을 가진 이메일 주소를 내보내려면, 아래 스크린샷에 표시된 대로 특정 도메인의 모든 이메일 주소를 텍스트 파일로 추출하기 위해 VBA 코드를 적용하는 데 도움이 될 이 튜토리얼을 읽어보세요.

doc-export-addresses-with-domain-1

VBA 코드를 사용하여 Outlook에서 특정 도메인에 따른 이메일 주소 내보내기

모든 연락처에서 특정 도메인을 가진 모든 이메일 주소를 추출하려면 다음 단계를 따르세요:

1. 새 텍스트 파일을 만들고 이름을 지정하세요. 스크린샷을 참조하세요:

doc-export-addresses-with-domain-2

2. "ALT + F11" 키를 눌러 "Microsoft Visual Basic for Applications" 창을 엽니다.

3. 그런 다음, "삽입" > "모듈"을 클릭하고 모듈 창에 다음 코드를 붙여넣으세요.

"VBA 코드: 특정 도메인에 따른 이메일 주소 내보내기"

Dim GDomain As String
Dim GFileSystem As Object
Dim GFilePath As String
Dim GFileObj As Object
Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal ipOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub ExportListOfEmailAddressesInSpecificDomain()
'Updateby ExtendOffice
Dim xStore As Store
Dim xFolder As Folder
On Error Resume Next
GDomain = InputBox("Enter domain(@***.com):", "Kutools for Outlook")
If Len(GDomain) <> 0 Then
  GFilePath = "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" 'Specify the file path
  Set GFileSystem = CreateObject("Scripting.FileSystemObject")
  Set GFileObj = GFileSystem.CreateTextFile(GFilePath, True)
  For Each xStore In Application.Session.Stores
    For Each xFolder In xStore.GetRootFolder.Folders
      If xFolder.DefaultItemType = olContactItem Then
        Call ProcessFolders(xFolder)
      End If
    Next
  Next
  GFileObj.Close
  ShellExecute 0&, vbNullString, GFilePath, vbNullString, vbNullString, 1
End If
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim xContactItems As Items
Dim I As Long
Dim xContact As ContactItem
Dim xSubFolder As Folder
On Error Resume Next
Set xContactItems = Fld.Items
For I = xContactItems.Count To 1 Step -1
  If xContactItems(I).Class = olContact Then
    Set xContact = xContactItems(I)
    If InStr(xContact.Email1Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email1Address & vbCrLf)
    ElseIf InStr(xContact.Email2Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email2Address & vbCrLf)
    ElseIf InStr(xContact.Email3Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email3Address & vbCrLf)
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    If xSubFolder.DefaultItemType = olContactItem Then
      Call ProcessFolders(xSubFolder)
    End If
  Next
End If
End Sub

참고: 위의 코드에서 파일 경로 "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt"를 사용자 자신의 것으로 변경하세요.

doc-export-addresses-with-domain-4