Outlook에서 폴더 이름으로 폴더(전체 폴더 경로)를 찾는 방법은 무엇인가요?

아래 단계를 따라 Outlook에서 VBA를 사용하여 폴더 이름으로 폴더를 검색하세요.

1. "Alt" + "F11" 키를 동시에 눌러 "Microsoft Visual Basic for Applications" 창을 엽니다.

2. "삽입" > "모듈"을 클릭한 다음 아래 VBA 코드를 새 모듈 창에 붙여넣습니다.

VBA: Outlook에서 폴더 이름으로 폴더 검색 및 열기

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. "F5" 키를 누르거나 "실행" 버튼을 클릭하여 이 VBA를 실행합니다.

4. 나타나는 "폴더 검색" 대화 상자에서 검색할 폴더 이름을 입력하고 "확인" 버튼을 클릭하세요.

참고: 이 VBA는 와일드카드(*)를 지원합니다. 예를 들어, tes*를 입력하면 이름이 tes로 시작하는 모든 폴더를 찾을 수 있습니다.

5. 이제 대화 상자가 나타나며, 찾은 폴더의 경로를 보여줍니다. 찾은 폴더를 열려면 "예" 버튼을 클릭하세요.

다음 스크린샷과 같이 지금 찾은 폴더가 탐색 창에서 열립니다:

참고: 동일한 이름을 가진 폴더가 여러 개 있는 경우, 이 VBA는 하나의 폴더만 찾고 열 수 있습니다.

Kutools for Outlook이 설치되어 있다면, "폴더 열기" 기능을 사용하여 특정 폴더 이름으로 모든 폴더를 빠르게 찾고, 쉽게 열 수도 있습니다.

1. "Kutools Plus" > "폴더 열기"를 클릭하여 이 기능을 활성화합니다.

2. "폴더 열기" 대화 상자에서 "검색" 상자에 지정된 폴더 이름을 입력하고, 검색 결과에서 폴더를 선택한 후 "확인" 버튼을 클릭하세요.

이제 지정된 이름의 폴더가 즉시 찾아지고 열립니다.