Excel COUNTIFS 함수 - 여러 조건을 가진 셀 세기 - AND 논리와 OR 논리

Excel에서 COUNTIFS 함수의 구문

• COUNTIFS 함수의 구문
• 기억해야 할 사항

AND 논리를 사용하여 여러 지정된 조건을 충족하는 셀 세기

• 하나의 범위에서 여러 지정된 조건을 충족하는 셀을 세는 COUNTIFS
• 다른 범위에서 여러 지정된 조건을 충족하는 셀을 세는 COUNTIFS

OR 논리를 사용하여 여러 지정된 조건을 충족하는 셀 세기

• 지정된 조건 중 하나라도 충족하는 셀을 세기 위해 COUNTIF 또는 COUNTIFS 결과를 합산하기
• 지정된 조건 중 하나라도 충족하는 셀을 세기 위한 배열 상수를 사용한 COUNTIFS

Excel에서 COUNTIFS 함수의 구문

Excel의 통계 함수 중 하나로서, COUNTIFS는 하나 또는 여러 범위에서 단일 또는 여러 지정된 조건을 충족하는 셀을 계산합니다.

COUNTIFS 함수의 구문

COUNTIFS 함수의 구문에는 다음 인수가 포함됩니다:

• "criteria_range1" (필수)은 "criteria1"을 적용할 첫 번째 셀 범위를 나타냅니다.
• "criteria1" (필수)은 "criteria_range1"에서 계산될 셀을 정의하는 조건을 나타냅니다.
• "criteria_range2", "criteria2" (선택 사항)은 추가적인 범위 및 해당 기준을 나타냅니다. 최대 127개의 범위와 기준 쌍이 허용됩니다.

COUNTIF 함수는 관련 범위에서 하나 이상의 지정된 조건을 충족하는 셀의 수를 나타내는 숫자 값을 반환합니다.

기억해야 할 사항

• 각 추가 범위의 행과 열 수는 "criteria_range1"과 같아야 합니다. 범위는 동일하거나 서로 인접하거나 비인접할 수 있습니다.
•  
• Excel의 COUNTIFS 공식에서 별표 (*)는 임의의 문자열을 매칭할 수 있고, 물음표 (?)는 임의의 단일 문자를 매칭합니다. 실제 와일드카드 문자(별표 (*) 또는 물음표 (?))로 셀을 계산해야 하는 경우, 와일드카드 문자 앞에 물결표 (~)를 붙여야 합니다. 예를 들어, ~*, ~?.
• 쌍따옴표 (“”) 는 숫자가 아닌 기준을 묶어야 하며, 숫자 기준은 따옴표 없이도 가능합니다 . 예를 들어, 80, “>=80”, “a”, “india”.
• COUNTIFS 함수는 대소문자를 구분하지 않습니다. 따라서 문자열 “India” 또는 “INDIA”는 수식의 결과에 차이를 주지 않습니다.
• "비교 연산자"를 사용하여 COUNTIFS 함수에서 셀 참조를 사용하려면 연산자를 따옴표 (“”)로 묶고 그 사이에 앰퍼샌드 (&) 를 추가해야 합니다. 예를 들어, “>”&B2.
• 비교 연산자의 순서는 중요합니다: = 는 자체적으로 작동하거나 > 또는 < 뒤에서만 작동합니다.

AND 논리를 사용하여 여러 지정된 조건을 충족하는 셀 세기

기본적으로 COUNTIFS 함수는 "AND" 논리로 여러 조건을 평가합니다. COUNTIFS 공식의 결과는 모든 지정된 조건을 충족하는 셀의 수를 보여줍니다. 여기에 AND 논리를 사용하여 COUNTIFS 함수로 셀을 세는 몇 가지 예제가 있습니다.

하나의 범위에서 여러 지정된 조건을 충족하는 셀을 세는 COUNTIFS

√ 참고: 빈 셀은 점수가 제대로 기록되지 않았음을 의미합니다. 0점은 학생이 시험을 치르지 않았음을 의미합니다.

영어 점수가 60에서 90 사이(60과 90 포함)인 학생의 수를 세기 위해 두 가지 방법을 소개합니다.

• 다음 COUNTIFS 공식을 사용할 수 있습니다:

  =COUNTIFS(C2:C8,">=60",C2:C8,"<=90")

  결과는 "5"입니다.
•  
• 또는, 만약 당신이 Kutools for Excel 설치했다면, "Kutools" 탭으로 이동하여 "Select"를 찾고 드롭다운 목록에서 "Select Specific Cells"를 클릭하세요. 아래 스크린샷과 같이 설정하세요:
  

Kutools for Excel - 필수적인 300개 이상의 도구로 Excel을 강화하세요. 영구적으로 무료인 AI 기능을 활용하세요! 지금 바로 구매하기

☞ 작업을 수행하는 다른 방법: Excel에서 두 값 또는 날짜 사이의 셀 개수를 어떻게 세나요?

유효한 점수의 수(0이거나 빈 셀이 아닌 셀)를 세기 위해 여기에도 두 가지 방법을 소개합니다.

• 다음 공식을 사용할 수 있습니다:

  =COUNTIFS(C2:D8,"<>0",C2:D8,"<>")

  결과는 "12"입니다.
  √ 참고: Excel에서 "<>"는 같지 않음을 의미합니다. ""<>0""은 0이 아님을 의미하며, ""<>""는 비어 있지 않음을 의미하거나 우리는 그것을 빈 셀이 아니라고 말할 수 있습니다.
•  
• 설치된 상태에서 "Kutools for Excel"를 사용하면 "Kutools" 탭으로 이동하여 "Select"를 찾고 드롭다운 목록에서 "Select Specific Cells"를 클릭할 수도 있습니다. 아래 스크린샷과 같이 설정하세요:
  
  √ 참고: Kutools는 기본적으로 빈 셀을 계산하지 않으므로 "Specific Type"에서 기준을 “"Does not equal to 0"”로 설정하면 됩니다.

  Kutools for Excel - 필수적인 300개 이상의 도구로 Excel을 강화하세요. 영구적으로 무료인 AI 기능을 활용하세요! 지금 바로 구매하기

다양한 범위에서 여러 지정된 조건을 충족하는 셀을 세는 COUNTIFS

• "a로 끝나는 국가들로부터 온 학생"이고 "이름이 J로 시작하는 학생"의 수를 세기 위해 다음 공식을 사용하세요:

  =COUNTIFS(A2:A8,"j*", B2:B8,"*a")

  결과는 "2"입니다.
  √ 참고: 와일드카드 문자 "asterisk (*)"는 임의의 문자열을 매칭합니다.
•  
• "Eddie의 영어 점수와 수학 점수(C4 및 D4의 값)보다 큰 점수를 받은 학생"의 수를 세기 위해 다음 공식 중 하나를 사용하세요:

  =COUNTIFS(C2:C8,">60",D2:D8,">80")

  =COUNTIFS(C2:C8,">"&C4,D2:D8,">"&D4

  결과는 "3"입니다.
•  
• "인도(B2의 값)로부터 온 학생"이고 "A 등급(E2의 값)을 가진 학생"의 수를 세기 위해 다음 공식 중 하나를 사용하세요:

  =COUNTIFS(B2:B8,"india",E2:E8,"a")

  =COUNTIFS(B2:B8,B2,E2:E8,E2)

  결과는 "2"입니다.

OR 리를 사용하여 여러 지정된 조건을 충족하는 셀 세기

OR 논리를 사용하여 여러 지정된 조건을 충족하는 셀을 세는 것은 조건1을 충족하는 셀, 조건2를 충족하는 셀, 그리고 ... 즉, 적어도 하나의 조건을 충족하는 셀의 총 수를 세는 것을 의미합니다. 이를 위해 아래에 2가지 방법을 소개합니다:

지정된 조건 중 하나라도 충족하는 셀을 세기 위해 COUNTIF 또는 COUNTIFS 결과를 합산하기

적어도 하나의 조건을 충족하는 셀의 수를 더하면 쉽게 총 셀 수를 생성할 수 있습니다. 그래서 해야 할 일은 필요한 만큼 COUNTIF(S) 공식을 작성하고 산술 연산을 수행하는 것입니다.

• "인도(B2의 값)" 또는 "잉글랜드(B3의 값)"로부터 온 학생의 수를 세기 위해 다음 공식 중 하나를 사용하세요:

  =COUNTIF(B2:B8,"india")+COUNTIF(B2:B8,"england")

  =COUNTIF(B2:B8,B2)+COUNTIF(B2:B8,B3)

  결과는 "4"입니다.
  √ 참고: 전문적인 추가 기능인 "Kutools for Excel"이 설치되어 있다면 "Kutools" > "Select" > "Select Specific Cells"를 사용할 수 있으며, "Specific type"에서 "OR"을 선택하세요.
•  
• "영어 점수 또는 수학 점수가 80 이상(80 포함)인 학생"의 수를 세기 위해 다음 공식 중 하나를 사용하세요:

  =COUNTIF(C2:C8,">=80")+COUNTIF(D2:D8,">=80")-COUNTIFS(C2:C8,">=80", D2:D8,">=80")

  결과는 "5"입니다.
  √ 참고: 여기서 COUNTIFS(C2:C8,">=80", D2:D8,">=80")를 빼는 이유는 중복을 제거하기 위함이며, 이는 영어와 수학 점수가 모두 80 이상인 학생입니다.

지정된 조건 중 하나라도 충족하는 셀을 세기 위한 배열 상수를 사용한 COUNTIFS

COUNTIF 또는 COUNTIFS 결과를 합산하는 것이 서식 면에서 너무 크기가 커질 수 있으므로, SUM과 COUNTIFS 함수를 배열 상수와 결합하여 다양한 셀의 수를 세는 방법을 사용할 수 있습니다. 아래 예제를 확인하세요:

• "인도 또는 잉글랜드로부터 온 학생"의 수를 세기 위해 다음 공식(하나의 범위)을 사용하세요:

  =SUM(COUNTIF(B2:B8,{"india","england"}))

  결과는 "4"입니다.
•  
• "인도 또는 미국에서 온 A, B 또는 C 등급을 가진 학생"의 수를 세기 위해 다음 공식을 사용하세요:

  =SUM(COUNTIFS(B2:B8,{"india","america"},E2:E8,{"a";"b";"c"}))

  결과는 "4"입니다.
  √ 참고: 두 번째 배열 상수에서는 세미콜론 (;)을 사용해야 합니다. 더 많은 조건이 있는 경우 "SUMPRODUCT" 공식을 고려하세요.