Outlook에서 메시지 또는 작업 내의 제목 텍스트를 찾아 바꾸는 방법은 무엇입니까?

Author: Xiaoyang Last Modified: 2025-08-06

Outlook에서 여러 메시지 제목이나 작업 제목을 지정한 텍스트로 바꿔야 하는 경우, 물론 하나씩 변경할 수 있지만, Outlook에서 이 작업을 한 번에 끝낼 수 있는 빠른 방법이 있을까요?

VBA 코드를 사용하여 여러 메시지 내의 제목 텍스트 찾기 및 바꾸기

VBA 코드를 사용하여 여러 작업 내의 제목 텍스트 찾기 및 바꾸기

VBA 코드를 사용하여 여러 메시지 내의 제목 텍스트 찾기 및 바꾸기

여러 메시지 제목에서 특정 텍스트를 찾아 다른 것으로 바꾸려면 아래 VBA 코드가 도움이 될 수 있습니다. 다음 단계를 따르세요:

1. 제목 텍스트를 찾고 바꾸려는 이메일을 선택하고, "ALT + F11" 키를 눌러 "Microsoft Visual Basic for Applications" 창을 엽니다.

2. 그런 다음, "삽입" > "모듈"을 클릭하고, 열린 빈 모듈에 아래 코드를 복사하여 붙여넣으세요. 스크린샷을 참조하세요:

VBA 코드: 여러 메시지 내의 제목 텍스트 찾기 및 바꾸기:

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

참고: 위 코드에서 xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")에서 "kte"는 찾으려는 이전 텍스트이고, "Kutools for Excel"은 바꿀 새 텍스트입니다. 필요에 따라 이를 변경하세요.

3. 그런 다음 "F5" 키를 눌러 이 코드를 실행하면, 메시지 제목의 특정 텍스트가 필요한 새 텍스트로 바뀝니다. 스크린샷을 참조하세요:

VBA 코드를 사용하여 여러 작업 내의 제목 텍스트 찾기 및 바꾸기

작업 내의 제목 텍스트를 찾아 바꿔야 하는 경우, 다음 VBA 코드도 도움이 될 수 있습니다.

1. "ALT + F11" 키를 눌러 "Microsoft Visual Basic for Applications" 창을 엽니다.

2. 그런 다음, "삽입" > "모듈"을 클릭하고, 열린 빈 모듈에 아래 코드를 복사하여 붙여넣으세요. 스크린샷을 참조하세요:

VBA 코드: 모든 작업 내의 제목 텍스트 찾기 및 바꾸기:

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. 그런 다음 "F5" 키를 눌러 이 코드를 실행하면, 작업 제목에서 찾으려는 텍스트를 입력하라는 프롬프트 상자가 나타납니다. 스크린샷을 참조하세요: