Outlook에서 Excel로 폴더 구조를 내보내는 방법은 무엇입니까?

Author: Xiaoyang Last Modified: 2025-08-06

이 문서에서는 Outlook에서 계정의 폴더 구조를 Excel 파일로 내보내는 방법을 소개하겠습니다. 이 문서의 세부 정보를 통해 이를 수행해 주세요.

VBA 코드를 사용하여 Outlook에서 계정의 폴더 구조를 Excel로 내보내기

VBA 코드를 사용하여 Outlook에서 계정의 폴더 구조를 Excel로 내보내기

다음 VBA 코드가 도움이 될 수 있습니다. 아래 단계에 따라 진행하세요:

1. Excel을 활성화하고 ALT + F11 키를 누른 상태에서 Microsoft Visual Basic for Applications 창을 엽니다.

2. 삽입 > 모듈을 클릭하고, 모듈 창에 다음 코드를 붙여넣습니다.

VBA 코드: Outlook에서 계정의 폴더 구조를 Excel로 내보내기:

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3. 여전히 Microsoft Visual Basic for Applications 창에서 도구 > 참조를 클릭하여 References-Project1 대화 상자로 이동한 후, 사용 가능한 참조 목록 상자에서 Microsoft Excel Object Library 옵션을 선택합니다. 스크린샷 참고: