Excel에서 날짜를 빠르게 단어로 변환하는 방법은 무엇입니까?

일반적으로 Excel에서는 날짜를 다른 날짜 형식이나 숫자로 변환하는 경우가 많지만, 아래 스크린샷과 같이 날짜를 영어 단어로 변환해야 하는 문제를 겪어본 적이 있습니까? 사실, 이를 처리할 수 있는 내장 함수는 없으며 VBA 코드만 사용할 수 있습니다.

정의된 함수를 사용하여 날짜를 단어로 변환

정의된 함수를 사용하여 날짜를 단어로 변환

다음은 날짜를 단어로 변환하는 데 도움을 줄 수 있는 매크로 코드입니다.

1. 사용 중인 시트를 활성화하고 Alt + F11 키를 눌러 Microsoft Visual Basic for Applications 창을 엽니다.

2. 삽입 > 모듈을 클릭하고 아래 코드를 스크립트에 붙여넣습니다.

VBA: 날짜를 단어로 변환

Function DateToWords(ByVal xRgVal As Date) As String
' Update by Extendoffice on 20240926
    Dim xYear As String
    Dim Hundreds As String
    Dim Decades As String
    Dim xTensArr As Variant
    Dim xOrdArr As Variant
    Dim xCardArr As Variant
    
    ' Initialize arrays
    xOrdArr = Array("First", "Second", "Third", "Fourth", "Fifth", "Sixth", _
                    "Seventh", "Eighth", "Ninth", "Tenth", "Eleventh", "Twelfth", _
                    "Thirteenth", "Fourteenth", "Fifteenth", "Sixteenth", _
                    "Seventeenth", "Eighteenth", "Nineteenth", "Twentieth", _
                    "Twenty-first", "Twenty-second", "Twenty-third", "Twenty-fourth", _
                    "Twenty-fifth", "Twenty-sixth", "Twenty-seventh", "Twenty-eighth", _
                    "Twenty-ninth", "Thirtieth", "Thirty-first")
    
    xCardArr = Array("", "One", "Two", "Three", "Four", "Five", "Six", "Seven", "Eight", "Nine", _
                    "Ten", "Eleven", "Twelve", "Thirteen", "Fourteen", "Fifteen", "Sixteen", _
                    "Seventeen", "Eighteen", "Nineteen")
    
    xTensArr = Array("Twenty", "Thirty", "Forty", "Fifty", "Sixty", "Seventy", "Eighty", "Ninety")
    
    ' Extract year
    xYear = CStr(Year(xRgVal))
    Decades = Mid$(xYear, 3)
    
    ' Handle decades
    If CInt(Decades) < 20 Then
        Decades = xCardArr(CInt(Decades))
    Else
        Decades = xTensArr(CInt(Left$(Decades, 1)) - 2) & "-" & xCardArr(CInt(Right$(Decades, 1)))
    End If
    
    ' Handle hundreds
    Hundreds = Mid$(xYear, 2, 1)
    If CInt(Hundreds) Then
        Hundreds = xCardArr(CInt(Hundreds)) & " Hundred "
    Else
        Hundreds = ""
    End If
    
    ' Construct English representation of the date
    DateToWords = xOrdArr(Day(xRgVal) - 1) & " " & Format$(xRgVal, "mmmm") & " " & _
                  xCardArr(CInt(Left$(xYear, 1))) & " Thousand " & Hundreds & Decades
End Function

3. 코드를 저장하고 시트로 돌아가서 결과를 출력할 셀을 선택한 다음 다음 수식을 입력합니다. =DateToWords(A2) (A2는 사용 중인 날짜입니다), Enter 키를 누르고 필요한 셀 위로 자동 채우기 핸들을 드래그합니다. 스크린샷 보기:

관련 기사:

• Excel에서 유럽과 미국 간 날짜 형식을 빠르게 변환하는 방법은 무엇입니까?
• Excel에서 dD.MM.YYYY를 날짜 형식(mM/DD/YYYY)으로 변환하는 방법은 무엇입니까?
• Excel에서 날짜와 유닉스 타임스탬프 간 변환 방법은 무엇입니까?