Outlook 에서 보낸 회의 초대를 특정 폴더로 자동 이동하는 방법은 무엇인가요？

일반적으로 이메일이나 회의 초대를 보내면 둘 다 보낸 편지함 폴더에 저장됩니다。 따라서 보낸 편지함 폴더는 상당히 지저분하고 관리하기 번거로워집니다。 이 문서에서는 회의 초대를 보내면 자동으로 다른 폴더로 이동시키는 방법을 소개합니다。

VBA 코드를 사용하여 보낸 회의 초대를 특정 폴더로 자동 이동하기

---

VBA 코드를 사용하여 보낸 회의 초대를 특정 폴더로 자동 이동하기

보낸 모든 회의 초대를 자동으로 다른 폴더로 이동하려면 다음 코드를 사용할 수 있습니다。 아래 단계를 따라 주세요：

1.ALT + F11키를 누른 채로Microsoft Visual Basic for Applications창을 엽니다。

2.Microsoft Visual Basic for Applications창에서ThisOutlookSession을(를)Project1(VbaProject.OTM)패널에서 두 번 클릭하여 모듈을 열고， 다음 코드를 빈 모듈에 복사하여 붙여넣습니다。

VBA 코드： 보낸 회의 초대를 특정 폴더로 자동 이동하기

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

3。 그런 다음 코드 창을 저장하고 닫기 합니다。 이제 회의 이메일을 보내면 자동으로 보낸 편지함 폴더 아래에 있는Meetings이라는 이름의새 폴더폴더로 이동됩니다。 스크린샷 참조：