Excel 에서 중첩된 IF 문 마스터하기 – 단계별 가이드

Excel 에서 IF 함수는 기본적인 논리 검사에 필수적이지만, 복잡한 조건의 경우 데이터 처리를 강화하기 위해 중첩 IF 문이 필요할 때가 많습니다. 이 포괄적인 가이드에서는 중첩 IF 의 기본 개념을 구문부터 실제 적용 사례까지 자세히 다루며， AND/OR 조건과 결합하는 방법도 포함합니다。 또한 중첩 IF 함수의 가독성을 개선하는 방법과 관련 팁을 공유하고， VLOOKUP， IFS 등과 같은 강력한 대안을 탐색하여 복잡한 논리 연산을 더 쉽게， 더 효율적으로 수행하는 방법을 알아봅니다。

• 중첩 IF 구문
• 중첩 IF 실무 예제
• AND/OR 조건과 함께 사용하는 중첩 IF

• 중첩 IF 가독성 높이기
• 중첩 IF 함수의 순서
• 숫자와 텍스트는 다르게 처리해야 합니다
• 중첩 IF 의 한계

• VLOOKUP 사용하기
• IFS 사용하기
• CHOOSE 및 MATCH 사용하기

Excel IF 함수 vs. 중첩 IF 문

Excel 의 IF 함수와 중첩 IF 문은 유사한 목적을 가지고 있지만 복잡성과 적용 방식에서 상당한 차이가 있습니다。

중첩 IF 사용법

이 섹션에서는 Excel 에서 중첩 IF 문의 기본 사용법을 구문， 실용적인 예제， AND 또는 OR 조건과의 결합 방법과 함께 설명합니다。

중첩 IF 구문

함수의 구문을 이해하는 것은 Excel 에서 해당 함수를 올바르고 효과적으로 사용하기 위한 기초입니다。 중첩 IF 문의 구문부터 시작해 보겠습니다。

구문:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

인수:

• 조건1,조건2,조건3: 이는 테스트하려는 조건들입니다. 각 조건은 조건1 부터 순서대로 평가됩니다。
• 결과1: 조건1 이 TRUE 일 때 반환되는 값입니다。
• 결과2: 조건1 이 FALSE 이고 조건2 가 TRUE 일 때 반환되는 값입니다. 결과2 는 조건1 이 FALSE 인 경우에만 평가된다는 점에 유의해야 합니다。
• 결과3: 조건1 과 조건2 가 모두 FALSE 이고 조건3 이 TRUE 일 때 반환되는 값입니다. 즉, 결과3 이 평가되려면 이전 조건(조건1 과 조건2)이 모두 FALSE 여야 합니다。
• 결과4: 조건1, 조건2, 조건3 이 모두 FALSE 일 때 반환되는 결과입니다。
  
  요약하면， 이 표현은 다음과 같이 해석할 수 있습니다：
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

중첩 IF 구조에서는 각 후속 조건이 이전 모든 조건이 FALSE 일 경우에만 평가됩니다. 이러한 순차적 검사는 중첩 IF 가 작동하는 방식을 이해하는 데 매우 중요합니다。

중첩 IF 실무 예제

이제 두 가지 실용적인 예제를 통해 중첩 IF 의 사용법을 살펴보겠습니다。

예제 1: 성적 평가 시스템

아래 스크린샷과 같이 학생들의 점수 목록이 있고 이를 기준으로 등급을 부여하려 한다면, 중첩 IF 를 사용하여 이 작업을 수행할 수 있습니다。

빈 셀(C2)을 선택하고 다음 수식을 입력한 후 Enter 키를 눌러 결과를 확인하세요。 그런 다음 채우기 핸들을 아래로 드래그하여 나머지 결과를 얻으세요。

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

예제 2: 영업 수수료 계산

영업 담당자가 영업 실적에 따라 서로 다른 수수료율을 받는 상황을 가정해 보겠습니다。 아래 스크린샷과 같이 다양한 영업 기준에 따라 영업직원의 수수료를 계산하려 할 때 중첩 IF 문이 도움이 됩니다。

빈 셀(C2)을 선택하고 다음 수식을 입력한 후 Enter 키를 눌러 결과를 확인하세요。 그런 다음 채우기 핸들을 아래로 드래그하여 나머지 결과를 얻으세요。

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

AND/OR 조건과 함께 사용하는 중첩 IF

이 섹션에서는 앞서 설명한 첫 번째 예제인 「성적 평가 시스템」을 수정하여 Excel 에서 중첩 IF 를 AND 또는 OR 조건과 결합하는 방법을 보여줍니다。 수정된 성적 예제에서는 「출석률」을 기준으로 추가 조건를 도입했습니다。

AND 조건과 함께 중첩 IF 사용하기

학생이 점수와 출석률 기준을 모두 충족하면 등급이 상향 조정됩니다. 예를 들어, 점수가 60 이상이고 출석률이 95% 이상인 학생은 A 에서 A+, B 에서 B+ 등으로 한 단계 높은 등급을 받습니다。 그러나 출석률이 95% 미만이면 원래의 점수 기반 기준에 따라 등급이 부여됩니다。 이러한 경우 AND 조건이 포함된 중첩 IF 문을 사용해야 합니다。

빈 셀(D2)을 선택하고 다음 수식을 입력한 후 Enter 키를 눌러 결과를 확인하세요。 그런 다음 채우기 핸들을 아래로 드래그하여 나머지 결과를 얻으세요。

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

OR 조건과 함께 중첩 IF 사용하기

이 경우 학생의 점수가 95 이상이거나 출석률이 95% 이상이면 등급이 한 단계 상향 조정됩니다. 중첩 IF 와 OR 조건을 결합하여 이를 구현하는 방법은 다음과 같습니다。

빈 셀(D2)을 선택하고 다음 수식을 입력한 후 Enter 키를 눌러 결과를 확인하세요。 그런 다음 채우기 핸들을 아래로 드래그하여 나머지 결과를 얻으세요。

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

중첩 IF 팁과 노하우

이 섹션에서는 중첩 IF 에 대한 네 가지 유용한 팁과 요령을 소개합니다。

중첩 IF 가독성 높이기

일반적인 중첩 IF 문은 간결해 보일 수 있지만 해독하기 어려울 때가 많습니다。

다음 수식에서는 복잡성이 증가함에 따라 어떤 조건이 어디서 끝나고 다음 조건이 어디서 시작되는지 빠르게 파악하기 어렵습니다。

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

해결 방법： 줄 바꿈과 들여쓰기 추가

중첩 IF 를 쉽게 읽을 수 있도록 하려면 수식을 여러 줄로 나누고 각 중첩 IF 를 새 줄에 배치하세요。 수식 내에서 IF 앞에 커서를 두고 Alt + Enter 키를 누르기만 하면 됩니다。

위 수식을 나눈 후에는 다음과 같이 표시됩니다：

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

이 형식은 각 조건과 해당 출력값이 어디에 위치하는지 명확하게 보여주어 수식의 가독성을 높입니다。

중첩 IF 함수의 순서

중첩 IF 수식에서 논리 조건의 순서는 매우 중요합니다. 이 순서가 Excel 이 조건을 평가하는 방식을 결정하며， 따라서 수식의 최종 결과에 영향을 미칩니다。

올바른 수식

성적 평가 시스템 예제에서 점수에 따라 등급을 부여하기 위해 다음 수식을 사용합니다。

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel 은 중첩 IF 수식의 조건을 처음부터 마지막까지 순차적으로 평가합니다。 이 수식은 가장 높은 점수 기준(「>=90」이면 「A」)부터 확인한 후 낮은 기준으로 이동합니다。 이를 통해 점수가 해당하는 가장 높은 등급과 비교되도록 보장합니다。 첫 번째 조건(A2>=90)이 참이면 「A」를 반환하고 이후 조건은 평가하지 않습니다。

잘못된 순서의 수식

조건의 순서를 반대로 하여 가장 낮은 기준부터 시작하면 잘못된 결과가 반환됩니다。

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

이 잘못된 수식에서는 점수 95 이 첫 번째 조건 B2>=60 을 즉시 충족하여 등급이 잘못 「D」로 부여됩니다。

숫자와 텍스트는 다르게 처리해야 합니다

이 섹션에서는 중첩 IF 문에서 숫자와 텍스트가 어떻게 다르게 처리되는지 설명합니다。

숫자

숫자는 산술 비교 및 계산에 사용됩니다。 중첩 IF 문에서는 >， =， <= 같은 연산자를 사용해 숫자를 직접 비교할 수 있습니다。

텍스트

중첩 IF 문에서 텍스트는 큰따옴표로 묶어야 합니다. 다음 수식의 A, B, C, D, F 를 참고하세요：

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

중첩 IF 의 한계

이 섹션에서는 중첩 IF 의 여러 가지 제한점과 단점을 나열합니다。

복잡성 및 가독성：

Excel 은 최대 64 개의 IF 함수를 중첩할 수 있도록 허용하지만， 그렇게 하는 것은 전혀 권장되지 않습니다。 중첩 수준이 높아질수록 수식이 더욱 복잡해져 읽고 이해하며 유지보수하기 어려워집니다。

오류 발생 가능성：

또한 복잡한 중첩 IF 문은 오류가 발생하기 쉽고 디버깅하거나 수정하기 어렵습니다。

확장 또는 확장성 어려움：

논리가 변경되거나 더 많은 조건을 추가해야 할 경우, 깊이 중첩된 IF 는 수정하거나 확장하기 어렵습니다。

이러한 제한점을 이해하는 것은 Excel 에서 중첩 IF 문을 효과적으로 사용하는 데 핵심입니다. 종종 중첩 IF 를 다른 함수와 결합하거나 대안적 접근 방식을 모색하면 더 효율적이고 유지보수 가능한 솔루션을 얻을 수 있습니다。

중첩 IF 의 대안

이 섹션에서는 중첩 IF 문의 대안으로 사용할 수 있는 Excel 의 여러 함수를 나열합니다。

VLOOKUP 사용하기

앞서 설명한 두 실용 예제를 중첩 IF 문 대신 VLOOKUP 함수를 사용하여 수행할 수 있습니다。 방법은 다음과 같습니다：

예제 1: VLOOKUP 을 사용한 성적 평가 시스템

여기에서는 VLOOKUP 을 사용하여 점수에 따라 등급을 부여하는 방법을 보여드리겠습니다。

단계 1: 등급 조회 테이블 만들기

먼저 점수 범위와 해당 등급에 대한 조회 테이블(E1:F6)을 만들어야 합니다。참고:테이블의 첫 번째 열에 있는 점수는 오름차순으로 정렬되어야 합니다。

단계 2: 등급 부여를 위해 VLOOKUP 함수 적용하기

빈 셀(C2)을 선택하고 다음 수식을 입력한 후 Enter 키를 눌러 첫 번째 등급을 확인하세요。 이 수식 셀을 선택하고 채우기 핸들을 아래로 드래그하여 나머지 등급을 얻으세요。

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

예제 2: VLOOKUP 을 사용한 영업 수수료 계산

Excel 에서 영업 수수료 계산에도 VLOOKUP 을 사용할 수 있습니다。 다음 단계를 따르세요。

단계 1: 등급용 조회 테이블 생성

먼저 영업 실적과 해당 수수료율에 대한 조회 테이블(E2:F4)을 만들어야 합니다。참고： 테이블의 첫 번째 열에 있는 영업 실적은 오름차순으로 정렬되어야 합니다。

단계 2: 등급 부여를 위해 VLOOKUP 함수 적용

빈 셀(C2 의 경우)을 선택하고 다음 수식을 입력한 후 Enter 키를 눌러 첫 번째 커미션을 계산합니다。 이 수식이 포함된 셀을 선택하고 채우기 핸들을 아래로 끌어 나머지 결과를 얻습니다。

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

IFS 사용하기

IFS 함수는 중첩할 필요 없이 조건을 간단하게 처리할 수 있어 수식을 더 쉽게 읽고 관리할 수 있습니다。 여러 조건을 확인하는 과정을 보다 명확하고 간결하게 만들어 줍니다。 IFS 함수를 사용하려면 Excel 2019 이상 버전을 사용하거나 Office 365 구독이 필요합니다。 이제 이를 실제 예제에 어떻게 적용할 수 있는지 살펴보겠습니다。

예제 1: IFS 를 사용한 성적 평가 시스템

이전과 동일한 성적 기준을 가정할 때， IFS 함수는 다음과 같이 사용할 수 있습니다：

C2 와 같은 빈 셀을 선택하고 다음 수식을 입력한 후 Enter 를 눌러 첫 번째 결과를 얻습니다。 이 결과 셀을 선택하고 채우기 핸들을 아래로 끌어 나머지 결과를 얻습니다。

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

예제 2: IFS 를 사용한 영업 커미션 계산

영업 커미션 계산 시나리오에서는 IFS 함수를 다음과 같이 적용합니다：

C2 와 같은 빈 셀을 선택하고 다음 수식을 입력한 후 Enter 를 눌러 첫 번째 결과를 얻습니다。 이 결과 셀을 선택하고 채우기 핸들을 아래로 끌어 나머지 결과를 얻습니다。

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

CHOOSE 및 MATCH 사용하기

CHOOSE 와 MATCH 를 조합한 방식은 중첩된 IF 문보다 더 효율적이며 관리하기도 쉽습니다。 이 방법은 수식을 단순화하고 업데이트나 변경 작업을 더욱 간편하게 만듭니다。 아래에서는 CHOOSE 및 MATCH 함수를 조합하여 본 문서의 두 가지 실용 예제를 처리하는 방법을 설명하겠습니다。

예제 1: CHOOSE 및 MATCH 를 사용한 성적 평가 시스템

CHOOSE 및 MATCH 함수를 조합하여 다양한 점수에 따라 등급을 부여할 수 있습니다。

단계 1: 찾을 값를 사용하여 조회 배열 생성

먼저 MATCH 가 검색할 임계값을 포함하는 셀 범위(이 경우 $E$2：$E$6)를 만들어야 합니다。참고:이 범위의 숫자는 근사치 일치 유형을 사용할 때 MATCH 함수가 정상적으로 작동하려면 오름차순으로 정렬되어 있어야 합니다。

단계 2: CHOOSE 및 MATCH 를 적용하여 등급 부여

빈 셀(C2 의 경우)을 선택하고 다음 수식을 입력한 후 Enter 키를 눌러 첫 번째 등급을 얻습니다。 이 수식이 포함된 셀을 선택하고 채우기 핸들을 아래로 끌어 나머지 결과를 얻습니다。

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

예제 2: IFS 를 사용한 영업 커미션 계산

영업 커미션 계산에 CHOOSE 및 MATCH 조합을 사용하는 것도 효과적입니다。 특히 커미션 비율이 특정 판매 임계값에 기반할 때 더욱 유용합니다。 이제 이를 어떻게 적용할 수 있는지 살펴보겠습니다。

단계 1: 찾을 값을 사용하여 조회 배열 생성

먼저 MATCH 가 검색할 임계값을 포함하는 셀 범위(이 경우 $E$2：$E$4)를 만들어야 합니다。참고:이 범위의 숫자는 근사치 일치 유형을 사용할 때 MATCH 함수가 정상적으로 작동하려면 오름차순으로 정렬되어 있어야 합니다。

단계 2: CHOOSE 및 MATCH 를 적용하여 결과 얻기

빈 셀(C2 의 경우)을 선택하고 다음 수식을 입력한 후 Enter 키를 눌러 첫 번째 등급을 얻습니다。 이 수식이 포함된 셀을 선택하고 채우기 핸들을 아래로 끌어 나머지 결과를 얻습니다。

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

결론적으로, Excel 에서 중첩된 IF 문을 마스터하는 것은 데이터 분석 및 의사결정 프로세스에서 복잡한 논리적 시나리오를 처리하는 능력을 향상시키는 매우 유용한 기술입니다. 중첩된 IF 문은 복잡한 논리 연산에 강력하지만 그 한계점도 인지해야 합니다. VLOOKUP, IFS, CHOOSE 와 MATCH 같은 더 간단한 대안들이 특정 상황에서 보다 효율적인 해결책을 제공할 수 있습니다. 이러한 통찰을 바탕으로 이제 여러분은 자신의 데이터 분석 작업에 가장 적절한 Excel 기법을 자신 있게 적용하여 스프레드시트의 명확성, 정확성, 효율성을 확보할 수 있습니다. Excel 의 기능을 더 깊이 탐구하고 싶으신 분들을 위해 저희 웹사이트에는 다양한 튜토리얼이 준비되어 있습니다。더 많은 Excel 팁과 노하우를 여기서 확인하세요.

관련 문서