Excel 데이터에서 약속 일정을 어떻게 생성하나요？

다음 스크린샷과 같이 Excel 워크시트에 약속 일정 데이터 테이블이 있고， 이 데이터를 Outlook 캘린더로 가져오려고 한다면， 이 작업을 어떻게 빠르게 처리할 수 있을까요？

VBA 코드로 Excel 데이터에서 약속 일정 생성하기

---

VBA 코드로 Excel 데이터에서 약속 일정 생성하기

Excel 데이터에서 약속 일정을 생성하려면 다음 VBA 코드를 적용하세요。 아래 단계대로 진행해 주세요：

1. Outlook 을 실행한 후ALT + F11키를 누른 상태로Microsoft Visual Basic for Applications창을 엽니다。

2.삽입(Insert)>모듈(Module)을 클릭하고， 다음 코드를모듈(Module)창에 붙여넣습니다。

VBA 코드： Excel 데이터를 약속 일정으로 가져오기：

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3。 여전히Microsoft Visual Basic for Applications창에서，도구(Tools)>참조(References)를 클릭하여참조-Project1(References-Project1)대화상자로 이동한 후，Microsoft Excel Object Library옵션을사용 가능한 참조(Available References)목록 상자에서 선택합니다。 스크린샷 참조：

4。 그런 다음확인(OK)버튼을 클릭하고， 이제F5키를 눌러 이 코드를 실행합니다。 그러면파일 선택(Select a file)창이 표시되며, Outlook 으로 가져올 Excel 파일을 선택하세요 합니다。 스크린샷 참조：

5.그리고 나서확인(OK)를 클릭하면 다음과 같은 알림 창이 나타납니다：

6。 그런 다음확인(OK)을 클릭하면 Excel 데이터가 다음 스크린샷과 같이 캘린더에 가져와집니다：