Excel에서 조회 값과 함께 배경색을 반환하는 VLOOKUP을 어떻게 사용합니까?

아래 스크린샷에 표시된 것처럼 테이블이 있다고 가정해 보겠습니다. 이제 지정된 값이 A열에 있는지 확인하고, C열에서 해당 값을 배경색과 함께 반환하려고 합니다. 이를 수행하는 방법은 무엇일까요? 이 문서의 방법이 문제를 해결하는 데 도움이 될 수 있습니다.

사용자 정의 함수로 조회 값과 함께 배경색 반환하기

사용자 정의 함수로 조회 값과 함께 배경색 반환하기

조회 값을 찾고 Excel에서 해당 값을 배경색과 함께 반환하려면 다음과 같이 하세요.

1. VLOOKUP으로 찾고자 하는 값이 포함된 워크시트에서 시트 탭을 마우스 오른쪽 버튼으로 클릭하고 상황에 맞는 메뉴에서 코드 보기(View Code)를 선택합니다. 스크린샷 참조:

2. 열리는 Microsoft Visual Basic for Applications 창에서 아래 VBA 코드를 코드(Code) 창에 복사하세요.

VBA 코드 1: 조회 값과 함께 배경색 반환하기

Sub Worksheet_Change(ByVal Target As Range)
    Dim I As Long
    Dim xKeys As Long
    Dim xDicStr As String
    On Error Resume Next
    Application.ScreenUpdating = False
    xKeys = UBound(xDic.Keys)
    If xKeys >= 0 Then
        For I = 0 To UBound(xDic.Keys)
            xDicStr = xDic.Items(I)
            If xDicStr <> "" Then
                Range(xDic.Keys(I)).Interior.Color = _
                Range(xDic.Items(I)).Interior.Color
            Else
                Range(xDic.Keys(I)).Interior.Color = xlNone
            End If
        Next
        Set xDic = Nothing
    End If
    Application.ScreenUpdating = True
End Sub

3. 그런 다음 삽입(Insert) > 모듈(Module)을 클릭하고 아래 VBA 코드 2를 모듈(Module) 창에 복사합니다.

VBA 코드 2: 조회 값과 함께 배경색 반환하기

Public xDic As New Dictionary
Function LookupKeepColor (ByRef FndValue, ByRef LookupRng As Range, ByRef xCol As Long)
    Dim xFindCell As Range
    On Error Resume Next
    Set xFindCell = LookupRng.Find(FndValue, , xlValues, xlWhole)
    If xFindCell Is Nothing Then
        LookupKeepColor = ""
        xDic.Add Application.Caller.Address, ""
    Else
        LookupKeepColor = xFindCell.Offset(0, xCol - 1).Value
        xDic.Add Application.Caller.Address, xFindCell.Offset(0, xCol - 1).Address
    End If
End Function

4. 두 개의 코드를 삽입한 후 도구(Tools) > 참조(References)를 클릭합니다. 그런 다음 참조 – VBAProject 대화상자에서 Microsoft Script Runtime 상자를 체크합니다. 스크린샷 참조:

5. Alt + Q 키를 눌러 Microsoft Visual Basic for Applications 창을 종료하고 워크시트로 돌아갑니다.

6. 조회 값 옆의 빈 셀을 선택하고 수식 표시줄(F)에 =LookupKeepColor(E2,$A$1:$C$8,3) 공식을 입력한 다음 Enter 키를 누릅니다.

참고: 수식에서 E2는 조회할 값을 포함하고 있으며, $A$1:$C$8은 테이블 범위이고 숫자 3 은 반환할 해당 값이 테이블의 세 번째 열에 위치함을 의미합니다. 필요에 따라 변경하세요.

7. 첫 번째 결과 셀을 계속 선택하고 채우기 핸들을 아래로 드래그하여 모든 결과와 그들의 배경색을 가져옵니다. 스크린샷 참조.

관련 기사:

• Excel에서 VLOOKUP을 사용할 때 조회 셀의 원본 서식을 복사하는 방법은 무엇입니까?
• Excel에서 숫자 대신 날짜 형식을 반환하는 VLOOKUP을 사용하는 방법은 무엇입니까?
• Excel에서 VLOOKUP과 합계를 사용하는 방법은 무엇입니까?
• Excel에서 인접하거나 다음 셀에 있는 값을 반환하는 VLOOKUP을 사용하는 방법은 무엇입니까?
• Excel에서 VLOOKUP을 사용하여 값을 조회하고 참/거짓 또는 예/아니오를 반환하는 방법은 무엇입니까?