Outlook 에서 특정 첨부 파일을 기준으로 이메일을 자동으로 플래그하는 방법은 무엇인가요？

특정 중요 첨부 파일이 포함된 이메일을 수신할 때 해당 이메일을 플래그하여 나중에 후속 조치를 위해 빠르고 쉽게 찾을 수 있도록 해야 할 수도 있습니다。 이 글에서는 첨부 파일 이름이 특정 조건을 충족하는 이메일을 자동으로 플래그하는 간단한 방법을 소개합니다。

VBA 코드를 사용하여 특정 첨부 파일 기반으로 이메일 자동 플래그하기

---

VBA 코드를 사용하여 특정 첨부 파일 기반으로 이메일 자동 플래그하기

특정 첨부 파일이 포함된 이메일을 자동으로 플래그하려면 다음 VBA 코드를 적용하세요：

1. Outlook 을 실행한 후 「ALT + F11」 키를 눌러 「Microsoft Visual Basic for Applications」 창을 엽니다。

2. 「Microsoft Visual Basic for Applications」 창에서 “Project1(VbaProject.OTM)“ 패널의 「ThisOutlookSession」을 두 번 클릭하여 새 모듈을 열고， 다음 코드를 복사하여 빈 모듈에 붙여넣습니다。

VBA 코드： 특정 첨부 파일을 기준으로 이메일 자동 플래그하기：

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

참고： 위 코드에서 파일 확장자와 첨부 파일 이름을 필요에 따라 변경할 수 있습니다。

3. 그런 다음 코드를 저장하고 Outlook 을 다시 시작하여 코드를 적용합니다. 이제 첨부 파일 이름에 지정된 텍스트가 포함된 이메일을 수신하면 Outlook 이 자동으로 해당 이메일을 후속 조치용으로 플래그합니다。 스크린샷 참조：