Outlook 캘린더에서 약속 일정 제목을 검색하고 바꾸는 방법은 무엇인가요？

찾기 및 바꾸기 Outlook 캘린더에서 약속 일정 제목을 대량으로 동일한 텍스트로 교체해야 할 때 유용합니다. 또는 Outlook 으로 데이터를 가져온 후 제목 필드에 있는 『Copy』라는 단어를 교체할 때도 사용할 수 있습니다。 이 문서에서는 여러 약속 일정 제목을 검색하고 교체할 수 있는 VBA 코드를 제공합니다。 자세한 내용은 아래를 참조하세요。

VBA 코드로 약속 일정 제목 검색 및 교체하기

---

VBA 코드로 약속 일정 제목 검색 및 교체하기

이 섹션에서는 다음과 같이 VBA 코드를 사용하여 약속 일정 제목을 검색하고 교체할 수 있습니다。

1. 먼저 Outlook 에서 매크로 설정을 낮음으로 변경해야 합니다。

1) Outlook 2010 및 2013 에서는 「파일」 > 「옵션」을 클릭합니다。 「Outlook 옵션」 대화 상자에서 왼쪽 창의 「신뢰 센터」를 클릭한 다음， 「신뢰 센터 설정」 버튼을 클릭합니다。

「신뢰 센터」 대화 상자에서 왼쪽 창의 「매크로 설정」을 클릭하고， 「매크로 설정」 섹션에서 「모든 매크로 사용」 옵션을 선택한 후 「확인」 버튼을 클릭합니다。 스크린샷 참조：

2) Outlook 2007 에서는 「도구」 > 「신뢰 센터」를 클릭합니다。 「신뢰 센터」 대화 상자에서 왼쪽 창의 「매크로 설정」을 클릭하고， 「매크로에 대한 보안 검사 없음」 옵션을 선택한 후 「확인」 버튼을 클릭합니다。

2. 「Alt」 + “F11" 키를 눌러 「Microsoft Visual Basic for Applications」 창을 엽니다。

3. 「Microsoft Visual Basic for Applications」 창에서 “Project1" > 「Microsoft Outlook 개체」 > 「ThisOutlookSession」을 두 번 클릭하여 VBA 편집기를 엽니다。 스크린샷 참조：

4. 다음 VBA 코드를 복사하여 VBA 편집기에 붙여넣고， “F5" 키를 눌러 코드를 실행합니다。

VBA： 찾기 및 바꾸기 약속 일정 제목

Sub FindReplaceAppointment()
    Dim oApp As Outlook.Application
    Dim oCalFolder As Outlook.MAPIFolder
    Dim oAppt As Outlook.AppointmentItem
    Dim sOldText As String
    Dim sNewText As String
    Dim iCalChangedCount As Integer
    Set oApp = Outlook.Application
    MsgBox ("This script will perform a find/replace in the subject line of all appointments in a specified calendar.")
    sOldText = InputBox("What is the text string that you would like to replace?")
    sNewText = InputBox("With what would you like to replace it?")
    ' Check to be sure a Calendar folder was selected
    Do
    If Not (oCalFolder Is Nothing) Then
        If (oCalFolder.DefaultItemType = olAppointmentItem) Then Exit Do
    End If
    MsgBox ("Please select a calendar folder from the following list.")
    Set oCalFolder = Application.Session.PickFolder
    On Error GoTo ErrHandler:
    Loop Until oCalFolder.DefaultItemType = olAppointmentItem
    ' Loop through appointments in calendar, change text where necessary, keep count
    iCalChangedCount = 0
    For Each oAppt In oCalFolder.Items
        If InStr(oAppt.Subject, sOldText) <> 0 Then
            Debug.Print "Changed: " & oAppt.Subject & " - " & oAppt.Start
            oAppt.Subject = Replace(oAppt.Subject, sOldText, sNewText)
            oAppt.Save
            iCalChangedCount = iCalChangedCount + 1
        End If
    Next
    ' Display results and clear table
    MsgBox (iCalChangedCount & " appointments had text in their subjects changed from '" & sOldText & "' to '" & sNewText & "'.")
    Set oAppt = Nothing
    Set oCalFolder = Nothing
Exit Sub
ErrHandler:
    MsgBox ("Macro terminated.")
End Sub

5. 코드 실행 후 「Microsoft Outlook」 대화 상자가 나타납니다。 「확인」 버튼을 클릭하세요。

6. 두 번째 「Microsoft Outlook」 대화 상자에서 교체할 텍스트를 입력한 후 「확인」 버튼을 클릭합니다。

7. 세 번째 「Microsoft Outlook」 대화 상자에서 교체할 새 텍스트를 입력하고 「확인」을 클릭합니다。

참고： 지정된 캘린더에서 제목의 모든 “Copy” 단어만 제거하려면 이 상자를 비워 두세요。

8. 아래 대화 상자에서 「확인」 버튼을 클릭합니다。

9. 「폴더 선택」 대화 상자에서 지정된 이메일 계정 아래의 캘린더를 선택한 후 「확인」 버튼을 클릭합니다。 스크린샷 참조：

10. 이후 교체가 성공적으로 완료되었다는 대화 상자가 나타납니다。 「확인」 버튼을 클릭하세요。

11. 이제 선택한 캘린더의 모든 제목 텍스트가 새 내용으로 교체되었습니다。