Excel에서 입력 할 때 텍스트 상자를 자동 완성하는 방법은 무엇입니까?

기본적으로 Excel은 현재 워크 시트의 셀에 입력 한 내용을 기억하고 다음에 관련 첫 글자를 새 셀에 입력 할 때이 내용을 자동 완성 할 수 있습니다. 그러나 워크 시트에 입력 한 모든 내용이 텍스트 상자 (ActiveX Control)에 자동 완성되도록하려면 어떻게해야합니까? 이 기사에서는 내부에 첫 글자를 입력 할 때 텍스트 상자를 자동 완성하는 데 도움이되는 VBA 방법을 제공합니다.

VBA 코드로 입력 할 때 텍스트 상자 자동 완성

VBA 코드로 입력 할 때 텍스트 상자 자동 완성

텍스트 상자에 첫 글자를 입력 할 때 텍스트 상자가 자동 ​​완성되도록하려면 다음과 같이하십시오.

1. 클릭하여 텍스트 상자를 삽입하십시오 개발자 > 끼워 넣다 > 텍스트 상자 (ActiveX 컨트롤). 스크린 샷보기 :

2. 그런 다음 개발자 > 끼워 넣다 > 목록 상자 (ActiveX 컨트롤) 현재 워크 시트에 목록 상자를 삽입합니다. 스크린 샷보기 :

3. 시트 탭을 마우스 오른쪽 단추로 클릭 한 다음 코드보기 아래 스크린 샷과 같이 컨텍스트 메뉴에서.

4. 에서 응용 프로그램 용 Microsoft Visual Basic 창에서 VBA 코드 아래에 복사하여 코드 창에 붙여 넣으십시오. 그런 다음 도구 > 참고자료을 클릭 한 다음 Microsoft 스크립팅 런타임 상자에 참조 – VBAProject 대화 상자. 스크린 샷보기 :

VBA 코드 : 입력시 텍스트 상자 자동 완성

Dim xRg As Range
Dim xDic As New Dictionary
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    Me.TextBox1.Value = Me.ListBox1.Value
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim xVal As String
    On Error Resume Next
    If IsNumeric(Target.Value) Then
        xVal = Str(Target.Value)
    Else
        xVal = Target.Value
    End If
    If xVal <> "" Then
        If Not xDic.Exists(xVal) Then
            xDic.Add xVal, xVal
        End If
    End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Me.ListBox1.Visible = False
End Sub
Private Sub Worksheet_Activate()
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    If xRg Is Nothing Then
        Set xRg = ActiveSheet.UsedRange
    End If
    Me.ListBox1.Visible = False
    xDic.RemoveAll
    With Me.ListBox1
        For I = 1 To xRg.Count
            xStr = xRg(I).Value
            If xStr <> "" Then
                .AddItem xStr
                If Not xDic.Exists(xStr) Then
                    xDic.Add xStr, xStr
                End If
            End If
        Next
    End With
End Sub
Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    With Me.ListBox1
        .Top = Me.TextBox1.Top
        .Left = Me.TextBox1.Left + Me.TextBox1.Width
        .Width = Me.TextBox1.Width
    End With
    TextBoxVal Me.TextBox1.Object
End Sub
Sub TextBoxVal(xTextBox As Variant)
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    Application.ScreenUpdating = False
    If xRg Is Nothing Then Exit Sub
    Me.ListBox1.Clear
    xStr = xTextBox.Value
    If xStr = "" Then
        Me.ListBox1.Visible = False
        Application.EnableEvents = True
        Exit Sub
    End If
    For I = 0 To UBound(xDic.Items)
        If Left(xDic.Items(I), Len(xStr)) = xStr Then
            Me.ListBox1.AddItem xDic.Items(I)
        End If
    Next
    Me.ListBox1.Visible = True
    If Me.ListBox1.ListCount > 0 Then
        With xTextBox
            .Value = Me.ListBox1.List(0)
            .SelStart = Len(xStr)
            .SelLength = Len(Me.ListBox1.List(0))
        End With
    End If
    Me.ListBox1.Activate
    Me.ListBox1.Selected(0) = True
    Application.ScreenUpdating = True
End Sub
Private Sub ListBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 13 Then
        Me.TextBox1.Value = Me.ListBox1.Value
    End If
End Sub

주의 사항: 코드에서 ListBox1 and 텍스트 상자 1 워크 시트에 삽입 한 목록 상자 및 텍스트 상자의 이름입니다.

5. 누르세요 다른 + Q 나가는 열쇠 응용 프로그램 용 Microsoft Visual Basic 창.

6. 클릭하여 디자인 모드를 끕니다. 개발자 > 디자인 모드 워크 시트에서.

7. 이제 다른 워크 시트로 이동 한 다음 이전 워크 시트로 돌아가서 VBA 코드를 활성화합니다.

지금부터. 텍스트 상자에 첫 글자를 입력 할 때 워크 시트에 입력 한 해당 글자로 시작하는 모든 텍스트는 텍스트 상자의 오른쪽에있는 목록 상자 안에 나열됩니다. 필요한 것을 두 번 클릭하여 텍스트 상자에 입력하십시오. 스크린 샷보기 :

주의 사항: Up or 아래로 화살표 키를 눌러 목록 상자의 모든 자동 완성 텍스트 사이를 이동 한 다음 엔터 버튼 텍스트 상자에 필요한 키를 입력합니다.

관련 기사 :

• Excel에서 선택한 텍스트 상자의 텍스트를 자동으로 선택하는 방법은 무엇입니까?
• Excel에서 클릭하면 텍스트 상자의 내용을 지우는 방법은 무엇입니까?
• 여러 셀의 텍스트를 Excel의 텍스트 상자에 연결하는 방법은 무엇입니까?
• Excel에서 사용자 입력을 방지하기 위해 텍스트 상자에서 편집을 비활성화하는 방법은 무엇입니까?
• Excel에서 텍스트 상자를 백분율로 서식을 지정하는 방법은 무엇입니까?