Excel에서 텍스트를 찾아 바꾸고 서식을 유지하려면 어떻게 해야 하나요?

찾기 및 바꾸기 기능은 특정 값을 찾아 다른 값으로 바꿀 때 강력하고 유용합니다. 하지만 셀 범위가 있고, 일부 셀에는 서로 다른 서식이 포함된 값이 있는 경우, 찾기 및 바꾸기 기능을 사용하여 값을 찾고 바꾸면 아래 스크린샷과 같이 셀 내 값의 서식이 깨질 수 있습니다. Excel에서 찾기 및 바꾸기를 하면서 각 셀의 값 서식을 유지하려면 어떻게 해야 할까요?

매크로 코드를 사용하여 찾기 및 바꾸기하면서 서식 유지하기

매크로 코드를 사용하여 찾기 및 바꾸기하면서 서식 유지하기

매크로 코드 외에는 텍스트를 찾아 바꾸고 서식을 유지할 수 있는 다른 방법은 없습니다.

1. Alt + F11 키를 눌러 Microsoft Visual Basic for Applications 창을 엽니다.

2. 삽입 > 모듈을 클릭하고 아래 코드를 스크립트에 붙여넣습니다.

VBA: 찾기 및 바꾸기하면서 서식 유지하기

Sub CharactersReplace(Rng As Range, FindText As String, ReplaceText As String, Optional MatchCase As Boolean = False)
  'UpdatebyExtendoffice20160711
    Dim I As Long
    Dim xLenFind As Long
    Dim xLenRep As Long
    Dim K As Long
    Dim xValue As String
    Dim M As Long
    Dim xCell As Range
    xLenFind = Len(FindText)
    xLenRep = Len(ReplaceText)
    If Not MatchCase Then M = 1
    For Each xCell In Rng
        If VarType(xCell) = vbString Then
            xValue = xCell.Value
            K = 0
            For I = 1 To Len(xValue)
              If StrComp(Mid$(xValue, I, xLenFind), FindText, M) = 0 Then
                xCell.Characters(I + K, xLenFind).Insert ReplaceText
                K = K + xLenRep - xLenFind
              End If
            Next
        End If
    Next
End Sub

Sub Test_CharactersReplace()
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Select a range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Call CharactersReplace(xRg, "KK", "Kutools", True)
End Sub

팁: 코드에서 KK는 찾으려는 문자열이고, Kutools는 바꿀 내용입니다. 필요에 따라 이를 변경할 수 있습니다.

3. 누르세요 F5 키를 누르면 선택한 범위에서 찾기 및 바꾸기를 할 수 있는 대화상자가 나타납니다. 스크린샷 참고:

4. 확인을 클릭하면 선택한 셀의 특정 문자열이 다른 것으로 바뀌고 서식은 유지됩니다.