Outlook 에서 이메일 메시지를 그림 형식(jpg/tiff)으로 저장하는 방법은 무엇인가요？

Outlook 에서 이메일 메시지를 jpg 또는 tiff 와 같은 그림 형식으로 저장해 보신 적이 있나요？ 이 문서에서는 이 문제를 해결할 수 있는 방법을 안내해 드립니다。

VBA 코드로 이메일 메시지를 그림 형식으로 저장하기

---

VBA 코드로 이메일 메시지를 그림 형식으로 저장하기

Outlook 에서 이메일 메시지를 그림 형식으로 저장하려면 다음 단계를 따르세요。

1. 그림으로 저장할 이메일을 선택한 후Alt+F11키를 동시에 눌러Microsoft Visual Basic for Applications창을 엽니다。

2. Microsoft Visual Basic for Applications창에서삽입>사용자 폼을 클릭하세요。 스크린샷 참조：

3. 아래 스크린샷과 같이사용자 폼을 만듭니다。

4. jpg 옵션버튼을 선택하고 왼쪽opbJPG으로 이름을 변경합니다。 이름은속성패널에서 변경하세요。

5. 위 단계를 반복하여 다른 옵션 버튼의 이름을opbTIFF로 변경하세요。 또한확인명령 단추와취소명령 단추의 이름을 각각cdbOk및cdbCancel으로 변경합니다。

참고:속성패널이Microsoft Visual Basic for Applications창에 표시되지 않으면F4키를 눌러 패널을 표시하세요。

6. 사용자 폼의 빈 공간을 두 번 클릭하여코드창을 엽니다。 기존 코드를 모두 삭제하고 다음 VBA 스크립트로 교체한 후 코드 창을 닫습니다。

VBA 코드 1: 이메일 메시지를 그림으로 저장하기

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. UserForm1을 선택하고 아래 스크린샷과 같이FrmPicType으로 이름을 변경합니다。 이름은속성패널에서 변경하세요。

8. 삽입>모듈을 클릭한 후 아래 VBA 코드를 모듈 창에 복사합니다。

VBA 코드 2: 이메일 메시지를 그림으로 저장하기

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. 도구>참조를 클릭하고Microsoft PowerPoint Object Library확인란을 선택한 후확인버튼을 클릭합니다。 스크린샷 참조：

10. F5키를 눌러 코드를 실행합니다。 그러면UserForm1대화 상자가 나타나며， 선택하세요 그림 형식을 선택한 후확인버튼을 클릭합니다。 스크린샷 참조：

11. 폴더 찾아보기대화 상자에서 그림을 저장할 폴더를 지정한 후확인버튼을 클릭합니다。

12. 마지막으로Microsoft Outlook대화 상자가 저장이 완료되었음을 알려줍니다。확인버튼을 클릭하세요。

이제 선택한 이메일이 jpg 또는 tiff 그림으로 변환되어 지정된 폴더에 성공적으로 저장되었습니다。

---

관련 문서：

• Outlook 에서 여러 이메일의 모든 첨부 파일을 폴더에 저장하는 방법은 무엇인가요？
• Outlook 에서 이메일의 모든 첨부 파일을 제거하는 방법은 무엇인가요？