Excel 에서 Outlook 캘린더로 생일을 가져오는 방법은 무엇입니까？

워크시트에 생일 정보가 긴 목록으로 저장되어 있고， 이를 Outlook 캘린더의 일정으로 가져오고자 한다면， 이 작업을 빠르게 처리할 수 있는 방법은 무엇입니까？

---

VBA 코드를 사용하여 Excel 에서 Outlook 캘린더로 생일 가져오기

일반적으로 생일을 Outlook 캘린더로 직접 가져오는 방법은 없으므로， 이 문제를 해결하기 위해 VBA 코드를 작성하겠습니다。 다음 단계에 따라 진행하세요：

1. Outlook 으로 가져오려는 생일이 포함된 워크시트를 열고，ALT + F11키를 누른 상태로Microsoft Visual Basic for Applications창을 엽니다。

2.삽입(Insert)>모듈(Module)을 클릭한 후， 모듈 창에 다음 코드를 붙여넣습니다。

VBA 코드： Outlook 캘린더로 생일 가져오기

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3。 여전히Microsoft Visual Basic for Applications창에서，도구(Tools)>참조(References)를 클릭합니다。 나타난참조 – VBAProject(References – VBAProject)대화상자에서Microsoft Outlook 16.0 Object Library옵션을사용 가능한 참조(Available References)목록 상자에서 선택합니다。 스크린샷 참조：

4。 그런 다음확인(OK)을 클릭하여 이 대화상자를 닫습니다。 이제F5키를 눌러 코드를 실행하면 프롬프트 상자가 나타나며， 이름과 생일 열을 선택하세요 선택하라는 안내가 표시됩니다。 스크린샷 참조：

5。 이후확인(OK)버튼을 클릭하면 생일이 즉시 Outlook 캘린더로 가져옵니다. Outlook 을 실행하여 결과를 확인할 수 있습니다。 스크린샷 참조：