Outlook 의 보낸 편지함 폴더에서 일반적으로 회신하려면 어떻게 해야 하나요？

일반적으로 보낸 편지함 폴더에서 ‘회신’ 기능을 클릭하여 이미 보낸 사람에게 추가 메시지를 보내려고 하면, 다음 스크린샷과 같이 귀하의 이메일 주소 주소가 받는 사람(To) 필드에 표시됩니다. 매번 주소를 변경해야 해서 불편할 수 있습니다. Outlook 이 내 주소가 아닌 원래 수신자의 주소를 사용하도록 하려면 어떻게 해야 할까요？

Outlook 에서 보낸 편지함 폴더의 ‘모두 회신(Reply All)’ 기능으로 일반적으로 회신하기

Outlook 에서 VBA 코드로 보낸 편지함 폴더에서 일반적으로 회신하기

---

Outlook 에서 보낸 편지함 폴더의 ‘모두 회신(Reply All)’ 기능으로 일반적으로 회신하기

Outlook 에서는모두 회신(Reply All)기능을 사용해 이 문제를 해결할 수 있습니다。 다음 단계를 따르세요：

보낸 이메일을 다시 보내 원래 수신자의 주소를 유지해야 할 경우，모두 회신(Reply All)버튼을 클릭하세요。 그러면 다음 스크린샷과 같이 원래 수신자의 주소가받는 사람(To)필드에 표시됩니다。

---

Outlook 에서 VBA 코드로 보낸 편지함 폴더에서 일반적으로 회신하기

보낸 메시지에 회신할 때모두 회신(Reply All)기능을 잊어버릴 수도 있습니다。 아래 VBA 코드를 사용하면 ‘회신(Reply)’ 기능으로도 보낸 편지함 폴더에서 일반적으로 회신할 수 있습니다。 다음 단계를 따라 진행하세요：

1.ALT + F11키를 누른 채로Microsoft Visual Basic for Applications창을 엽니다。

2.Microsoft Visual Basic for Applications창에서 왼쪽Project1(VbaProject.OTM)패널의ThisOutlookSession항목을 두 번 클릭하여 모듈을 열고， 다음 코드를 빈 모듈에 복사하여 붙여넣습니다。

VBA 코드: Outlook 에서 보낸 편지함 폴더에서 일반적으로 회신하기：

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. 그런 다음 코드를 저장하고 Outlook 을 다시 시작하여 코드를 적용합니다。 이제회신(Reply)버튼을 클릭해보낸 편지함폴더에서 이메일을 재전송하면， 원래 수신자의 주소가 필요하신 대로 받는 사람(To) 필드에 표시됩니다。