Excel 의 데이터 목록에서 여러 폴더 및 하위 폴더 생성

워크시트 범위 내에 직원 이름 목록이 있고 각각의 정보를 저장할 개별 폴더를 생성하려 한다고 가정해 보겠습니다。 폴더를 하나씩 수동으로 만드는 것은 시간이 많이 소요됩니다。 그러나 이 과정을 신속하게 처리할 수 있는 효율적인 방법들이 있습니다。 본 가이드에서는 지정된 셀 값을 기반으로 폴더를 빠르게 생성하는 여러 가지 방법을 소개합니다。

셀 값에 기반한 폴더 생성

• MD 명령어와 메모장 사용
• 강력한 기능인 Kutools for Excel 사용
• VBA 코드 사용

VBA 코드를 사용하여 셀 값을 기반으로 폴더 및 하위 폴더 생성

셀 값에 기반한 폴더 생성

이 섹션에서는 셀 값 목록을 기반으로 폴더를 신속하고 손쉽게 생성하기 위한 다양한 방법을 단계별로 자세히 안내합니다。

MD 명령어와 메모장을 사용하여 목록에서 폴더 생성

Excel 의 목록을 MD 명령어와 메모장을 활용해 폴더로 변환하는 것은 간단한 배치 스크립팅과 Excel 의 정돈된 데이터 관리 능력을 결합한 스마트한 방법입니다。 이 방법은 많은 폴더를 수작업 없이 빠르게 생성할 때 매우 유용합니다。 다음은 이 작업을 수행하는 단계별 가이드입니다：

단계 1: MD 명령어를 사용하여 공식 생성

첫 번째 셀 값(B1 등) 옆의 빈 셀에 다음 수식을 복사하거나 입력한 후 채우기 핸들을 아래로 드래그하여 모든 목록 항목에 수식을 적용합니다。

="MD "&A1

단계 2: 수식을 복사하여 메모장 파일에 붙여넣기

1. MD 명령어 수식이 포함된 셀을 선택하고 「Ctrl + C」를 눌러 복사합니다。
2. 메모장을 열고 「Ctrl + V」를 눌러 명령어를 생성된 파일에 붙여넣습니다。
   

단계 3: 메모장 파일을 .bat 파일로 저장

메모장의 「파일(File)」 탭에서 「다른 이름으로 저장(Save as)」을 클릭합니다。 「다른 이름으로 저장」 대화상자에서 여러 폴더를 생성할 디렉터리를 선택하고 .bat 확장자를 붙여 파일 이름을 지정합니다。 마지막으로 「저장(Save)」 버튼을 클릭합니다。 스크린샷을 참조하세요：

단계 4: .bat 파일을 두 번 클릭하여 여러 폴더 생성

1. 메모장 파일을 닫고 이전에 .bat 파일을 저장한 폴더로 이동합니다。
2. 이제 마법을 확인해 보세요。 파일을 두 번 클릭하면 여러 폴더가 한 번에 생성되는 것을 볼 수 있습니다。 아래 데모를 참조하세요：
   

강력한 도구 – Kutools for Excel 를 사용하여 목록에서 폴더 생성

강력한 Kutools for Excel 의 「범위를 기반으로 폴더 생성」 기능을 사용하면 Excel 목록에서 손쉽고 빠르게 폴더를 생성할 수 있습니다. 기본 폴더 생성에 그치지 않고 Kutools 는 한 번에 다단계 하위 폴더를 포함한 복잡한 구조도 생성할 수 있습니다. 몇 가지 간단한 단계만으로 Excel 의 데이터를 체계적인 폴더 시스템으로 변환하여 생산성을 크게 향상시킬 수 있습니다。

Kutools for Excel 설치 후 「Kutools 플러스」 > 「가져오기/내보내기(Import / Export)」 > 「범위를 기반으로 폴더 생성」을 클릭하여 범위를 기반으로 폴더 생성 대화상자를 엽니다：

1. 폴더를 생성할 기준이 되는 셀 값을 선택합니다；
2. 그런 다음，버튼을 클릭하여 폴더를 저장할 대상 폴더를 지정합니다；
3. 마지막으로 확인(OK) 버튼을 클릭합니다。
   

결과：

Kutools 는 워크시트의 목록을 처리하여 지정된 대상 위치에 각 항목에 해당하는 폴더를 생성합니다。 결과를 확인하려면 대상 폴더로 이동하세요。 스크린샷을 참조하세요：

VBA 코드를 사용하여 목록에서 폴더 생성

Excel 에서 VBA 코드를 사용하면 목록에서 폴더를 생성하는 번거로운 작업을 빠르고 자동화된 프로세스로 바꿀 수 있습니다。 이 섹션에서는 VBA 코드를 적용하여 폴더를 생성하는 방법을 안내합니다。

단계 1: VBA 모듈 편집기를 열고 코드 복사

1. Excel 에서 「ALT + F11」 키를 누르면 「Microsoft Visual Basic for Applications」 창이 열립니다。
2. 「삽입(Insert)」 > 「모듈(Module)」을 클릭하고 다음 코드를 모듈 창에 붙여넣습니다。
   VBA 코드： 셀 값 목록을 기반으로 폴더 생성

   Sub CreateFoldersFromSelection()
   'Updateby Extendoffice
       Dim FolderPath As String
       Dim Cell As Range
       Dim SelectedRange As Range
       Dim FolderName As String
       On Error Resume Next
       Set SelectedRange = Application.InputBox("Select the range with folder names", "Kutools for Excel", Type:=8)
       If SelectedRange Is Nothing Then Exit Sub
       On Error GoTo 0
       
       With Application.FileDialog(msoFileDialogFolderPicker)
           .Title = "Select the destination Folder"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           FolderPath = .SelectedItems(1) & "\"
       End With
       
       For Each Cell In SelectedRange
           FolderName = FolderPath & Cell.Value
           If Cell.Value <> "" And Not FolderExists(FolderName) Then
               MkDir FolderName
           End If
       Next Cell
   End Sub
   
   Function FolderExists(ByVal Path As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(Path) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

단계 2: 코드 실행

1. 이 코드를 붙여넣은 후 F5 키를 눌러 코드를 실행합니다。 나타나는 프롬프트 상자에서 폴더를 생성할 셀 값을 선택한 후 확인(OK)을 클릭합니다。
   
2. 그리고 나서 나타나는 「대상 폴더 선택(Select the destination Folder)」 창에서 생성된 폴더를 출력할 대상 경로를 지정합니다。 그런 다음 확인(OK) 버튼을 클릭하고 다음 스크린샷을 참조하세요：
   

결과：

VBA 코드 실행 후 대상 디렉터리로 이동하여 결과를 확인합니다。 Excel 목록의 각 항목에 해당하는 새로 생성된 폴더를 확인할 수 있습니다。 스크린샷을 참조하세요：

VBA 코드를 사용하여 셀 값을 기반으로 폴더 및 하위 폴더 생성

때로는 폴더뿐만 아니라 Excel 셀 내 데이터를 기반으로 해당 하위 폴더까지 동시에 생성해야 할 상황이 생깁니다。 이러한 작업을 수행하기 위해 여기서 VBA 코드를 소개합니다。

단계 1: 데이터 준비

먼저 다음 스크린샷과 같이 첫 번째 열에 주요 폴더 이름을 입력하고 두 번째 열에 하위 폴더 이름을 입력해야 합니다。

단계 2: VBA 모듈 편집기를 열고 코드 복사

1. Excel 에서 「ALT + F11」 키를 누르면 「Microsoft Visual Basic for Applications」 창이 열립니다。
2. 「삽입(Insert)」 > 「모듈(Module)」을 클릭하고 다음 코드를 모듈 창에 붙여넣습니다。
   VBA 코드： 셀 값을 기반으로 폴더 및 하위 폴더 생성

   Sub CreateFoldersAndSubfoldersWithUserInput()
   'Updateby Extendoffice
       Dim Rng As Range
       Dim Cell As Range
       Dim basePath As String
       Dim fldrPicker As FileDialog
       Dim FolderPath As String, subfolderPath As String
       On Error Resume Next
       Set Rng = Application.InputBox("Select the range of cells (two columns: one is folder column, another s subfolder column):", "Kutools for Excel", Type:=8)
       If Rng Is Nothing Then Exit Sub
       On Error GoTo 0
       Set fldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
       With fldrPicker
           .Title = "Select the Base Folder Path"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           basePath = .SelectedItems(1)
       End With
       If Right(basePath, 1) <> "\" Then basePath = basePath & "\"
       For Each Cell In Rng.Columns(1).Cells
           If Not Cell.Value = "" Then
               FolderPath = basePath & Cell.Value
               If Not FolderExists(FolderPath) Then MkDir FolderPath
               If Not Cell.Offset(0, 1).Value = "" Then
                   subfolderPath = FolderPath & "\" & Cell.Offset(0, 1).Value
                   If Not FolderExists(subfolderPath) Then MkDir subfolderPath
               End If
           End If
       Next Cell
   End Sub
   
   Function FolderExists(FolderPath As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(FolderPath) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

단계 3: 코드 실행

1. 이 코드를 붙여넣은 후 F5 키를 눌러 코드를 실행합니다。 나타나는 프롬프트 상자에서 폴더를 생성할 셀 값을 선택한 후 확인(OK)을 클릭합니다。
   
2. 다음 팝업 창에서 생성된 폴더를 출력할 대상 경로를 지정합니다。 그런 다음 확인(OK) 버튼을 클릭하고 스크린샷을 참조하세요：
   

결과：

VBA 코드 실행 후 대상 디렉터리로 이동하여 결과를 확인합니다。 셀 값에 따라 폴더와 해당 하위 폴더가 다음 스크린샷과 같이 성공적으로 생성된 것을 확인할 수 있습니다：

관련 문서：