Outlook 에서 범주별로 작업을 인쇄하는 방법은 무엇인가요？

Outlook 작업에 다양한 색상 범주가 있고, 이제 각 범주별로 작업 목록을 서로 다른 페이지에 인쇄하려고 한다면, Outlook 에서 이 작업을 어떻게 해결할 수 있을까요？

범주별로 작업을 수동으로 하나씩 다른 페이지에 인쇄하기

VBA 코드를 사용하여 범주별로 작업을 다른 페이지에 인쇄하기

---

범주별로 작업을 수동으로 하나씩 다른 페이지에 인쇄하기

Outlook 에서는 서로 다른 범주에 따라 작업을 수동으로 하나씩 다른 페이지에 인쇄할 수 있습니다。 다음 단계를 따르세요：

1. Outlook 을 실행하고 작업 창으로 이동하여 인쇄하려는 작업 폴더를 선택한 후Ctrl + E를 눌러검색상자를 활성화합니다。 그런 다음검색탭에서범주 지정됨아이콘을 클릭하고 인쇄할 색상 범주를 하나 선택하세요(스크린샷 참조)：

2。 그러면 해당 색상 범주가 지정된 모든 작업이 한 번에 표시됩니다(스크린샷 참조)：

3。 그런 다음파일>인쇄를 차례로 클릭하여 아래 스크린샷과 같이 이 작업 목록을 인쇄합니다：

4. 위 단계를 반복하여 다른 색상 범주에 해당하는 작업 목록을 수동으로 하나씩 인쇄하세요。

---

VBA 코드를 사용하여 범주별로 작업을 다른 페이지에 인쇄하기

다음 VBA 코드를 사용하면 범주별로 작업을 한 번에 다른 페이지에 인쇄할 수 있습니다。 다음 단계를 따라 진행하세요：

1.작업창으로 이동하여 인쇄하려는 작업 폴더를 선택합니다。

2。 그런 다음ALT + F11키를 누르고 있어Microsoft Visual Basic for Applications창을 엽니다。

3。 그 후삽입>모듈을 클릭하고， 아래 코드를 열린 빈 모듈에 복사하여 붙여넣습니다：

VBA 코드： 범주별로 작업을 다른 페이지에 인쇄하기：

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4。 그런 다음도구>참조를 클릭합니다。Microsoft Visual Basic for Applications창에서 나타난참조-Project1대화 상자에서Microsoft Excel Object Library및Microsoft Scripting Runtime옵션을사용 가능한 참조목록 상자에서 선택하세요(스크린샷 참조)：

5。 그런 다음확인버튼을 클릭하고， 이제F5키를 눌러 이 코드를 실행합니다。 코드 실행이 완료되면 서로 다른 범주에 해당하는 작업 목록이 각각 다른 페이지에 인쇄됩니다。