Excel에서 두 개의 리스트 박스 간에 항목을 빠르게 이동하는 방법은 무엇입니까?

아래 스크린샷에 표시된 대로 필요에 따라 한 리스트 박스에서 다른 리스트 박스로 항목을 이동해 본 적이 있습니까? 여기에서는 Excel에서 이 작업에 대해 설명하겠습니다.

리스트 박스 간 항목 이동

리스트 박스 간 항목 이동

이 작업을 완료하는 데 도움이 되는 내장 함수는 없지만, 제가 도움을 줄 수 있는 VBA 코드가 있습니다.

1. 먼저 Admin_Lists라는 새 워크시트에 리스트 박스에 표시될 항목으로 사용할 데이터 목록을 생성해야 합니다.

2. 그런 다음 이러한 데이터를 선택하고 이름 상자로 이동하여 이름을 ItemList로 지정합니다. 스크린샷 보기:

3. 그런 다음 두 개의 리스트 박스를 포함할 워크시트에서 개발 도구 > 삽입 > 리스트 박스(Active X 컨트롤)를 클릭하고 두 개의 리스트 박스를 그립니다. 스크린샷 보기:

개발 도구 탭이 리본에서 숨겨져 있는 경우, Excel 2007/2010/2013 리본에서 개발 도구 탭을 어떻게 표시합니까? 이 기사에서는 이를 표시하는 방법을 알려드립니다.

4. 그런 다음 개발 도구 > 삽입 > 명령 단추(Active X 컨트롤)를 클릭하고 두 리스트 박스 사이에 네 개의 단추를 그립니다. 스크린샷 보기:

이제 네 개의 명령 단추를 새 이름으로 바꿉니다.

5. 첫 번째 명령 단추를 선택하고 속성을 클릭한 다음 속성 창에서 이름을 BTN_moveAllRight로 지정하고 캡션 옆의 텍스트 상자에 >>를 입력합니다. 스크린샷 보기:

6. 5단계를 반복하여 마지막 세 명령 단추의 이름을 아래와 같이 변경하고 캡션에 다른 화살표를 입력합니다. 스크린샷 보기:

BTN_MoveSelectedRight

BTN_moveAllLeft

BTN_MoveSelectedLeft

7. 리스트 박스와 명령 단추가 포함된 워크시트 이름을 마우스 오른쪽 버튼으로 클릭하고 상황 메뉴에서 코드 보기(View Code)를 선택합니다. 스크린샷 보기:

8. 아래 매크로 코드를 모듈 스크립트에 복사하여 붙여넣고 코드를 저장한 후 Microsoft Visual Basic for Applications 창을 닫습니다. 스크린샷 보기:

VBA: 두 리스트 박스 간 항목 이동

Private Sub Worksheet_Activate()
'UpdatebyExtendoffice20171117
    Dim xCell As Range
    Dim xRg As Range
    Set xRg = Sheets("Admin_Lists").Range("ItemList")
    Me.ListBox1.Clear
    Me.ListBox2.Clear
    With Me.ListBox1
        .LinkedCell = ""
        .ListFillRange = ""
        For Each xCell In xRg
            If xCell <> "" Then
                .AddItem xCell.Value
            End If
        Next xCell
    End With
    Me.ListBox1.MultiSelect = fmMultiSelectMulti
    Me.ListBox2.MultiSelect = fmMultiSelectMulti
End Sub

Private Sub BTN_MoveSelectedLeft_Click()
    Call moveSigle(Me.ListBox2, Me.ListBox1)
End Sub

Private Sub BTN_MoveSelectedRight_Click()
    Call moveSigle(Me.ListBox1, Me.ListBox2)
End Sub

Private Sub BTN_moveAllLeft_Click()
    Call moveAll(Me.ListBox2, Me.ListBox1)
End Sub

Private Sub BTN_moveAllRight_Click()
    Call moveAll(Me.ListBox1, Me.ListBox2)
End Sub

Sub moveAll(xListBox1 As Object, xListBox2 As Object)
    Dim I As Long
    For I = 0 To xListBox1.ListCount - 1
        xListBox2.AddItem xListBox1.List(I)
    Next I
    xListBox1.Clear
End Sub

Sub moveSigle(xListBox1 As Object, xListBox2 As Object)
    Dim I As Long
    For I = 0 To xListBox1.ListCount - 1
        If I = xListBox1.ListCount Then Exit Sub
        If xListBox1.Selected(I) = True Then
            xListBox2.AddItem xListBox1.List(I)
            xListBox1.RemoveItem I
            I = I - 1
        End If
    Next
End Sub

9. 그런 다음 다른 워크시트로 이동한 후 리스트 박스가 포함된 워크시트로 돌아갑니다. 이제 첫 번째 리스트 박스에 목록 데이터가 나열되어 있는 것을 볼 수 있습니다. 그리고 명령 단추를 클릭하여 두 리스트 박스 간에 항목을 이동합니다.

선택 영역 이동

모두 이동