Outlook 에서 폴더 목록을 가져오는 방법은 무엇입니까？

작업 중에 Outlook 사용자에게 탐색의 모든 메일 폴더(사용자가 만든 개인 폴더 포함)로 구성된 트리 구조가 도움이 될 때가 있습니다。 전체 트리 구조의 폴더를 빠르게 나열하려면 VBA 코드를 사용할 수 있습니다。 이 자습서에서는 VBA 코드를 사용해 폴더 목록을 쉽게 가져오는 방법을 배울 수 있습니다。

VBA 코드로 Outlook 에서 폴더 목록 가져오기

---

VBA 코드로 Outlook 에서 폴더 목록 가져오기

VBA 코드를 사용해 Outlook 에서 폴더 목록을 가져오려면 다음 단계를 따르십시오。

1. 키보드에서 「Alt」 + “F11" 키를 눌러 「Microsoft Visual Basic for Applications」 창을 엽니다。

2. 그런 다음 “Project1" > 「Microsoft Outlook Object」 > 「ThisOutlookSession」을 두 번 클릭하여 「Project1 – ThisOutlookSession」 창을 엽니다。 스크린샷 참조：

3. 그런 다음 아래의 VBA 코드를 복사하여 「Project1 – ThisOutlookSession」 창에 붙여넣습니다。

VBA: Outlook 에서 폴더 목록 가져오기

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. 키보드에서 “F5" 키를 눌러 VBA 코드 실행을 시작합니다。

5. 이제 「매크로」 대화상자가 나타나면 「실행」 버튼을 클릭합니다。

6. 매크로 실행을 기다립니다。 그러면 방금 생성된 새 메시지 창에 모든 전자메일 폴더 목록이 즉시 표시됩니다。 이 목록은 쉽게 인쇄할 수 있습니다。 스크린샷 참조：

참고: 이 VBA 코드는 Outlook 2007, 2010 및 2013 에 적용할 수 있습니다。