Excel에서 코멘트 표시기 색상을 변경하는 방법은 무엇입니까?

Excel에서 코멘트를 삽입한 후, 셀의 오른쪽 상단에 작은 빨간색 삼각형 표시기가 나타납니다. 많은 Excel 사용자들은 이 빨간색 표시기의 색상을 자신이 원하는 다른 색상으로 변경할 수 있는지 궁금해 할 수 있습니다. 이 문서에서는 이 작업을 수행하기 위한 해결 방법에 대해 설명하겠습니다.

VBA 코드로 코멘트 표시기 색상 변경하기

VBA 코드로 코멘트 표시기 색상 변경하기

코멘트 표시기의 색상을 빠르고 쉽게 변경할 수 있는 직접적인 방법은 없지만, 다음 VBA 코드는 활성 시트의 모든 코멘트 표시기에 특정 색상으로 덮어씌운 삼각형 도형을 그려줍니다.

1. 코멘트 표시기 색상을 변경하려는 워크시트를 활성화하세요.

2. ALT + F11 키를 눌러 Microsoft Visual Basic for Applications 창을 엽니다.

3. 삽입 > 모듈을 클릭하고, 모듈 창에 다음 코드를 붙여넣습니다.

VBA 코드: 활성 시트에서 코멘트 표시기 색상 변경하기

Sub CoverCommentIndicator()
'Update 20141110
Dim pWs As Worksheet
Dim pComment As Comment
Dim pRng As Range
Dim pShape As Shape
Set pWs = Application.ActiveSheet
wShp = 6
hShp = 4
For Each pComment In pWs.Comments
  Set pRng = pComment.Parent
  Set pShape = pWs.Shapes.AddShape(msoShapeRightTriangle, pRng.Offset(0, 1).Left - wShp, pRng.Top, wShp, hShp)
  With pShape
    .Flip msoFlipVertical
    .Flip msoFlipHorizontal
    .Fill.ForeColor.SchemeColor = 12
    .Fill.Visible = msoTrue
    .Fill.Solid
    .Line.Visible = msoFalse
  End With
Next
End Sub

4. 코드를 붙여넣은 후, F5 키를 눌러 코드를 실행하면, 아래 스크린샷과 같이 모든 빨간색 삼각형 표시기가 파란색 삼각형으로 덮입니다.

참고:

1. 위의 코드에서 .Fill.ForeColor.SchemeColor = 12의 색상 인덱스를 변경하여 파란색을 원하는 색상으로 바꿀 수 있습니다.

2. 위의 VBA로 추가한 삼각형 도형은 셀 크기를 조정할 때 크기가 변경됩니다.

3. 즉시 모든 색상이 적용된 삼각형 도형을 제거하려면, 다음 VBA 코드가 도움이 될 것입니다:

VBA 코드: 코멘트 표시기에 덮인 삼각형 도형 제거하기

Sub RemoveIndicatorShapes()
'Update 20141110
Dim pWs As Worksheet
Dim pShape As Shape
Set pWs = Application.ActiveSheet
For Each pShape In pWs.Shapes
    If Not pShape.TopLeftCell.Comment Is Nothing Then
      If pShape.AutoShapeType = msoShapeRightTriangle Then
        pShape.Delete
      End If
    End If
Next
End Sub

관련 기사:

Excel에서 코멘트가 있는 모든 셀을 강조하는 방법은 무엇입니까?

Excel에서 모든 코멘트와 코멘트 표시기를 표시하거나 숨기는 방법은 무엇입니까?