Excel에서 여러 조건에 따라 고유한 값을 세는 방법은 무엇입니까?

이 문서에서는 워크시트에서 하나 이상의 조건에 따라 고유한 값을 세는 몇 가지 예를 들어 설명하겠습니다. 다음의 자세한 단계들이 도움이 될 수 있습니다.

하나의 조건에 따른 고유 값 세기

두 개의 지정된 날짜에 따른 고유 값 세기

두 가지 조건에 따른 고유 값 세기

세 가지 조건에 따른 고유 값 세기

하나의 조건에 따른 고유 값 세기

예를 들어, 다음과 같은 데이터 범위가 있다고 가정해 보겠습니다. 이제 Tom이 판매한 고유한 제품을 세고 싶습니다.

결과를 얻고자 하는 빈 셀(G2 등)에 다음 수식을 입력하세요:

=SUM(IF("Tom"=$C$2:$C$20, 1/(COUNTIFS($C$2:$C$20, "Tom", $A$2:$A$20, $A$2:$A$20)), 0)) 그리고 나서 올바른 결과를 얻기 위해 Shift + Ctrl + Enter 키를 함께 누르세요, 스크린샷 참조:

참고: 위 수식에서 “Tom”은 기준 이름이며, C2:C20은 해당 이름 기준이 포함된 셀들입니다. A2:A20은 고유한 값을 세고자 하는 셀들입니다.

두 개의 지정된 날짜에 따른 고유 값 세기

두 개의 지정된 날짜 사이의 고유 값을 계산하기 위해, 예를 들어 2016/9/1부터 2016/9/30까지의 날짜 범위 내에서 고유한 제품을 세고 싶다면, 다음 수식을 사용하세요:

=SUM(IF($D$2:$D$20<=DATE(2016, 9, 30)*($D$2:$D$20>=DATE(2016, 9, 1)), 1/COUNTIFS( $A$2:$A$20, $A$2:$A$20, $D$2:$D$20, "<="&DATE(2016, 9, 30),$D$2:$D$20, ">="&DATE(2016, 9, 1))), 0), 그리고 나서 고유한 결과를 얻기 위해 Shift + Ctrl + Enter 키를 함께 누르세요, 스크린샷 참조:

참고: 위 수식에서 2016,9,1 및 2016,9,30은 시작 날짜와 종료 날짜이며, D2:D20은 날짜 기준이 포함된 셀들입니다. A2:A20은 고유한 값을 세고자 하는 셀들입니다.

두 가지 조건에 따른 고유 값 세기

만약 9월에 Tom이 판매한 고유한 제품을 세고 싶다면, 다음 수식이 도움이 될 것입니다.

결과를 출력할 빈 셀(H2 등)에 이 수식을 입력하세요.

=SUM(IF(("Tom"=$C$2:$C$20)*($D$2:$D$20<=DATE(2016, 9, 30)*($D$2:$D$20>=DATE(2016, 9, 1))), 1/COUNTIFS($C$2:$C$20, "Tom", $A$2:$A$20, $A$2:$A$20, $D$2:$D$20, "<="&DATE(2016, 9, 30),$D$2:$D$20, ">="&DATE(2016, 9, 1))), 0) 그리고 나서 고유한 결과를 얻기 위해 Shift + Ctrl + Enter 키를 함께 누르세요, 스크린샷 참조:

참고:

1. 위 수식에서 “Tom”은 이름 기준이며, 2016,9,1 및 2016,9,30은 기준으로 삼고자 하는 두 날짜입니다. C2:C20은 이름 기준이 포함된 셀들이고, D2:D20 은 날짜가 포함된 셀들입니다. A2:A20은 고유한 값을 세고자 하는 셀들의 범위입니다.

2. “or” 조건을 사용하여 고유한 값을 세야 한다면, 예를 들어 Tom이 판매하거나 남부 지역에서 판매된 제품을 계산하고자 할 때, 다음 수식을 적용하세요:

=SUM(--(FREQUENCY(IF(("Tom"=$C$2:$C$20)+("South"=$B$2:$B$20), COUNTIF($A$2:$A$20, "<"&$A$2:$A$20), ""), COUNTIF($A$2:$A$20, "<"&$A$2:$A$20))>0)), 그리고 나서 고유한 결과를 얻기 위해 Shift + Ctrl + Enter 키를 함께 누르세요, 스크린샷 참조:

세 가지 조건에 따른 고유 값 세기

세 가지 조건에 따라 고유한 제품을 세려면, 수식이 더 복잡해질 수 있습니다. 예를 들어, 9월에 Tom이 북부 지역에서 판매한 고유한 제품을 계산한다고 가정해 보겠습니다. 아래와 같이 해보세요:

결과를 출력할 빈 셀(I2 등)에 이 수식을 입력하세요:

=SUM(IF(("Tom"=$C$2:$C$20)*($D$2:$D$20<=DATE(2016, 9, 30))*($D$2:$D$20>=DATE(2016, 9, 1))*("North"=$B$2:$B$20), 1/COUNTIFS($C$2:$C$20, "Tom", $A$2:$A$20, $A$2:$A$20, $D$2:$D$20, "<="&DATE(2016, 9, 30), $D$2:$D$20, ">="&DATE(2016, 9, 1), $B$2:$B$20, "North")), 0), 그리고 나서 고유한 결과를 얻기 위해 Shift + Ctrl + Enter 키를 함께 누르세요, 스크린샷 참조: