Outlook 에서 여러 폴더/하위 폴더의 이메일을 Excel 로 내보내는 방법은？

여러 폴더나 하위 폴더에서 이메일을 Excel 로 내보내는 작업은 수동 방식이나 제한된 Outlook 기능에 의존할 경우 매우 번거로울 수 있습니다. 다행히도 이를 더 효율적으로 수행할 수 있는 방법들이 있습니다. 이 글에서는 VBA 기반 방법과 Kutools for Outlook 를 활용한 빠르고 사용자 친화적인 해결책이라는 두 가지 방법을 소개합니다. VBA 방법은 유연성이 있지만 복잡한 설정과 코드 조정이 필요합니다. 반면 Kutools for Outlook 는 몇 번의 클릭만으로 이메일을 Excel 로 내보낼 수 있는 간편하고 강력한 방법을 제공하여 시간과 노력을 절약해 줍니다。 이제 자세히 살펴보겠습니다。

VBA 를 사용하여 여러 폴더/하위 폴더에서 이메일을 Excel 로 내보내기(복잡하지만 유연함)

Kutools for Outlook 를 사용하여 폴더/하위 폴더에서 이메일을 Excel 로 내보내기 👍(효율적이고 사용자 친화적)

---

VBA 를 사용하여 여러 폴더/하위 폴더에서 이메일을 Excel 로 내보내기

코딩에 익숙하고 맞춤형 솔루션이 필요한 경우 VBA 를 사용하는 것이 효과적일 수 있습니다。 이 방법을 통해 여러 폴더나 하위 폴더를 지정하고 해당 이메일을 개별 Excel 파일로 내보낼 수 있습니다。 다만 기술적 지식과 신중한 코드 사용자 정의가 필요합니다。

단계 1: VBA 편집기 열기

"Alt+F11「 키를 눌러 」Microsoft Visual Basic for Applications“ 창을 실행하세요。

단계 2: 새 모듈 삽입하기

「삽입(Insert)」 > 「모듈(Module)」을 클릭한 후 아래 VBA 코드를 새 모듈 창에 붙여넣으세요。

VBA: 여러 폴더 및 하위 폴더에서 이메일을 Excel 로 내보내기

Const MACRO_NAME = "Export Outlook Folders to Excel"
Sub ExportMain()
ExportToExcel "destination_folder_path\A.xlsx", "your_email_account\folder\subfolder_1"
ExportToExcel "destination_folder_path\B.xlsx", "your_email_account\folder\subfolder_2"
MsgBox "Process complete.", vbInformation + vbOKOnly, MACRO_NAME
End Sub

Sub ExportToExcel(strFilename As String, strFolderPath As String)
Dim olkMsg As Object
Dim olkFld As Object
Dim excApp As Object
Dim excWkb As Object
Dim excWks As Object
Dim intRow As Integer
Dim intVersion As Integer

If strFilename <> "" Then
If strFolderPath <> "" Then
Set olkFld = OpenOutlookFolder(strFolderPath)
If TypeName(olkFld) <> "Nothing" Then
intVersion = GetOutlookVersion()
Set excApp = CreateObject("Excel.Application")
Set excWkb = excApp.Workbooks.Add()
Set excWks = excWkb.ActiveSheet
With excWks
.Cells(1, 1) = "Subject"
.Cells(1, 2) = "Received"
.Cells(1, 3) = "Sender"
End With
intRow = 2
For Each olkMsg In olkFld.Items
If olkMsg.Class = olMail Then
excWks.Cells(intRow, 1) = olkMsg.Subject
excWks.Cells(intRow, 2) = olkMsg.ReceivedTime
excWks.Cells(intRow, 3) = GetSMTPAddress(olkMsg, intVersion)
intRow = intRow + 1
End If
Next
Set olkMsg = Nothing
excWkb.SaveAs strFilename
excWkb.Close
Else
MsgBox "The folder '" & strFolderPath & "' does not exist in Outlook.", vbCritical + vbOKOnly, MACRO_NAME
End If
Else
MsgBox "The folder path was empty.", vbCritical + vbOKOnly, MACRO_NAME
End If
Else
MsgBox "The filename was empty.", vbCritical + vbOKOnly, MACRO_NAME
End If

Set olkMsg = Nothing
Set olkFld = Nothing
Set excWks = Nothing
Set excWkb = Nothing
Set excApp = Nothing
End Sub

Public Function OpenOutlookFolder(strFolderPath As String) As Outlook.MAPIFolder
Dim arrFolders As Variant
Dim varFolder As Variant
Dim bolBeyondRoot As Boolean

On Error Resume Next
If strFolderPath = "" Then
Set OpenOutlookFolder = Nothing
Else
Do While Left(strFolderPath, 1) = "\"
strFolderPath = Right(strFolderPath, Len(strFolderPath) - 1)
Loop
arrFolders = Split(strFolderPath, "\")
For Each varFolder In arrFolders
Select Case bolBeyondRoot
Case False
Set OpenOutlookFolder = Outlook.Session.Folders(varFolder)
bolBeyondRoot = True
Case True
Set OpenOutlookFolder = OpenOutlookFolder.Folders(varFolder)
End Select
If Err.Number <> 0 Then
Set OpenOutlookFolder = Nothing
Exit For
End If
Next
End If
On Error GoTo 0
End Function

Function GetSMTPAddress(Item As Outlook.MailItem, intOutlookVersion As Integer) As String
Dim olkSnd As Outlook.AddressEntry
Dim olkEnt As Object

On Error Resume Next
Select Case intOutlookVersion
Case Is < 14
If Item.SenderEmailType = "EX" Then
GetSMTPAddress = SMTPEX(Item)
Else
GetSMTPAddress = Item.SenderEmailAddress
End If
Case Else
Set olkSnd = Item.Sender
If olkSnd.AddressEntryUserType = olExchangeUserAddressEntry Then
Set olkEnt = olkSnd.GetExchangeUser
GetSMTPAddress = olkEnt.PrimarySmtpAddress
Else
GetSMTPAddress = Item.SenderEmailAddress
End If
End Select
On Error GoTo 0
Set olkSnd = Nothing
Set olkEnt = Nothing
End Function

Function GetOutlookVersion() As Integer
Dim arrVer As Variant
arrVer = Split(Outlook.Version, ".")
GetOutlookVersion = arrVer(0)
End Function

Function SMTPEX(olkMsg As Outlook.MailItem) As String
Dim olkPA As Outlook.propertyAccessor
On Error Resume Next
Set olkPA = olkMsg.propertyAccessor
SMTPEX = olkPA.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x5D01001E")
On Error GoTo 0
Set olkPA = Nothing
End Function

단계 3: VBA 코드 사용자 정의하기

1. 위 코드에서 “destination_folder_path「를 실제 파일 경로로 바꾸세요. 예: 」C:\Users\DT168\Documents\TEST".
2. "your_email_account\folder\subfolder_1「 및 」your_email_account\folder\subfolder_2「를 사용자의 Outlook 파일 경로으로 변경하세요. 예: 」Kelly@extendoffice.com\Inbox\A「 및 」Kelly@extendoffice.com\Inbox\B".
   

단계 4: 코드 실행하기

“F5" 키를 누르거나 「실행(Run)」 버튼을 클릭하여 코드를 실행하세요。 그런 다음 나타나는 「Export Outlook Folders to Excel」 대화 상자에서 「확인(OK)」 버튼을 클릭하세요。 이제 지정된 모든 폴더/하위 폴더의 이메일이 Excel 통합 문서로 내보내졌습니다。

---

---

Kutools for Outlook 를 사용하여 폴더/하위 폴더에서 이메일을 Excel 로 내보내기 👍

더 빠르고 번거롭지 않은 방법으로 「Kutools for Outlook」의 「선택한 이메일을 다양한 형식의 파일로 저장(Save Selected Emails as Files in Various Formats)」 기능을 활용할 수 있습니다. 이 방법은 간편함, 속도, 다재다능함 덕분에 강력히 추천됩니다. 소량의 이메일이든 대규모 데이터셋이든 Kutools 는 최소한의 노력으로 원활한 경험을 보장합니다。

단계 1: 폴더 또는 하위 폴더 선택하기

내보낼 이메일이 포함된 폴더 또는 하위 폴더로 이동하세요。 목록의 모든 이메일을 선택하려면Ctrl+A키를 누르세요。

단계 2: 다양한 형식의 파일로 선택한 이메일 저장 기능 접근하기

「Kutools」 > 「대량 처리」 > 「Save Selected Emails as Files in Various Formats」를 클릭하세요。

단계 3: 내보내기 설정 구성하기

1. 「이메일을 다른 파일로 저장」 대화 상자에서 파일을 저장할 대상 폴더를 선택하세요。
2. 「Excel 형식」 옵션을 선택하세요。
3. 「저장 내용」 섹션에서 내보낼 특정 이메일 내용(예： 헤더， 본문)을 선택하세요。
   

단계 4: 내보내기 완료하기

「확인(OK)」을 클릭하여 내보내기 프로세스를 시작하세요。 완료되면 지정된 폴더에 모든 이메일이 개별 Excel 파일로 저장되어 있습니다。